Keep dired from creating new buffers.

Keep dired from creating new buffers.

[Bora]

Whenever I navigate through (sub)directories in "dired", I get a new buffer
for each directory.  This quickly creates a large number of buffers in
emacs.  Is there a way to keep dired from doing this, and instead use only
one buffer and update its content if I move through directories.

Thanks
Bora

Re: Keep dired from creating new buffers.

[Yoni Rabkin]

Copied verbatim from
http://www.emacswiki.org/cgi-bin/wiki.pl/DiredMode:

Here's the code to make dired use only one buffer:

 (eval-after-load "dired"
  '(progn
     (defadvice dired-advertised-find-file (around dired-subst-directory activate)
       "Replace current buffer if file is a directory."
       (interactive)
       (let* ((orig (current-buffer))
              (filename (dired-get-filename))
              (bye-p (file-directory-p filename)))
         ad-do-it
         (when (and bye-p (not (string-match "[/\\\\]\\.$" filename)))
           (kill-buffer orig))))))

And here is another way for achieving this:

    ;; we want dired not not make always a new buffer if visiting a directory
    ;; but using only one dired buffer for all directories.
    (defadvice dired-advertised-find-file (around dired-subst-directory activate)
      "Replace current buffer if file is a directory."
      (interactive)
      (let ((orig (current-buffer))
            (filename (dired-get-filename)))
        ad-do-it
        (when (and (file-directory-p filename)
                   (not (eq (current-buffer) orig)))
          (kill-buffer orig))))

Re: Keep dired from creating new buffers.

[Ekkehard Görlach]

Some time ago somebody posted the following code I have for that in my
.emacs:

;; dired customization
(defun dired-follow-file ()
  "In dired, visit the file or directory on this line.
If a directory is on the current line, replace the current
Dired buffer with one containing the contents of the directory.
Otherwise, invoke `dired-find-file' on the file."
  (interactive)
  (let ((filename (dired-get-filename)))
    (if (file-directory-p filename)
        (find-alternate-file filename)
      (dired-find-file))))

(defun dired-setup-follow-file ()
  (substitute-key-definition
   'dired-find-file 'dired-follow-file dired-mode-map)
  (substitute-key-definition
   'dired-advertised-find-file 'dired-follow-file dired-mode-map))
(add-hook 'dired-mode-hook 'dired-setup-follow-file)


HTH,
Ekkehard

Re: Keep dired from creating new buffers.

[Henrik Enberg]

"Bora" <nobody@nospam.none> writes:

> Whenever I navigate through (sub)directories in "dired", I get a new buffer
> for each directory.  This quickly creates a large number of buffers in
> emacs.  Is there a way to keep dired from doing this, and instead use only
> one buffer and update its content if I move through directories.

Hit "a" instead of RET on the directory.

Re: Keep dired from creating new buffers.

[Sébastien Kirche]

Yoni Rabkin <yonirabkin@member.fsf.org> writes:

> Copied verbatim from
> http://www.emacswiki.org/cgi-bin/wiki.pl/DiredMode:
>
> [...]
>

I tried both of these functions.
They seem to work when entering down a directory, 
but if you want to get back to the parent directory with the "..", 
they fail with the following message : 
dired-get-filename: Cannot operate on `.' or `..'

How to correct this ?

Sébastien Kirche

Re: Keep dired from creating new buffers.

[Rob Thorpe]

"Bora" <nobody@nospam.none> wrote in message news:<brcpjk$hcr$1@fred.mathworks.com>...
> Whenever I navigate through (sub)directories in "dired", I get a new buffer
> for each directory.  This quickly creates a large number of buffers in
> emacs.  Is there a way to keep dired from doing this, and instead use only
> one buffer and update its content if I move through directories.
> 
> Thanks
> Bora

The most satisfactory method I've found is to use dired like this:

Normally press 'a' on a subdir which replaces the current dired buffer
with the buffer of that subdir.

Use 'enter' when you actually want a new dired buffer, sometimes it's
useful

Use 'i' which inserts the subdir into the current buffer when you know
the directory listing will be fairly short.  To remove these when
you've finished use C-u k next to them.