copy-word-from-line-above

copy-word-from-line-above

[HS]

Hello!
Does anyone have a function that copies words from the line above, word
after word ?
I'd like this function so I could have something like this:

double int xxx;

Then I'd just put the cursor under that line, press <f2> (for example)
twice and would be in this state:

double int xxx;
double int

then I would continue adding the new variable.

Thanks in advance,
HS

Re: copy-word-from-line-above

[Marc Tfardy]

HS wrote:
> Hello!
> Does anyone have a function that copies words from the line above, word
> after word ?
> I'd like this function so I could have something like this:
> 
> double int xxx;
> 
> Then I'd just put the cursor under that line, press <f2> (for example)
> twice and would be in this state:
> 
> double int xxx;
> double int
> 
> then I would continue adding the new variable.

Not exactly what you looking for, but a simple macro do a similar job:

C-a			;; beginning-of-line
C-p			;; previous-line
C-SPC			;; set-mark-command
C-e			;; end-of-line
M-w			;; kill-ring-save
C-a			;; beginning-of-line
C-n			;; next-line
C-y			;; yank


or:

(fset 'duplicate-last-line
    [?\C-a ?\C-p ?\C-  ?\C-e ?\M-w ?\C-a ?\C-n ?\C-y])

This macro duplcates whole previous line. The point is on the
end of the line. Now you can press (one or more times ) M-DEL
and continue editing.


regards

Marc

Re: copy-word-from-line-above

[Nikos Apostolakis]

Marc Tfardy <m-t-o@web.de> writes:

> HS wrote:
>> Hello!
>> Does anyone have a function that copies words from the line above, word
>> after word ?
>> I'd like this function so I could have something like this:
>>
>> double int xxx;
>>
>> Then I'd just put the cursor under that line, press <f2> (for example)
>> twice and would be in this state:
>>
>> double int xxx;
>> double int
>>
>> then I would continue adding the new variable.
>
> Not exactly what you looking for, but a simple macro do a similar job:
>

[...]

>
> This macro duplcates whole previous line. The point is on the
> end of the line. Now you can press (one or more times ) M-DEL
> and continue editing.

Here is a slightly better keyboard macro to record.  Go underneath
the line that you want to incrementally copy and do (spaces inseted
for readability)

C-x( C-e C-p C-M-s \< C-<space> C-M-s C-s M-w C-n C-y C-x)

IOW, go to the end of line, go to the line above, search for
beginning of word, set the mark, find the next beginning of word,
copy region, go to next line, yank.  Now hit C-xe to copy the word
above and (in emacs22 at least) keep hiting "e" to repeat as many
times as desired.  Haven't thoroughly checked it but it should work.

Shouldn't be hard to write this in lisp, either.

HTH
Nikos

Re: copy-word-from-line-above

[rgb]

HS wrote:
> Hello!
> Does anyone have a function that copies words from the line above, word
> after word ?
> I'd like this function so I could have something like this:
>
> double int xxx;
>
> Then I'd just put the cursor under that line, press <f2> (for example)
> twice and would be in this state:
>
> double int xxx;
> double int
>

I use this because its a bit more flexable.
It allows you to copy exactly the parts you want even if not full
words.

(global-set-key [?\C-\M-z] 'insert-prior-line-char)

(defun insert-prior-line-char ()
  "Insert the same character as in the prior line. Space if none."
  (interactive)
  (let* ((cur (current-column))
         (char (save-excursion
                 (if (or (not (eq 0 (forward-line -1)))
                         (not (eq cur (move-to-column cur)) ))
                     32
                   (char-after)))))
    (insert char)))

Re: copy-word-from-line-above

[Greg Bognar]

> I use this because its a bit more flexable. It allows you to copy exactly
> the parts you want even if not full words.
> 
> (global-set-key [?\C-\M-z] 'insert-prior-line-char)
> 
> (defun insert-prior-line-char ()
>   "Insert the same character as in the prior line. Space if none."
>   (interactive)
>   (let* ((cur (current-column))
>          (char (save-excursion
>                  (if (or (not (eq 0 (forward-line -1)))
>                          (not (eq cur (move-to-column cur)) ))
>                      32
>                    (char-after)))))
>     (insert char)))

This is great, but wouldn't it be nicer if you could give it an argument? 
Then you could do, say, C-8 C-M-z and the next 8 characters would be
inserted.

Re: copy-word-from-line-above

[rgb]

Greg Bognar wrote:
> > I use this because its a bit more flexable. It allows you to copy exactly
> > the parts you want even if not full words.
> >
> > (global-set-key [?\C-\M-z] 'insert-prior-line-char)
> >
> > (defun insert-prior-line-char ()
> >   "Insert the same character as in the prior line. Space if none."
> >   (interactive)
> >   (let* ((cur (current-column))
> >          (char (save-excursion
> >                  (if (or (not (eq 0 (forward-line -1)))
> >                          (not (eq cur (move-to-column cur)) ))
> >                      32
> >                    (char-after)))))
> >     (insert char)))
>
> This is great, but wouldn't it be nicer if you could give it an argument?
> Then you could do, say, C-8 C-M-z and the next 8 characters would be
> inserted.

I've got my keyboard repeat rate high enough that I've not missed
that feature but it's a good idea.  Maybe I'll add that Monday when
I have time to goof of at work:-)
thanks

Re: copy-word-from-line-above

[HS]

Cool! Post it here as well!
Cheers everyone!


rgb escreveu:

> Greg Bognar wrote:
> > > I use this because its a bit more flexable. It allows you to copy exactly
> > > the parts you want even if not full words.
> > >
> > > (global-set-key [?\C-\M-z] 'insert-prior-line-char)
> > >
> > > (defun insert-prior-line-char ()
> > >   "Insert the same character as in the prior line. Space if none."
> > >   (interactive)
> > >   (let* ((cur (current-column))
> > >          (char (save-excursion
> > >                  (if (or (not (eq 0 (forward-line -1)))
> > >                          (not (eq cur (move-to-column cur)) ))
> > >                      32
> > >                    (char-after)))))
> > >     (insert char)))
> >
> > This is great, but wouldn't it be nicer if you could give it an argument?
> > Then you could do, say, C-8 C-M-z and the next 8 characters would be
> > inserted.
>
> I've got my keyboard repeat rate high enough that I've not missed
> that feature but it's a good idea.  Maybe I'll add that Monday when
> I have time to goof of at work:-)
> thanks

Re: copy-word-from-line-above

[rgb]

On Jan 22, 7:02 am, "HS" <hug...@gmail.com> wrote:
> Cool! Post it here as well!
> Cheers everyone!
>
> rgb escreveu:
>
>
>
> > Greg Bognar wrote:
> > > > I use this because its a bit more flexable. It allows you to copy exactly
> > > > the parts you want even if not full words.
>
> > > > (global-set-key [?\C-\M-z] 'insert-prior-line-char)
>
> > > > (defun insert-prior-line-char ()
> > > >   "Insert the same character as in the prior line. Space if none."
> > > >   (interactive)
> > > >   (let* ((cur (current-column))
> > > >          (char (save-excursion
> > > >                  (if (or (not (eq 0 (forward-line -1)))
> > > >                          (not (eq cur (move-to-column cur)) ))
> > > >                      32
> > > >                    (char-after)))))
> > > >     (insert char)))
>
> > > This is great, but wouldn't it be nicer if you could give it an argument?
> > > Then you could do, say, C-8 C-M-z and the next 8 characters would be
> > > inserted.
>
> > I've got my keyboard repeat rate high enough that I've not missed
> > that feature but it's a good idea.  Maybe I'll add that Monday when
> > I have time to goof of at work:-)
> > thanks-

Somebody must have told the boss I had goof-off time!
But I got to it this morning...

(defun insert-prior-line-char (cnt)
  "Insert the same character as in the prior line. Space if none."
  (interactive "p")
  (while (< 0 cnt)
    (setq cnt (1- cnt))
    (let* ((cur (current-column))
           (char (save-excursion
                   (if (or (not (eq 0 (forward-line -1)))
                           (not (eq cur (move-to-column cur)) ))
                       32
                     (char-after)))))
      (insert char))))

Re: copy-word-from-line-above

[HS]

In practive I found out that copying chars is slower than typing, most
of the times...
Is there any kind soul here able to work out a insert-prior-line-word
from rgb's function? :)
Cheers
HS

On 24 jan, 09:19, "rgb" <rbiel...@i1.net> wrote:
> On Jan 22, 7:02 am, "HS" <hug...@gmail.com> wrote:
>
>
>
> > Cool! Post it here as well!
> > Cheers everyone!
>
> > rgb escreveu:
>
> > > Greg Bognar wrote:
> > > > > I use this because its a bit more flexable. It allows you to copy exactly
> > > > > the parts you want even if not full words.
>
> > > > > (global-set-key [?\C-\M-z] 'insert-prior-line-char)
>
> > > > > (defun insert-prior-line-char ()
> > > > >   "Insert the same character as in the prior line. Space if none."
> > > > >   (interactive)
> > > > >   (let* ((cur (current-column))
> > > > >          (char (save-excursion
> > > > >                  (if (or (not (eq 0 (forward-line -1)))
> > > > >                          (not (eq cur (move-to-column cur)) ))
> > > > >                      32
> > > > >                    (char-after)))))
> > > > >     (insert char)))
>
> > > > This is great, but wouldn't it be nicer if you could give it an argument?
> > > > Then you could do, say, C-8 C-M-z and the next 8 characters would be
> > > > inserted.
>
> > > I've got my keyboard repeat rate high enough that I've not missed
> > > that feature but it's a good idea.  Maybe I'll add that Monday when
> > > I have time to goof of at work:-)
> > > thanks-Somebody must have told the boss I had goof-off time!
> But I got to it this morning...
>
> (defun insert-prior-line-char (cnt)
>   "Insert the same character as in the prior line. Space if none."
>   (interactive "p")
>   (while (< 0 cnt)
>     (setq cnt (1- cnt))
>     (let* ((cur (current-column))
>            (char (save-excursion
>                    (if (or (not (eq 0 (forward-line -1)))
>                            (not (eq cur (move-to-column cur)) ))
>                        32
>                      (char-after)))))
>       (insert char))))

Re: copy-word-from-line-above

[Markus Triska]

"HS" <hugows@gmail.com> writes:

> insert-prior-line-word

What about:

(defun insert-word-above ()
  (interactive)
  (let (word whitespace)
    (save-excursion
      (let ((col (current-column)))
        (forward-line -1)
        (move-to-column col))
      (setq word (or (thing-at-point 'word)
                     (error "No word above")))
      (forward-word)
      (setq whitespace (or (thing-at-point 'whitespace) "")))
    (insert word whitespace)))

(global-set-key [f2] 'insert-word-above)

All the best,
Markus Triska

Re: copy-word-from-line-above

[HS]

Hello!
Thanks Triska!
But your function would not copy symbols like '(' so I tried something,
and think I just wrote my first defun :)
Here it is:

(defun insert-word-above ()
  (interactive)
  (save-excursion
	(let ((col (current-column)))
	  (forward-line -1)
	  (move-to-column col))
	(let ((beg (point)))
	  (forward-word)
	  (copy-region-as-kill-nomark beg (point))))
	(yank))

It seems to work!
Cheers,
HS

On 24 jan, 17:21, Markus Triska <markus.tri...@gmx.at> wrote:
> "HS" <hug...@gmail.com> writes:
> > insert-prior-line-wordWhat about:
>
> (defun insert-word-above ()
>   (interactive)
>   (let (word whitespace)
>     (save-excursion
>       (let ((col (current-column)))
>         (forward-line -1)
>         (move-to-column col))
>       (setq word (or (thing-at-point 'word)
>                      (error "No word above")))
>       (forward-word)
>       (setq whitespace (or (thing-at-point 'whitespace) "")))
>     (insert word whitespace)))
>
> (global-set-key [f2] 'insert-word-above)
> 
> All the best,
> Markus Triska

Re: copy-word-from-line-above

[rgb]

> (defun insert-word-above ()
>   (interactive)
>   (let (word whitespace)
>     (save-excursion
>       (let ((col (current-column)))
>         (forward-line -1)
>         (move-to-column col))
>       (setq word (or (thing-at-point 'word)
>                      (error "No word above")))
>       (forward-word)
>       (setq whitespace (or (thing-at-point 'whitespace) "")))
>     (insert word whitespace)))
>
> (global-set-key [f2] 'insert-word-above)

This does all kinds of bizar things whenever a seperator
other than whitespace surrounds a word.  So it's probably
a good thing that it doesn't accept a count argument.

It acted slightly better (for me) replacing 'word with 'symbol
and (forward-word) with (forward-symbol 1).

I suspect that the OP is running Emacs remotely
and so the repeat key rate using insert-prior-line-char
is insufficient :-(

A solution like this might work better under such
circumstances.

(defun insert-prior-line-word (cnt)
  "Insert chars in prior line starting above point until whitespace.
With prefix arg, do it CNT times."
  (interactive "p")
  (while (< 0 cnt)
    (setq cnt (1- cnt))
    (let (word whitespace)
      (save-excursion
        (let ((col (current-column)))
          (forward-line -1)
          (move-to-column col))
        (save-match-data
          (setq word (if (looking-at "\\S-+")
                         (prog1 (match-string 0)
                           (goto-char (match-end 0))))
                whitespace (and (looking-at "\\s-+")
                                (match-string 0)))))
      (or word whitespace (error "No word above"))
      (if word (insert word whitespace)
        (insert whitespace)))))

Re: copy-word-from-line-above

[Markus Triska]

"HS" <hugows@gmail.com> wrote:

> Hello!
> Thanks Triska!
> But your function would not copy symbols like '(' so I tried something,
> and think I just wrote my first defun :)

Cool; I changed "copy-region-as-kill-nomark" to "copy-region-as-kill"
to get it working. To preserve the kill ring, you can use: 

(defun insert-word-above ()
  (interactive)
  (let (string beg end)
    (save-excursion
      (let ((col (current-column)))
        (forward-line -1)
        (move-to-column col))
      (setq beg (point))
      (forward-word)
      (setq end (point)))
    (insert (buffer-substring beg end))))

All the best,
Markus Triska