Re: Number of open buffers?

Re: Number of open buffers?

[Eli Zaretskii]

> From: Ignoramus1904 <ignoramus1904@NOSPAM.1904.invalid>
> Newsgroups: gnu.emacs.help
> Date: 20 Nov 2003 15:12:12 GMT
> 
> Sometimes though I have just one file open for quick editing. Then I
> do want to exit on \C-x\C-c.
> 
> I want to modify it so that if the # of open file buffers is more than
> one, emacs would ask YES/NO, if less, I exit. I am a very bad lisp
> programmer, any suggestions?

The expression (length (buffer-list)) will return the number of
buffers in your Emacs session.  You will need to make allowances for
the minubuffer and buffers like *Messages* and *scratch* that are
always present.  There are usually 6 such buffers, so subtract 6 from
what the expression above returns and compare it with 1.

For a more bullet-proof code, walk the buffer list returned by the
function buffer-list, and filter out any buffer which doesn't have a
file associated with it (its buffer-file-name will be nil).  What is
left are the buffers which visit files.

HTH

Re: Number of open buffers?

[Micah Cowan]

Ignoramus1904 <ignoramus1904@NOSPAM.1904.invalid> writes:

> In article <mailman.342.1069348789.399.help-gnu-emacs@gnu.org>, Eli Zaretskii wrote:
> >> From: Ignoramus1904 <ignoramus1904@NOSPAM.1904.invalid>
> >> Newsgroups: gnu.emacs.help
> >> Date: 20 Nov 2003 15:12:12 GMT
> >> 
> >> Sometimes though I have just one file open for quick editing. Then I
> >> do want to exit on \C-x\C-c.
> >> 
> >> I want to modify it so that if the # of open file buffers is more than
> >> one, emacs would ask YES/NO, if less, I exit. I am a very bad lisp
> >> programmer, any suggestions?
> > 
> > The expression (length (buffer-list)) will return the number of
> > buffers in your Emacs session.  You will need to make allowances for
> > the minubuffer and buffers like *Messages* and *scratch* that are
> > always present.  There are usually 6 such buffers, so subtract 6 from
> > what the expression above returns and compare it with 1.

I seem to get more than 6. YMMV, I think, so it can't be relied
upon.

> > 
> > For a more bullet-proof code, walk the buffer list returned by the
> > function buffer-list, and filter out any buffer which doesn't have a
> > file associated with it (its buffer-file-name will be nil).  What is
> > left are the buffers which visit files.
> > 
> > HTH
> > 
> > 
> > 
> 
> Thanks Eli, sounds a little bit above my head to be honest. I do C++
> and Perl and do not know Lisp well. I just thought that there was a
> function like get-number-of-file-buffers, or something like that.

The following is what he's talking about, I think:

(defun get-number-of-file-buffers ()
  (interactive)
  (let (num)
    (setq num 0)
    (dolist (buf (buffer-list))
      (when (buffer-file-name buf)
          (setq num (+ num 1))
      ))
    num
    )
  )

Another possibility would be to have an alias to one or other
emacs that invokes emacs in the way you want (with or without the
"are you sure?" stuff): then just use one name for emacs when you
don't want to be asked, and another for when you do.

-- 
Micah J. Cowan
micah@cowan.name

Re: Number of open buffers?

[David Kastrup]

Ignoramus1904 <ignoramus1904@NOSPAM.1904.invalid> writes:

> In article <m31xs2c3na.fsf@localhost.localdomain>, Micah Cowan wrote:
> > Ignoramus1904 <ignoramus1904@NOSPAM.1904.invalid> writes:
> > 
> >> Eli Zaretskii wrote:
> >> >> From: Ignoramus1904 <ignoramus1904@NOSPAM.1904.invalid>
> >> >> 
> >> >> I want to modify it so that if the # of open file buffers is more than
> >> >> one, emacs would ask YES/NO, if less, I exit. I am a very bad lisp
> >> >> programmer, any suggestions?
> >> > 
> >> > 
> >> > For a more bullet-proof code, walk the buffer list returned by the
> >> > function buffer-list, and filter out any buffer which doesn't have a
> >> > file associated with it (its buffer-file-name will be nil).  What is
> >> > left are the buffers which visit files.
> >> > 
> >> 
> >> Thanks Eli, sounds a little bit above my head to be honest. I do C++
> >> and Perl and do not know Lisp well. I just thought that there was a
> >> function like get-number-of-file-buffers, or something like that.
> > 
> > The following is what he's talking about, I think:
> > 
> > (defun get-number-of-file-buffers ()
> >   (interactive)
> >   (let (num)
> >     (setq num 0)
> >     (dolist (buf (buffer-list))
> >       (when (buffer-file-name buf)
> >           (setq num (+ num 1))
> >       ))
> >     num
> >     )
> >   )

Somewhat shorter:

(defun get-number-of-file-buffers ()
  (interactive)
  (let ((num 0))
    (dolist (buf (buffer-list) num)
      (when (buffer-file-name buf)
          (setq num (1+ num))))))

> Thanks. When I try to run it via eval-expr, saying
> 
> (insert get-number-of-file-buffers)
> 
> It says: Error: void-variable. Data: get-number-of-file-buffers

Yes.  One calls a function by putting it after an opening
parenthesis.  The way you tried to "call" it, just a variable of that
name got referenced, and there is no such variable.  In addition, the
function returns a numeric expression, and `insert' expects a string.

-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum

Re: Number of open buffers?

[Lucas]

Un beau jour, Ignoramus1904 <ignoramus1904@NOSPAM.1904.invalid> nous a dit:

>
> Thanks. When I try to run it via eval-expr, saying
>
> (insert get-number-of-file-buffers)

(insert (get-number-of-file-buffers))

should do the trick, the functions are surrounded by parens :)


-- 
Lucas

Re: Number of open buffers?

[lawrence mitchell]

David Kastrup wrote:

[...]

> (defun get-number-of-file-buffers ()
>   (interactive)
>   (let ((num 0))
>     (dolist (buf (buffer-list) num)
>       (when (buffer-file-name buf)
>           (setq num (1+ num))))))

Assuming cl is loaded:

(defun get-number-of-file-buffers ()
  (loop for b in (buffer-list) count (buffer-file-name b)))

:)

>> Thanks. When I try to run it via eval-expr, saying

>> (insert get-number-of-file-buffers)

>> It says: Error: void-variable. Data: get-number-of-file-buffers

> Yes.  One calls a function by putting it after an opening
> parenthesis.  The way you tried to "call" it, just a variable of that
> name got referenced, and there is no such variable.  In addition, the
> function returns a numeric expression, and `insert' expects a string.

The OP may find reading the Emacs Lisp Introduction a useful
exercise, it's not that long, and, I think, explains the basics
of emacs lisp quite nicely.

-- 
lawrence mitchell <wence@gmx.li>

Re: Number of open buffers?

[David Kastrup]

lawrence mitchell <wence@gmx.li> writes:

> David Kastrup wrote:
> 
> [...]
> 
> > (defun get-number-of-file-buffers ()
> >   (interactive)
> >   (let ((num 0))
> >     (dolist (buf (buffer-list) num)
> >       (when (buffer-file-name buf)
> >           (setq num (1+ num))))))
> 
> Assuming cl is loaded:
> 
> (defun get-number-of-file-buffers ()
>   (loop for b in (buffer-list) count (buffer-file-name b)))
> 

Wel, if we want to squeeze characters of source, we can do so without
cl, too.

(defun get-number-of-file-buffers ()
  (apply '+ (mapcar (lambda(x)(if(buffer-file-name x)1 0)) (buffer-list))))



-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum

Re: Number of open buffers?

[Johan Bockgård]

David Kastrup <dak@gnu.org> writes:

> Somewhat shorter:
>
> (defun get-number-of-file-buffers ()
>   (interactive)
>   (let ((num 0))
>     (dolist (buf (buffer-list) num)
>       (when (buffer-file-name buf)
>           (setq num (1+ num))))))

If you are allowed to use `cl':

    ...
    (count-if 'buffer-file-name (buffer-list))

-- 
Johan Bockgård

Re: Number of open buffers?

[lawrence mitchell]

David Kastrup wrote:

[...]

> Wel, if we want to squeeze characters of source, we can do so without
> cl, too.

> (defun get-number-of-file-buffers ()
>   (apply '+ (mapcar (lambda(x)(if(buffer-file-name x)1 0)) (buffer-list))))

I see your apply and raise you a:

(defun get-number-of-file-buffers ()
  (length (delq nil (mapcar 'buffer-file-name (buffer-list)))))

:P
-- 
lawrence mitchell <wence@gmx.li>

Re: Number of open buffers?

[David Kastrup]

lawrence mitchell <wence@gmx.li> writes:

> David Kastrup wrote:
> 
> [...]
> 
> > Wel, if we want to squeeze characters of source, we can do so without
> > cl, too.
> 
> > (defun get-number-of-file-buffers ()
> >   (apply '+ (mapcar (lambda(x)(if(buffer-file-name x)1 0)) (buffer-list))))
> 
> I see your apply and raise you a:
> 
> (defun get-number-of-file-buffers ()
>   (length (delq nil (mapcar 'buffer-file-name (buffer-list)))))

I was looking for something like that, but the delq escaped me.

-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum

Re: Number of open buffers?

[David Kastrup]

Ignoramus15351 <ignoramus15351@NOSPAM.15351.invalid> writes:

> people, thank you, you are all beautiful.
> 
> The following works like a charm:
> 
> (defun get-number-of-file-buffers ()
>   (interactive)

Delete the (interactive) line: the function does nothing useful when
called interactively and thus should not clutter up command
completion.

>   (let (num)
>     (setq num 0)
>     (dolist (buf (buffer-list))
>       (when (buffer-file-name buf)
>         (setq num (+ num 1))
>         ))
>     num
>     )
>   )

Pffft.  The most verbose version.

-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum

Re: Number of open buffers?

[Stefan Monnier]

> (insert (get-number-of-file-buffers))
> should do the trick, the functions are surrounded by parens :)

Not the functions: the function *calls*.


        Stefan

Re: Number of open buffers?

[Lucas]

> Not the functions: the function *calls*.

Yeah, that's what i wanted to say.

-- 
Lucas