Re: master 39e3fce0d5e0: 'read-passwd' can toggle the visibility of passwords

[Stefan Monnier <monnier@iro.umontreal.ca>]

> No, it makes things worse:
>
>   In read-passwd-mode:
>   simple.el:10907:16: Warning: reference to free variable `read-passwd--show-password-icon'
>   simple.el:10912:12: Warning: reference to free variable `mode-line-faces'
>   simple.el:10915:4: Error: `define-icon' defined after use in (define-icon
> read-passwd--hide-password-icon nil '((image "conceal.svg"
> "conceal.pbm" :height (0.8 . em)) (symbol " ") (text "<\\>")) "Mode line
> icon to hide a visible password." :group mode-line-faces :version
> "30.1" :help-echo "mouse-1: Toggle password visibility") (missing `require'
> of a library file?)
>   simple.el:10915:16: Warning: reference to free variable `read-passwd--hide-password-icon'
>
>   In end of data:
>   simple.el:10907:4: Warning: the function `define-icon' might not be defined at runtime.
>   simple.el:10883:19: Warning: the function `icon-string' might not be defined at runtime.
>   Makefile:289: recipe for target `../lisp/simple.elc' failed

Ah, right: the code as written only works if there's a warning earlier,
because it uses `define-icon` inside a function and that macro is
defined in `icons` and is not autoloaded, so the only reason it
currently works is that `display-warning` loads `icons`: as soon as we
fix the warning, the core problem shows up.

The hideous patch below should result in working code without warnings,
but I hope we can find a better solution (e.g. one that lets us move
the two `define-icon`s to the toplevel of some file rather than being
inside a function).


        Stefan


diff --git a/lisp/simple.el b/lisp/simple.el
index 0645f18cc78..5ce3e27e99b 100644
--- a/lisp/simple.el
+++ b/lisp/simple.el
@@ -10873,6 +10873,9 @@ read-passwd-toggle-visibility
   "Toggle minibuffer contents visibility.
 Adapt also mode line."
   (interactive)
+  (require 'icons) ;; Should usually be loaded already.
+  (defvar icon-preference)
+  (declare-function icon-string "icons" (name))
   (setq read-passwd--hide-password (not read-passwd--hide-password))
   (with-current-buffer read-passwd--mode-line-buffer
     (setq read-passwd--mode-line-icon
@@ -10902,22 +10905,25 @@ read-passwd-mode
   ;; no corresponding Unicode char with a slash.  So we use symbols as
   ;; fallback only, with "⦵" ("\N{CIRCLE WITH HORIZONTAL BAR}") for
   ;; hiding the password.
-  (define-icon read-passwd--show-password-icon nil
-    '((image "reveal.svg" "reveal.pbm" :height (0.8 . em))
-      (symbol "👁")
-      (text "<o>"))
-    "Mode line icon to show a hidden password."
-    :group mode-line-faces
-    :version "30.1"
-    :help-echo "mouse-1: Toggle password visibility")
-  (define-icon read-passwd--hide-password-icon nil
-    '((image "conceal.svg" "conceal.pbm" :height (0.8 . em))
-      (symbol "⦵")
-      (text "<\\>"))
-    "Mode line icon to hide a visible password."
-    :group mode-line-faces
-    :version "30.1"
-    :help-echo "mouse-1: Toggle password visibility")
+  (eval
+   '(progn
+      (define-icon read-passwd--show-password-icon nil
+        '((image "reveal.svg" "reveal.pbm" :height (0.8 . em))
+          (symbol "👁")
+          (text "<o>"))
+        "Mode line icon to show a hidden password."
+        :group mode-line-faces
+        :version "30.1"
+        :help-echo "mouse-1: Toggle password visibility")
+      (define-icon read-passwd--hide-password-icon nil
+        '((image "conceal.svg" "conceal.pbm" :height (0.8 . em))
+          (symbol "⦵")
+          (text "<\\>"))
+        "Mode line icon to hide a visible password."
+        :group mode-line-faces
+        :version "30.1"
+        :help-echo "mouse-1: Toggle password visibility"))
+   t)
 
   (setq read-passwd--hide-password nil
         ;; Stolen from `eldoc-minibuffer-message'.