Where is ewoc--node-delete

Where is ewoc--node-delete

[Stefan Reichör]

Hi!

Why was ewoc--node-delete removed?

>From ewoc.el:
;; An ewoc is a very dynamic thing.  You can easily add or delete elements.
;; You can apply a function to all elements in an ewoc, etc, etc.

So, how can one now remove a node?


Stefan.

Re: Where is ewoc--node-delete

[Thien-Thi Nguyen]

Stefan Reichör <stefan@xsteve.at> writes:

> Why was ewoc--node-delete removed?

it was merged into its unique caller, the rationale being
that "internal" (i.e., "ewoc--" -- note double hyphen) interfaces
should not be multiplied needlessly.
 
> So, how can one now remove a node?

you can use `ewoc-filter' to remove nodes.  for example:

(defun my-delete-nodes-with-data (ewoc data)
  (ewoc-filter ewoc (lambda (d) (not (eq data d)))))

if your program is calling `ewoc--node-delete' within a loop,
that is a good chance to restructure it to let `ewoc-filter'
do the looping.

if not, perhaps it would be best to add `ewoc-delete-node'
w/ the body of the former `ewoc--node-delete'.

thi

Re: Where is ewoc--node-delete

[Stefan Reichör]

Thien-Thi Nguyen <ttn@gnu.org> writes:

> Stefan Reichör <stefan@xsteve.at> writes:
>
>> Why was ewoc--node-delete removed?
>
> it was merged into its unique caller, the rationale being
> that "internal" (i.e., "ewoc--" -- note double hyphen) interfaces
> should not be multiplied needlessly.
>  
>> So, how can one now remove a node?
>
> you can use `ewoc-filter' to remove nodes.  for example:
>
> (defun my-delete-nodes-with-data (ewoc data)
>   (ewoc-filter ewoc (lambda (d) (not (eq data d)))))
>
> if your program is calling `ewoc--node-delete' within a loop,
> that is a good chance to restructure it to let `ewoc-filter'
> do the looping.
>
> if not, perhaps it would be best to add `ewoc-delete-node'
> w/ the body of the former `ewoc--node-delete'.

I think the ewoc-delete-node is missing.
One could use the ewoc-filter trick above, but it is not the obvious
way to delete a node.

So please (re)add ewoc-delete-node.


Stefan.

Re: Where is ewoc--node-delete

[Thien-Thi Nguyen]

Stefan Reichör <stefan@xsteve.at> writes:

> I think the ewoc-delete-node is missing.  One could
> use the ewoc-filter trick above, but it is not the
> obvious way to delete a node.
> 
> So please (re)add ewoc-delete-node.

i think it is better to avoid introducing "ewoc-delete-node"
for now, if we can.  can you use the `ewoc-filter' (below),
instead?  here is an "ewoc-delete-node" implementation
that uses it:

(defun ewoc-delete-node (ewoc node)
  (ewoc-filter ewoc t node))

thi


_____________________________________________________
(defun ewoc-filter (ewoc predicate &rest args)
  "Remove all elements in EWOC for which PREDICATE returns nil.
Note that the buffer for EWOC will be current-buffer when PREDICATE
is called.  PREDICATE must restore the current buffer before it returns
if it changes it.
The PREDICATE is called with the element as its first argument.  If any
ARGS are given they will be passed to the PREDICATE.
As a special case, if PREDICATE is t, ARGS specifies nodes to be
deleted unconditionally."
  (ewoc--set-buffer-bind-dll-let* ewoc
      ((node (ewoc--node-nth dll 1))
       (footer (ewoc--footer ewoc))
       (next nil)
       (L nil) (R nil)
       (goodbye nil)
       (inhibit-read-only t))
    (cond ((eq t predicate)
           (setq goodbye args))
          (t (while (not (eq node footer))
               (setq next (ewoc--node-next dll node))
               (unless (apply predicate (ewoc--node-data node) args)
                 (push node goodbye))
               (setq node next))))
    (dolist (node goodbye)
      ;; If we are about to delete the node pointed at by last-node,
      ;; set last-node to nil.
      (if (eq (ewoc--last-node ewoc) node)
          (setf (ewoc--last-node ewoc) nil))
      (delete-region (ewoc--node-start-marker node)
                     (ewoc--node-start-marker (ewoc--node-next dll node)))
      (set-marker (ewoc--node-start-marker node) nil)
      (setf L (ewoc--node-left  node)
            R (ewoc--node-right node)
            ;; Link neighbors to each other.
            (ewoc--node-right L) R
            (ewoc--node-left  R) L
            ;; Forget neighbors.
            (ewoc--node-left  node) nil
            (ewoc--node-right node) nil))))

Re: Where is ewoc--node-delete

[Stefan Monnier]

> As a special case, if PREDICATE is t, ARGS specifies nodes to be
> deleted unconditionally."

This is very ugly.


        Stefan

Re: Where is ewoc--node-delete

[David Kastrup]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

>> As a special case, if PREDICATE is t, ARGS specifies nodes to be
>> deleted unconditionally."
>
> This is very ugly.

Sort of what an XEmacs interface would look like...  At the very
least, we should have a wrapper to ewoc-filter doing that.

-- 
David Kastrup, Kriemhildstr. 15, 44793 Bochum

Re: Where is ewoc--node-delete

[Stefan Monnier]

>>> As a special case, if PREDICATE is t, ARGS specifies nodes to be
>>> deleted unconditionally."
>> 
>> This is very ugly.

> Sort of what an XEmacs interface would look like...  At the very
> least, we should have a wrapper to ewoc-filter doing that.

(ewoc-filter ewoc (lambda (node nodes) (not (memq node nodes))) nodes)


        Stefan

Re: Where is ewoc--node-delete

[Thien-Thi Nguyen]

Stefan Monnier <monnier@iro.umontreal.ca> writes:

> (ewoc-filter ewoc (lambda (node nodes) (not (memq node nodes))) nodes)

this would be great if the predicate were applied to each node,
rather than to each data element.

thi

Re: Where is ewoc--node-delete

[Thien-Thi Nguyen]

after some thought i have changed my mind and
now agree w/ a need for a function to delete nodes.

does the following give good results?

thi


__________________________________________
(defun ewoc-delete (ewoc &rest nodes)
  "Delete NODES from EWOC."
  (ewoc--set-buffer-bind-dll-let* ewoc
      ((L nil) (R nil))
    (dolist (node nodes)
      ;; If we are about to delete the node pointed at by last-node,
      ;; set last-node to nil.
      (if (eq (ewoc--last-node ewoc) node)
          (setf (ewoc--last-node ewoc) nil))
      (delete-region (ewoc--node-start-marker node)
                     (ewoc--node-start-marker (ewoc--node-next dll node)))
      (set-marker (ewoc--node-start-marker node) nil)
      (setf L (ewoc--node-left  node)
            R (ewoc--node-right node)
            ;; Link neighbors to each other.
            (ewoc--node-right L) R
            (ewoc--node-left  R) L
            ;; Forget neighbors.
            (ewoc--node-left  node) nil
            (ewoc--node-right node) nil))))

(defun ewoc-filter (ewoc predicate &rest args)
  "Remove all elements in EWOC for which PREDICATE returns nil.
Note that the buffer for EWOC will be current-buffer when PREDICATE
is called.  PREDICATE must restore the current buffer before it returns
if it changes it.
The PREDICATE is called with the element as its first argument.  If any
ARGS are given they will be passed to the PREDICATE."
  (ewoc--set-buffer-bind-dll-let* ewoc
      ((node (ewoc--node-nth dll 1))
       (footer (ewoc--footer ewoc))
       (goodbye nil)
       (inhibit-read-only t))
    (while (not (eq node footer))
      (unless (apply predicate (ewoc--node-data node) args)
        (push node goodbye))
      (setq node (ewoc--node-next dll node)))
    (apply 'ewoc-delete ewoc goodbye)))