Re: [Old patch] Unify fn and var help to make learning elisp a little easier

[Kelly Dean <kelly@prtime.org>]

[-- Attachment #1: Type: text/plain, Size: 490 bytes --]

Artur Malabarba wrote:
> Not yet, but I haven't forgotten about it. It just didn't apply
> cleanly and I haven't had time to look into it.
>
> Would you like to recreate the patch from current master?
>
>
> Here's the apply output
>
> $ git apply descfunorvar.patch
> error: patch failed: lisp/help.el:215
> error: lisp/help.el: patch does not apply

That's just Git being stupid. The «patch» program works fine.

Updated patch attached below so even Git can handle it.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: descfunorvar-trunk.patch --]
[-- Type: text/x-diff, Size: 3297 bytes --]

--- lisp/help-fns.el
+++ lisp/help-fns.el
@@ -930,6 +930,37 @@
 
 
 ;;;###autoload
+(defun describe-function-or-variable (symbol &optional buffer frame)
+  "Display the full documentation of the function or variable SYMBOL.
+If SYMBOL is a variable and has a buffer-local value in BUFFER or FRAME
+\(default to the current buffer and current frame), it is displayed along
+with the global value."
+  (interactive
+   (let* ((v-or-f (variable-at-point))
+	 (found (symbolp v-or-f))
+	 (v-or-f (if found v-or-f (function-called-at-point)))
+	 (found (or found v-or-f))
+	 (enable-recursive-minibuffers t)
+	 val)
+     (setq val (completing-read (if found
+				    (format
+				     "Describe function or variable (default %s): " v-or-f)
+				  "Describe function or variable: ")
+				obarray
+				(lambda (vv)
+				  (or (fboundp vv)
+				      (get vv 'variable-documentation)
+				      (and (boundp vv) (not (keywordp vv)))))
+				t nil nil
+				(if found (symbol-name v-or-f))))
+     (list (if (equal val "")
+	       v-or-f (intern val)))))
+  (if (not (symbolp symbol)) (message "You didn't specify a function or variable")
+    (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
+    (unless (frame-live-p frame) (setq frame (selected-frame)))
+    (help-xref-interned symbol buffer frame)))
+
+;;;###autoload
 (defun describe-syntax (&optional buffer)
   "Describe the syntax specifications in the syntax table of BUFFER.
 The descriptions are inserted in a help buffer, which is then displayed.
--- lisp/help-mode.el
+++ lisp/help-mode.el
@@ -621,10 +621,13 @@
 
 \f
 ;; Additional functions for (re-)creating types of help buffers.
-(defun help-xref-interned (symbol)
+
+;;;###autoload
+(defun help-xref-interned (symbol &optional buffer frame)
   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 Both variable, function and face documentation are extracted into a single
-help buffer."
+help buffer. If SYMBOL is a variable, include buffer-local value for optional
+BUFFER or FRAME."
   (with-current-buffer (help-buffer)
     ;; Push the previous item on the stack before clobbering the output buffer.
     (help-setup-xref nil nil)
@@ -640,7 +643,7 @@
 			  (get symbol 'variable-documentation))
 		  ;; Don't record the current entry in the stack.
 		  (setq help-xref-stack-item nil)
-		  (describe-variable symbol))))
+		  (describe-variable symbol buffer frame))))
       (cond
        (sdoc
 	;; We now have a help buffer on the variable.
--- lisp/help.el
+++ lisp/help.el
@@ -95,6 +95,7 @@
     (define-key map "k" 'describe-key)
     (define-key map "l" 'view-lossage)
     (define-key map "m" 'describe-mode)
+    (define-key map "o" 'describe-function-or-variable)
     (define-key map "n" 'view-emacs-news)
     (define-key map "p" 'finder-by-keyword)
     (define-key map "P" 'describe-package)
@@ -218,6 +219,7 @@
 m           Display documentation of current minor modes and current major mode,
               including their special commands.
 n           Display news of recent Emacs changes.
+o SYMBOL    Display the given function or variable's documentation and value.
 p TOPIC     Find packages matching a given topic keyword.
 P PACKAGE   Describe the given Emacs Lisp package.
 r           Display the Emacs manual in Info mode.