Gnus and No Gnus

Gnus and No Gnus

[Katsumi Yamaoka]

[-- Attachment #1: Type: text/plain, Size: 791 bytes --]

Hi,

Today I tried synch'ing the Gnus trunk with the Emacs trunk and
found a problem concerning `float-time'.

In time-date.el, `define-obsolete-function-alias' is not available
in Emacs 21 that Gnus still supports.  It causes an error when
loading gnus-load.el.

In ecomplete.el, gnus-util.el and time-date.el, (featurep 'xemacs)
is used for checking if `float-time' is available like this:

  (if (featurep 'xemacs)
      (time-to-seconds time)
    (float-time time))

However, XEmacs may implement `float-time' in the future.

Therefore I made changes in those files as attached below.  WDYT?
The whole patch that synch the Gnus trunk with the Emacs trunk is:

ftp://ftp.jpl.org/pub/tmp/Gnus-Emacs-20090907.diff.gz
of http://www.jpl.org/ftp/pub/tmp/Gnus-Emacs-20090907.diff.gz

Regards,


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: Type: text/x-patch, Size: 4003 bytes --]

*** lisp/calendar/time-date.el~	2009-09-02 21:50:25 +0000
--- lisp/calendar/time-date.el	2009-09-07 11:55:15 +0000
***************
*** 114,130 ****
  ;; Bit of a mess.  Emacs has float-time since at least 21.1.
  ;; This file is synced to Gnus, and XEmacs packages may have been written
  ;; using time-to-seconds from the Gnus library.
! ;;;###autoload(if (featurep 'xemacs)
! ;;;###autoload     (autoload 'time-to-seconds "time-date")
! ;;;###autoload   (define-obsolete-function-alias 'time-to-seconds 'float-time "21.1"))
! 
! (if (featurep 'xemacs)
!     (defun time-to-seconds (time)
!       "Convert time value TIME to a floating point number."
!       (with-decoded-time-value ((high low micro time))
!         (+ (* 1.0 high 65536)
!            low
!            (/ micro 1000000.0)))))
  
  ;;;###autoload
  (defun seconds-to-time (seconds)
--- 114,132 ----
  ;; Bit of a mess.  Emacs has float-time since at least 21.1.
  ;; This file is synced to Gnus, and XEmacs packages may have been written
  ;; using time-to-seconds from the Gnus library.
! ;;;###autoload(if (fboundp 'float-time)
! ;;;###autoload    (progn
! ;;;###autoload      (defalias 'time-to-seconds 'float-time)
! ;;;###autoload      (make-obsolete 'time-to-seconds 'float-time "21.1"))
! ;;;###autoload  (autoload 'time-to-seconds "time-date"))
! 
! (unless (fboundp 'float-time)
!   (defun time-to-seconds (time)
!     "Convert time value TIME to a floating point number."
!     (with-decoded-time-value ((high low micro time))
!       (+ (* 1.0 high 65536)
! 	 low
! 	 (/ micro 1000000.0)))))
  
  ;;;###autoload
  (defun seconds-to-time (seconds)
***************
*** 251,259 ****
  (defun time-to-number-of-days (time)
    "Return the number of days represented by TIME.
  The number of days will be returned as a floating point number."
!   (/ (if (featurep 'xemacs)
!          (time-to-seconds time)
!        (float-time time)) (* 60 60 24)))
  
  ;;;###autoload
  (defun safe-date-to-time (date)
--- 253,262 ----
  (defun time-to-number-of-days (time)
    "Return the number of days represented by TIME.
  The number of days will be returned as a floating point number."
!   (/ (if (fboundp 'float-time)
! 	 (float-time time)
!        (time-to-seconds time))
!      (* 60 60 24)))
  
  ;;;###autoload
  (defun safe-date-to-time (date)
*** lisp/gnus/ecomplete.el~	2009-09-02 21:50:26 +0000
--- lisp/gnus/ecomplete.el	2009-09-07 11:55:15 +0000
***************
*** 56,64 ****
  (defun ecomplete-add-item (type key text)
    (let ((elems (assq type ecomplete-database))
  	(now (string-to-number
! 	      (format "%.0f" (if (featurep 'xemacs)
! 				 (time-to-seconds (current-time))
! 			       (float-time)))))
  	entry)
      (unless elems
        (push (setq elems (list type)) ecomplete-database))
--- 56,64 ----
  (defun ecomplete-add-item (type key text)
    (let ((elems (assq type ecomplete-database))
  	(now (string-to-number
! 	      (format "%.0f" (if (fboundp 'float-time)
! 				 (float-time)
! 			       (time-to-seconds (current-time))))))
  	entry)
      (unless elems
        (push (setq elems (list type)) ecomplete-database))
*** lisp/gnus/gnus-util.el~	2009-09-02 21:50:26 +0000
--- lisp/gnus/gnus-util.el	2009-09-07 11:55:15 +0000
***************
*** 285,296 ****
  	(and (= (car fdate) (car date))
  	     (> (nth 1 fdate) (nth 1 date))))))
  
! (defun gnus-float-time (&optional time)
!   "Convert time value TIME to a floating point number.
  TIME defaults to the current time."
!   (if (featurep 'xemacs)
!       (time-to-seconds (or time (current-time)))
!     (float-time time)))
  
  ;;; Keymap macros.
  
--- 285,296 ----
  	(and (= (car fdate) (car date))
  	     (> (nth 1 fdate) (nth 1 date))))))
  
! (if (fboundp 'float-time)
!     (defalias 'gnus-float-time 'float-time)
!   (defun gnus-float-time (&optional time)
!     "Convert time value TIME to a floating point number.
  TIME defaults to the current time."
!     (time-to-seconds (or time (current-time)))))
  
  ;;; Keymap macros.
  

Re: Gnus and No Gnus

[Glenn Morris]

Katsumi Yamaoka wrote:

> Today I tried synch'ing the Gnus trunk with the Emacs trunk and
> found a problem concerning `float-time'.

Sorry, I did my best to think about these issues.

> In time-date.el, `define-obsolete-function-alias' is not available
> in Emacs 21 that Gnus still supports.  It causes an error when
> loading gnus-load.el.

I'm not suggesting this as a solution to this issue, but does the very
latest Gnus really need to run on 3 major versions of Emacs? When are
you going to drop support for Emacs 21?

> In ecomplete.el, gnus-util.el and time-date.el, (featurep 'xemacs)
> is used for checking if `float-time' is available like this:
>
>   (if (featurep 'xemacs)
>       (time-to-seconds time)
>     (float-time time))
>
> However, XEmacs may implement `float-time' in the future.

I used featurep in preference to fboundp to avoid compilation
warnings, and so that the compiler could optimise the test away.

> Therefore I made changes in those files as attached below.  WDYT?

Fine. I would then stick a with-no-warnings around every use of
time-to-seconds, and an eval-and-compile around the revised definition
of gnus-float-time.

Re: Gnus and No Gnus

[Stephen J. Turnbull]

Glenn Morris writes:

 > I'm not suggesting this as a solution to this issue, but does the very
 > latest Gnus really need to run on 3 major versions of Emacs?

Polls of corporate Emacs users (the last one I've seen was about
October 2007) showed that about 1% use Emacs 18, about 10% use Emacs
19 or Lucid 19, about 20% using Emacs 20 or XEmacs 20.  I forget what
current Emacs was at that time, but by extrapolating I suspect there
are indeed a lot of people still using Emacs 21 out there today.

I can look up the details if you like, but it's disappeared from
my "current XEmacs" folder so I'm working from memory.

Re: Gnus and No Gnus

[Teemu Likonen]

On 2009-09-08 11:15 (+0900), Stephen J. Turnbull wrote:

> Polls of corporate Emacs users (the last one I've seen was about
> October 2007) showed that about 1% use Emacs 18, about 10% use Emacs
> 19 or Lucid 19, about 20% using Emacs 20 or XEmacs 20.  I forget what
> current Emacs was at that time, but by extrapolating I suspect there
> are indeed a lot of people still using Emacs 21 out there today.

Yes, Emacs 21 is still used. This is what Debian popularity contest
graph shows:

http://qa.debian.org/popcon-graph.php?packages=emacs22-bin-common%2Cemacs23-bin-common%2Cemacs21-bin-common%2Cxemacs21-mule&show_vote=on&want_legend=on&from_date=&to_date=&hlght_date=&date_fmt=%25Y-%25m&beenhere=1

Debian Sid (the unstable development branch) does not have Emacs 21
anymore so I guess it will be dropped from next Debian release.

Re: Gnus and No Gnus

[Steinar Bang]

>>>>> Teemu Likonen <tlikonen@iki.fi>:

> On 2009-09-08 11:15 (+0900), Stephen J. Turnbull wrote:
>> Polls of corporate Emacs users (the last one I've seen was about
>> October 2007) showed that about 1% use Emacs 18, about 10% use Emacs
>> 19 or Lucid 19, about 20% using Emacs 20 or XEmacs 20.  I forget what
>> current Emacs was at that time, but by extrapolating I suspect there
>> are indeed a lot of people still using Emacs 21 out there today.

> Yes, Emacs 21 is still used. This is what Debian popularity contest
> graph shows:

> http://qa.debian.org/popcon-graph.php?packages=emacs22-bin-common%2Cemacs23-bin-common%2Cemacs21-bin-common%2Cxemacs21-mule&show_vote=on&want_legend=on&from_date=&to_date=&hlght_date=&date_fmt=%25Y-%25m&beenhere=1

> Debian Sid (the unstable development branch) does not have Emacs 21
> anymore so I guess it will be dropped from next Debian release.

Emacs 21 is the default emacs installed on RHEL4 machines, and there are
quite a few of them around, and they will probably be around for quite a
while.

Re: Gnus and No Gnus

[Glenn Morris]

"Stephen J. Turnbull" wrote:

> Polls of corporate Emacs users (the last one I've seen was about
> October 2007) showed that about 1% use Emacs 18, about 10% use Emacs
> 19 or Lucid 19, about 20% using Emacs 20 or XEmacs 20.  I forget what
> current Emacs was at that time, but by extrapolating I suspect there
> are indeed a lot of people still using Emacs 21 out there today.

Sure, people use old versions of Emacs. But do they need to run the
latest version of whatever-mode in those old versions? Personally, I
have no problem saying "sorry, you must upgrade to use the latest
awesome-mode.el".

Re: Gnus and No Gnus

[Steinar Bang]

>>>>> Glenn Morris <rgm@gnu.org>:

> Sure, people use old versions of Emacs. But do they need to run the
> latest version of whatever-mode in those old versions?

Some people running Gnus in Emacs 21 on RHEL4 systems, have been running
CVS Gnus from the late nineties, and would like to continue to do so.

> Personally, I have no problem saying "sorry, you must upgrade to use
> the latest awesome-mode.el".

I have a problem with it, if this precludes me from continuing to run
CVS Gnus.

Re: Gnus and No Gnus

[Ted Zlatanov]

On Tue, 15 Sep 2009 10:13:44 +0200 Steinar Bang <sb@dod.no> wrote: 

>>>>>> Glenn Morris <rgm@gnu.org>:
>> Personally, I have no problem saying "sorry, you must upgrade to use
>> the latest awesome-mode.el".

SB> I have a problem with it, if this precludes me from continuing to run
SB> CVS Gnus.

Maybe it's acceptable for optional features, though, which is what I
think Glenn meant.

Ted

Re: Gnus and No Gnus

[Katsumi Yamaoka]

[-- Attachment #1: Type: text/plain, Size: 1944 bytes --]

>>>>> Glenn Morris wrote:
> Katsumi Yamaoka wrote:

>> Today I tried synch'ing the Gnus trunk with the Emacs trunk and
>> found a problem concerning `float-time'.

> Sorry, I did my best to think about these issues.

>> In time-date.el, `define-obsolete-function-alias' is not available
>> in Emacs 21 that Gnus still supports.  It causes an error when
>> loading gnus-load.el.

> I'm not suggesting this as a solution to this issue, but does the very
> latest Gnus really need to run on 3 major versions of Emacs? When are
> you going to drop support for Emacs 21?

Basically I'm positive to drop old Emacsen.  It seems enough to
support the latest major version and one predecessor.  Those who
use Emacs 21 may perhaps not want to work on upgrading Gnus.
But in another thought, we don't have so much difficulty in
supporting Emacs 21 for the present.  Therefore I think it's not
time to drop Emacs 21.

>> In ecomplete.el, gnus-util.el and time-date.el, (featurep 'xemacs)
>> is used for checking if `float-time' is available like this:
>>
>>   (if (featurep 'xemacs)
>>       (time-to-seconds time)
>>     (float-time time))
>>
>> However, XEmacs may implement `float-time' in the future.

> I used featurep in preference to fboundp to avoid compilation
> warnings, and so that the compiler could optimise the test away.

Yes, I knew it.  (featurep 'xemacs) is useful in Emacs 22, 23
and XEmacs 21.5, so I hesitated to replace it with `fboundp'.
But it looks easy to provide `float-time' in XEmacs.

>> Therefore I made changes in those files as attached below.  WDYT?

> Fine. I would then stick a with-no-warnings around every use of
> time-to-seconds, and an eval-and-compile around the revised definition
> of gnus-float-time.

Unfortunately `with-no-warnings' is not available in Emacs 21
and XEmacs.  How about using macros like the following?  (For
warnings that old Emacsen and XEmacs issue, we can use lpath.el
and dgnushack.el.)


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: Type: text/x-patch, Size: 4867 bytes --]

*** lisp/calendar/time-date.el~	2009-09-02 21:50:25 +0000
--- lisp/calendar/time-date.el	2009-09-08 04:53:21 +0000
***************
*** 114,130 ****
  ;; Bit of a mess.  Emacs has float-time since at least 21.1.
  ;; This file is synced to Gnus, and XEmacs packages may have been written
  ;; using time-to-seconds from the Gnus library.
! ;;;###autoload(if (featurep 'xemacs)
! ;;;###autoload     (autoload 'time-to-seconds "time-date")
! ;;;###autoload   (define-obsolete-function-alias 'time-to-seconds 'float-time "21.1"))
! 
! (if (featurep 'xemacs)
!     (defun time-to-seconds (time)
!       "Convert time value TIME to a floating point number."
!       (with-decoded-time-value ((high low micro time))
!         (+ (* 1.0 high 65536)
!            low
!            (/ micro 1000000.0)))))
  
  ;;;###autoload
  (defun seconds-to-time (seconds)
--- 114,132 ----
  ;; Bit of a mess.  Emacs has float-time since at least 21.1.
  ;; This file is synced to Gnus, and XEmacs packages may have been written
  ;; using time-to-seconds from the Gnus library.
! ;;;###autoload(if (fboundp 'float-time)
! ;;;###autoload    (progn
! ;;;###autoload      (defalias 'time-to-seconds 'float-time)
! ;;;###autoload      (make-obsolete 'time-to-seconds 'float-time "21.1"))
! ;;;###autoload  (autoload 'time-to-seconds "time-date"))
! 
! (unless (fboundp 'float-time)
!   (defun time-to-seconds (time)
!     "Convert time value TIME to a floating point number."
!     (with-decoded-time-value ((high low micro time))
!       (+ (* 1.0 high 65536)
! 	 low
! 	 (/ micro 1000000.0)))))
  
  ;;;###autoload
  (defun seconds-to-time (seconds)
***************
*** 248,259 ****
         (- (/ (1- year) 100))		;	- century years
         (/ (1- year) 400))))		;	+ Gregorian leap years
  
  (defun time-to-number-of-days (time)
    "Return the number of days represented by TIME.
  The number of days will be returned as a floating point number."
!   (/ (if (featurep 'xemacs)
!          (time-to-seconds time)
!        (float-time time)) (* 60 60 24)))
  
  ;;;###autoload
  (defun safe-date-to-time (date)
--- 250,266 ----
         (- (/ (1- year) 100))		;	- century years
         (/ (1- year) 400))))		;	+ Gregorian leap years
  
+ (eval-when-compile
+   (defmacro time-date-float-time (time)
+     (if (and (fboundp 'float-time)
+ 	     (subrp (symbol-function 'float-time)))
+ 	`(float-time ,time)
+       `(time-to-seconds (or ,time (current-time))))))
+ 
  (defun time-to-number-of-days (time)
    "Return the number of days represented by TIME.
  The number of days will be returned as a floating point number."
!   (/ (time-date-float-time time) (* 60 60 24)))
  
  ;;;###autoload
  (defun safe-date-to-time (date)
*** lisp/gnus/ecomplete.el~	2009-09-02 21:50:26 +0000
--- lisp/gnus/ecomplete.el	2009-09-08 04:53:21 +0000
***************
*** 53,64 ****
  	(insert-file-contents ecomplete-database-file)
  	(setq ecomplete-database (read (current-buffer)))))))
  
  (defun ecomplete-add-item (type key text)
    (let ((elems (assq type ecomplete-database))
! 	(now (string-to-number
! 	      (format "%.0f" (if (featurep 'xemacs)
! 				 (time-to-seconds (current-time))
! 			       (float-time)))))
  	entry)
      (unless elems
        (push (setq elems (list type)) ecomplete-database))
--- 53,68 ----
  	(insert-file-contents ecomplete-database-file)
  	(setq ecomplete-database (read (current-buffer)))))))
  
+ (eval-when-compile
+   (defmacro ecomplete-float-time ()
+     (if (and (fboundp 'float-time)
+ 	     (subrp (symbol-function 'float-time)))
+ 	'(float-time)
+       '(time-to-seconds (current-time)))))
+ 
  (defun ecomplete-add-item (type key text)
    (let ((elems (assq type ecomplete-database))
! 	(now (string-to-number (format "%.0f" (ecomplete-float-time))))
  	entry)
      (unless elems
        (push (setq elems (list type)) ecomplete-database))
*** lisp/gnus/gnus-util.el~	2009-09-02 21:50:26 +0000
--- lisp/gnus/gnus-util.el	2009-09-08 04:53:21 +0000
***************
*** 285,296 ****
  	(and (= (car fdate) (car date))
  	     (> (nth 1 fdate) (nth 1 date))))))
  
  (defun gnus-float-time (&optional time)
    "Convert time value TIME to a floating point number.
  TIME defaults to the current time."
!   (if (featurep 'xemacs)
!       (time-to-seconds (or time (current-time)))
!     (float-time time)))
  
  ;;; Keymap macros.
  
--- 285,301 ----
  	(and (= (car fdate) (car date))
  	     (> (nth 1 fdate) (nth 1 date))))))
  
+ (eval-when-compile
+   (defmacro gnus-float-time-1 (time)
+     (if (and (fboundp 'float-time)
+ 	     (subrp (symbol-function 'float-time)))
+ 	`(float-time ,time)
+       `(time-to-seconds (or ,time (current-time))))))
+ 
  (defun gnus-float-time (&optional time)
    "Convert time value TIME to a floating point number.
  TIME defaults to the current time."
!   (gnus-float-time-1 time))
  
  ;;; Keymap macros.
  

Re: Gnus and No Gnus

[Glenn Morris]

Katsumi Yamaoka wrote:

> Unfortunately `with-no-warnings' is not available in Emacs 21
> and XEmacs.

Argh...
Could you add a compat definition in Gnus? Just an alias to progn
should be fine.

Otherwise, I'd say it's up to you as to how complicated you are
willing to make the code just in order to suppress (let's face it,
harmless) warnings.

Re: Gnus and No Gnus

[Katsumi Yamaoka]

>>>>> Glenn Morris wrote:
> Katsumi Yamaoka wrote:

>> Unfortunately `with-no-warnings' is not available in Emacs 21
>> and XEmacs.

> Argh...
> Could you add a compat definition in Gnus? Just an alias to progn
> should be fine.

It will be possible to add a compat definition that replaces
`with-no-warnings' with `progn' when compiling to dgnushack.el
or whatever.  However, it disables people, who use XEmacs or
Emacs 21 to develop Gnus, from loading .el files.  So, it is
better to add it to every file which uses `with-no-warnings'.
Is it ok?

In that case, the definition should be made available only when
compiling (or when loading .el files) because `with-no-warnings'
should never be bound normally in XEmacs and Emacs 21.

(eval-when-compile
  (unless (fboundp 'with-no-warnings)
    (defmacro with-no-warnings (&rest body)
      `(progn ,@body))))

> Otherwise, I'd say it's up to you as to how complicated you are
> willing to make the code just in order to suppress (let's face it,
> harmless) warnings.

Yes, that is for *only* suppressing warnings, in place of
`with-no-warnings'.  Using neither the complicated things nor
`with-no-warnings' makes it simple, if we don't mind warnings
when bootstrapping Emacs.

Re: Gnus and No Gnus

[Glenn Morris]

Katsumi Yamaoka wrote:

> `with-no-warnings' with `progn' when compiling to dgnushack.el
> or whatever.  However, it disables people, who use XEmacs or
> Emacs 21 to develop Gnus, from loading .el files.  So, it is
> better to add it to every file which uses `with-no-warnings'.

Fine by me. It's only 2 or 3 files.

>  Using neither the complicated things nor `with-no-warnings' makes
> it simple, if we don't mind warnings when bootstrapping Emacs.

Please install whatever version you prefer, regardless of warnings.
Personally, I would just expand the define-obsolete-function-alias
macro (for Emacs 21), and leave the featurep test, since: i) it's
totally correct today; ii) it seems unlikely XEmacs will ever add
float-time; iii) even if it does, it does zero harm if Gnus keeps
using time-to-seconds there; and iv) since Gnus will want to support
older versions of XEmacs, you wont be able to remove time-to-seconds
for many years anyway.

Re: Gnus and No Gnus

[Stephen J. Turnbull]

Glenn Morris writes:

 > Please install whatever version you prefer, regardless of warnings.
 > Personally, I would just expand the define-obsolete-function-alias
 > macro (for Emacs 21), and leave the featurep test, since: i) it's
 > totally correct today; ii) it seems unlikely XEmacs will ever add
 > float-time;

Where *do* you get your information?  I had no idea!

 > iii) even if it does, it does zero harm if Gnus keeps
 > using time-to-seconds there; and iv) since Gnus will want to support
 > older versions of XEmacs, you wont be able to remove time-to-seconds
 > for many years anyway.

Ah, that turns out not to be the case.  It will go into a package,
probably xemacs-base, which means that older versions of XEmacs can
get it conveniently when they update Gnus.  It's not like it's needed
to bootstrap.

Re: Gnus and No Gnus

[Katsumi Yamaoka]

>>>>> Glenn Morris wrote:
> Please install whatever version you prefer, regardless of warnings.
> Personally, I would just expand the define-obsolete-function-alias
> macro (for Emacs 21), and leave the featurep test, since: i) it's
> totally correct today; ii) it seems unlikely XEmacs will ever add
> float-time; iii) even if it does, it does zero harm if Gnus keeps
> using time-to-seconds there; and iv) since Gnus will want to support
> older versions of XEmacs, you wont be able to remove time-to-seconds
> for many years anyway.

I've made changes in the Emacs trunk, and also have synch'd
the Emacs trunk and the Gnus trunk mutually.  Maybe it didn't
break the way you first brought about.  Thanks.

Re: Gnus and No Gnus

[Steinar Bang]

>>>>> Katsumi Yamaoka <yamaoka@jpl.org>:

> Basically I'm positive to drop old Emacsen.  It seems enough to
> support the latest major version and one predecessor.  Those who use
> Emacs 21 may perhaps not want to work on upgrading Gnus.  But in
> another thought, we don't have so much difficulty in supporting Emacs
> 21 for the present.  Therefore I think it's not time to drop Emacs 21.

I'm glad to hear it.

Re: Gnus and No Gnus

[Reiner Steib]

On Tue, Sep 08 2009, Katsumi Yamaoka wrote:

> Basically I'm positive to drop old Emacsen.  It seems enough to
> support the latest major version and one predecessor.  

I agree with this rule of thumb.

> Those who use Emacs 21 may perhaps not want to work on upgrading
> Gnus.  But in another thought, we don't have so much difficulty in
> supporting Emacs 21 for the present.  Therefore I think it's not
> time to drop Emacs 21.

Dropping support for Emacs 21 would - in many cases - also mean to
drop support for XEmacs 21.4, the latest stable XEmacs release.  IIRC
there are plans to sync from Emacs after XEmacs switches to GPLv3.

Bye, Reiner.
-- 
       ,,,
      (o o)
---ooO-(_)-Ooo---  |  PGP key available  |  http://rsteib.home.pages.de/