describe-bindings-in-map

describe-bindings-in-map

[Drew Adams]

Any interest in adding something like this to Emacs?
I use it quite often, especially since I often work with
minibuffer keymaps, which are a bit less accessible than most.

(defun describe-bindings-in-map (keymap)
  "Describe bindings in KEYMAP, a variable whose value is a keymap.
Completion is available for the keymap name."
  (interactive
   (list (intern
          (completing-read
           "Keymap: " obarray
           (lambda (m) (and (boundp m) (keymapp (symbol-value m))))
           t nil 'variable-history))))
  (unless (and (symbolp keymap)
               (boundp keymap)
               (keymapp (symbol-value keymap)))
    (error "`%S' is not a keymapp" keymap))
  (let ((name (symbol-name keymap)))
    (help-setup-xref (list #'describe-bindings-in-map keymap)
                     (interactive-p))
    (with-output-to-temp-buffer "*Help*"
      (princ name) (terpri)
      (princ (make-string (length name) ?-)) (terpri) (terpri)
      (princ (substitute-command-keys (concat "\\{" name "}"))))))


[BTW, I would also be interested in a command that pretty-prints a keymap,
showing its tree structure (inheritance etc.) but with character values
replaced by their human-readable strings. I haven't coded that, but if
someone has, please send it along.]

Re: describe-bindings-in-map

[Johan Bockgård]

"Drew Adams" <drew.adams@oracle.com> writes:

> Any interest in adding something like this to Emacs?

Yes. I have had (almost) this command in my .emacs for a long time. I
prefer the name `describe-[key]map' though, and I think that it should
also print the keymap's documentation (`(documentation-property keymap
'variable-documentation)').

-- 
Johan Bockgård

RE: describe-bindings-in-map

[Drew Adams]

> > Any interest in adding something like this to Emacs?
> 
> Yes. I have had (almost) this command in my .emacs for a long time. I
> prefer the name `describe-[key]map' though, and I think that it should
> also print the keymap's documentation (`(documentation-property keymap
> 'variable-documentation)').

Agreed on both counts:

(defun describe-keymap (keymap)
  "Describe bindings in KEYMAP, a variable whose value is a keymap.
Completion is available for the keymap name."
  (interactive
   (list (intern
          (completing-read
           "Keymap: " obarray
           (lambda (m) (and (boundp m) (keymapp (symbol-value m))))
           t nil 'variable-name-history))))
  (unless (and (symbolp keymap) (boundp keymap)
               (keymapp (symbol-value keymap)))
    (error "`%S' is not a keymapp" keymap))
  (let ((name (symbol-name keymap)))
    (help-setup-xref (list #'describe-keymap keymap)
                     (interactive-p))
    (with-output-to-temp-buffer "*Help*"
      (princ name) (terpri)
      (princ (make-string (length name) ?-)) (terpri) (terpri)
      (princ (documentation-property keymap 'variable-documentation))
      (terpri) (terpri)
      (princ (substitute-command-keys (concat "\\{" name "}"))))))