Re: master 68ae6fa: Improved light/dark colour predicate (bug#41544)

["Mattias Engdegård" <mattiase@acm.org>]

[-- Attachment #1: Type: text/plain, Size: 932 bytes --]

11 juni 2020 kl. 21.22 skrev Yuri Khan <yuri.v.khan@gmail.com>:

> My equipment [...] says that shade of gold in fact
> performs okay in all four scenarios

I have no reason to doubt your observations. Let's try a plebiscite!

                      * * *

Dear Emacs developer or user,

Please load the attached code (any Emacs version), and run M-x contrast-compare with various cutoff values on your favourite system, to find what value is best for readability of the colour names (first column).

Colours with luminance (last column) below the cutoff will be use white text, others black. It is mainly Emacs in graphical (non-TTY) mode that is of interest.

Please reply (to emacs-devel or to me) the following pieces of information:

* the cutoff value you found optimal
* system information: window system, screen, anything you think is relevant
* whether you use a light or dark background in your Emacs


[-- Attachment #2: color-contrast.el --]
[-- Type: application/octet-stream, Size: 1727 bytes --]

;;; -*- lexical-binding: t -*-

(defconst contrast-default-cutoff 0.325)

(defun contrast-compare (cutoff)
  "Compare black and white text on various colours."
  (interactive
   (list (string-to-number
          (read-from-minibuffer "Cutoff value: "
                                (number-to-string contrast-default-cutoff)))))

  (with-current-buffer (get-buffer-create "*Contrast comparison*")
    (erase-buffer)
    (let ((cols nil)
          (seen (make-hash-table :test 'equal)))
      (dolist (name (defined-colors))
        (let ((cv (color-values name)))
          (unless (gethash cv seen)
            (puthash cv cv seen)
            (push (cons cv name) cols))))
      (insert (format "cutoff = %f\n" cutoff))
      (dolist (c (reverse cols))
        (let* ((cv (car c))
               (name (cdr c))
               (hex (apply #'format "#%02x%02x%02x"
                           (mapcar (lambda (x) (/ x 256)) cv)))
               (rgb (mapcar (lambda (x) (/ x 65535.0)) cv))
               (r (expt (nth 0 rgb) 2.2))
               (g (expt (nth 1 rgb) 2.2))
               (b (expt (nth 2 rgb) 2.2))
               (y (+ (* r 0.2126) (* g 0.7152) (* b 0.0722)))
               (fg (if (< y cutoff) "#ffffff" "#000000")))
          (insert
           (propertize
            (format "  %-20.20s  " name)
            'face (list :background name :foreground fg))
           (propertize
            (format " %s " hex)
            'face (list :background name :foreground "#ffffff"))
           (propertize
            (format " %s " hex)
            'face (list :background name :foreground "#000000"))
           (format "  %.5f\n" y)))))
    (let ((pop-up-windows t))
      (display-buffer (current-buffer)))))