Modus themes toggle (was: night-mode?)

[Protesilaos Stavrou <info@protesilaos.com>]

[-- Attachment #1: Type: text/plain, Size: 1283 bytes --]

On 2020-11-21, 08:06 +0530, Pankaj Jangid <pankaj@codeisgreat.org> wrote:

> Stefan Monnier <monnier@iro.umontreal.ca> writes:
>
>> Based on previous discussions, I think we should add some way to toggle
>> the dark/light mode.  I'm not completely sure what the interface should
>> look like, nor what'd be the better implementation, but see the patch
>> below for a first cut to add a `night-mode` command, which does
>> basically the "inverse video" by swapping the foreground and the
>> background of the default face (and then resetting the background-mode
>> accordingly, of course).
>
> Your's is a more generic solution I guess. But after inclusion of
> `modus-themes', I just use this snippet,
>
> (defun modus-theme-toggle ()
>   "Toggle between modus-operandi and modus-vivendi themes."
>   (interactive)
>   (if (member 'modus-operandi custom-enabled-themes)
>       (progn
> 	(disable-theme 'modus-operandi)
> 	(load-theme 'modus-vivendi t))
>     (disable-theme 'modus-vivendi)
>     (load-theme 'modus-operandi t)))

Just to note that I am in the process of refactoring aspects of the
Modus themes.  There will be a toggle command on offer.  Please find the
current version of it attached (note that I may still change things).

-- 
Protesilaos Stavrou
protesilaos.com

[-- Attachment #2: modus-themes-toggle-tentative.el --]
[-- Type: text/plain, Size: 1345 bytes --]

(defvar modus-themes-after-load-theme-hook nil
  "Hook that runs after the `modus-themes-toggle' routines.")

(defun modus-themes--light ()
  "Load `modus-operandi' and disable `modus-vivendi'."
  (disable-theme 'modus-vivendi)
  (load-theme 'modus-operandi)
  (run-hooks 'modus-themes-after-load-theme-hook))

(defun modus-themes--dark ()
  "Load `modus-vivendi' and disable `modus-operandi'."
  (disable-theme 'modus-operandi)
  (load-theme 'modus-vivendi)
  (run-hooks 'modus-themes-after-load-theme-hook))

(defun modus-themes--load-prompt ()
  "Helper for `modus-themes-toggle'."
  (let ((theme
         (intern
          (completing-read "Load Modus theme (will disable all others): "
                           '(modus-operandi modus-vivendi) nil t))))
    (mapc #'disable-theme custom-enabled-themes)
    (pcase theme
      ('modus-operandi (modus-themes--light))
      ('modus-vivendi (modus-themes--dark)))))

;;;###autoload
(defun modus-themes-toggle ()
  "Toggle between `modus-operandi' and `modus-vivendi' themes.
Also runs `modus-themes-after-load-theme-hook' by virtue of
calling the internal `modus-themes--light' and
`modus-themes--dark' functions."
  (interactive)
  (pcase (car custom-enabled-themes)
    ('modus-operandi (modus-themes--dark))
    ('modus-vivendi (modus-themes--light))
    (_ (modus-themes--load-prompt))))