Getting to online manuals from Info [was: On being web-friendly...]

[Drew Adams <drew.adams@oracle.com>]

[-- Attachment #1: Type: text/plain, Size: 1714 bytes --]

> > I frequently point people to particular nodes of our online HTML
> > manuals that could answer their question.  The way I do that is
> > to find the information in Info, then copy&paste some recognizably
> > unique text phrase into a web search engine, check that the
> > reference this turns up is the corresponding online version of
> > the Info manual and then post the HTML link.
> 
> Same here.  Except I don't bother to search the web.  I just go
> to the GNU Emacs or Elisp manual on the web (separate HTML page
> per node version), search the TOC (first page) for the node name,
> and copy the URL of the link to that node.
> 
> I do this often.  Instead of just answering questions, it is
> most helpful to *point users to the doc*, so they get additional
> info and they get the benefit of well thought out presentation.
> 
> It is even more helpful to also to tell them how _they_ can find
> such doc, by *asking Emacs* directly.
> 
> Probably what I should do is write an Emacs command that does
> all of that from an Info node: grab the URL to that same manual
> node on the web.  But it's so quick to get it manually that I
> haven't bothered, so far.

FWIW, attached is simple POC code to do this.  It handles only
the Emacs and Elisp manuals, but it could be extended to other
GNU manuals.  (The main use case for me is that expressed above.)

Two commands, for use in Info:

`Info-url-for-node':  Prompts for a node name and returns a URL
                      to that node on line.  Interactively, it
                      copies the URL to the `kill-ring'.

`Info-goto-node-web': Prompts for a node name and goes to that
                      node on line.

[-- Attachment #2: throw-manual-web.el --]
[-- Type: application/octet-stream, Size: 2405 bytes --]

(defun Info-goto-node-web (node &optional flip-new-win)
  "Use `browse-url' to go to Info node NODE using a Web browser.
With a prefix arg, reverse the effect of option
option`browse-url-new-window-flag'.

NODE is the name of a node in the GNU Emacs or Elisp manual.
Alternatively, NODE can have the form (MANUAL)NODE, where MANUAL is
\"emacs\" or \"elisp\" and NODE is the name of the node in that
manual.  Empty NODE in (MANUAL) defaults to the `Top' node."
  (interactive (list (Info-read-node-name "Go to node: ") current-prefix-arg))
  ;; (info-initialize)
  (unless Info-current-file (error "This command must be invoked from Info"))
  (browse-url (Info-url-for-node node) (list (if flip-new-win
                                                 (not browse-url-new-window-flag)
                                               browse-url-new-window-flag))))

(defun Info-url-for-node (node &optional copy-as-kill)
  "Return a URL for NODE, a node in the GNU Emacs or Elisp manual.
Alternatively, NODE can have the form (MANUAL)NODE, where MANUAL is
\"emacs\" or \"elisp\" and NODE is the name of the node in that
manual.  Empty NODE in (MANUAL) defaults to the `Top' node.
Interactively, the URL is copied to `kill-ring', so you can yank it."
  (interactive (list (Info-read-node-name "Node: ") 'COPY))
  (unless Info-current-file (error "This command must be invoked from Info"))
  (let (file url)
    (string-match "\\s *\\((\\s *\\([^\t)]*\\)\\s *)\\s *\\|\\)\\(.*\\)" node)
    (setq file  (if (= (match-beginning 1) (match-end 1)) "" (match-string 2 node))
	  node  (match-string 3 node))
    (when (equal node "") (setq node  "index")) ; `Top' node.
    (let ((trim  (string-match "\\s +\\'" file)))
      (when trim (setq file (substring file 0 trim))))
    (let ((trim  (string-match "\\s +\\'" node)))
      (when trim (setq node (substring node 0 trim))))
    (when (equal file "") (setq file  Info-current-file))
    (setq file  (file-name-sans-extension (file-name-nondirectory file)))
    (unless (member file '("emacs" "elisp"))
      (error "Manual cannot be `%s'; it can only be `emacs' or `elisp'" file))
    (setq node  (replace-regexp-in-string "[ \t]+" "-" node t t)
          url       (concat "http://www.gnu.org/software/emacs/manual/html_node/"
                            file "/" node ".html"))
    (when copy-as-kill (kill-new url) (message "URL copied: %s" url))
    url))