Creating submenu

Creating submenu

[ken]

I'm trying to create a submenu (under Edit) for inserting non-English
characters.  I'd like this submenu to show keybindings as well... to
serve as reminders so I don't have to go to the menu all the time.
Finally, I'm defining a new prefix key, "C-c g" for the items in this
submenu.  I'd like this submenu to be operative in all major modes that
I'd be editing in.

Actually, after reading a few chapters in the elisp manual and examining
existing elisp code, I have come up with code that is working, but it
has some undesirable side-effects.  Here's what I have:

------------------------------------------------------------------
;Make ^C-cg a key prefix for chars menu
(global-set-key [?\C-c ?g] ctl-x-map)

;;Need this definition, else the main "define-key ..." below it errors.
(defvar menu-bar-chars-menu (make-sparse-keymap "chars"))

;This puts the "European chars" item into the "Edit" menu.
;;Function definition: (define-key keymap key def)
(define-key menu-bar-edit-menu [chars]
  (list 'menu-item "Insert European chars" menu-bar-chars-menu))

;Menu item: list all UTF-8 chars
(fset 'list-all-chars [?\C-x ?8 f1])
(global-set-key [?\C-c ?g ?0] 'list-all-chars)
(define-key menu-bar-chars-menu [listall]
  '(menu-item "List all UTF-8 chars" list-all-chars))
------------------------------------------------------------------

The last stanza pretty much repeats for characters which are inserted.
And the above works fine except:

In the menu the keybinding displayed is not "C-x g 0", but rather "C-x
0" and...

While "C-x g 0" works as intended and does display the listing of UTF-8
characters, so does the displayed "C-x 0"... i.e., it has replaced the
former keybinding of "C-x 0"... not good.  So I'm guess there's some
error in the way I've established keybindings with the new prefix.


Thanks much for your cordial assistance.

-- 
Without music, life would be a mistake.
	--Friedrich Nietzsche

Re: Creating submenu

[Davis Herring]

> ;Make ^C-cg a key prefix for chars menu
> (global-set-key [?\C-c ?g] ctl-x-map)

You're reusing the keymap that C-x is normally bound to, so now C-c g is
an alias for C-x in every respect.  Don't do that!  Make a new keymap:

(defvar chars-map (make-sparse-keymap)
  "Keymap for inserting special characters.")
(global-set-key [?\C-c ?g] chars-map)

You can omit "sparse-" if you're planning to bind lots of ASCII characters
(like, say, C-c g a, C-c g 0, etc.).

> (fset 'list-all-chars [?\C-x ?8 f1])

You can do this more idomatically with

(defun list-all-chars ()
  "Describe the C-x 8 keybindings."
  (interactive)
  (describe-bindings "\C-x8"))

(`describe-bindings' is what implements `f1' after a prefix key.)  But
there might be a better way: one that used the binding of C-x 8 directly
so that it would work even if the user had moved that binding elsewhere. 
I don't know what it would be, though.

Hope this helps,
Davis

-- 
This product is sold by volume, not by mass.  If it appears too dense or
too sparse, it is because mass-energy conversion has occurred during
shipping.

Re: Creating submenu

[ken]

On 12/02/2009 01:49 PM Davis Herring wrote:
>> ;Make ^C-cg a key prefix for chars menu
>> (global-set-key [?\C-c ?g] ctl-x-map)
> 
> You're reusing the keymap that C-x is normally bound to, so now C-c g is
> an alias for C-x in every respect.  Don't do that!  Make a new keymap:

That was beginning to dawn on me, but didn't know where/what to fix.


> ....
> 
> Hope this helps,
> Davis
> 

Worked perfectly.  Thanks much.