Re: Add function to rotate/transpose all windows

[martin rudalics <rudalics@gmx.at>]

 > It was when byte comping emacs/lisp/leim/leim-list.el, so I just removed the
 > whole thing along with the quail library.  Then after than it was
 > another thing where it would just spam me with 'temacs' warnings, and
 > then segmentation fault.

Does it happen while building Emacs?  Then I would do a bootstrap.  If
the error persists, stash your changes, update from the repository and
do git clean -xf.  If the error still happens with the next bootstrap,
file a bug report.  Otherwise unstash your changes and build once more.

 > Ok, I did that, and it now works fine.

It's got one tiny bug: With 'window-resize-pixelwise' non-nil, you must
not pass a float as SIZE to 'split-window'.  So please use

(round split-size)

in both calls.  Also, compiling currently gives

In cycle-windows:
window-transpose.el:203:29: Warning: ‘deepmap’ called with 1 argument, but
     requires 2
window-transpose.el:210:22: Warning: reference to free variable ‘atom-windows’

 > I made progress with atom
 > windows and fixed size windows.
 >
 > It just gives message if you have any of those and do-not-convert-size
 > is non-nil (as in transpose and rotate window), but the strucuture
 > preservign thing works in flip functions.  I know it's theoreticly
 > possible to do atom-windows when size is converted, but it's a nightmare
 > iiuc.
 >
 > Also what do you want to happen with dedicated-windows in cycle-windows
 > command?  Technically it'll work fine, but it's unitutve as the user
 > gets the expression buffers have changed but window remains the same,
 > evo tho only windows have changed.

You would have to tell me more about it.  Can you give me an example?

 > So in atom windows, there is a bug where they do not remain atomic after
 > the functino is called, although the strucutre and proportions are
 > preserved,.
 >
 > I have prepared an gourmet bug experiance for you.  Just insert the test
 > in any buffer, and go C-x C-e at end.  I don't think it'll work if you
 > do M-:.  Use the updated window-transpose.el.

This is 'window--atom-check' at work while the window structure is yet
incomplete.  An atomic window must contain at least two windows.  Please
try with adding the below two forms

(defvar window--atom-check-inhibit nil
   "If non-nil, inhibit checking windows for atomicity.
This should be let-bound by functions that may temporarily violate the
atomicity of windows.  It's good practice to run `window--atom-check'
manually as soon as the binding is left.")

(defun window--atom-check (&optional frame)
   "Check atomicity of all windows on FRAME.
FRAME defaults to the selected frame.  If an atomic window is
wrongly configured, reset the atomicity of all its windows on
FRAME to nil.  An atomic window is wrongly configured if it has
no child windows or one of its child windows is not atomic."
   (unless window--atom-check-inhibit
     (window--atom-check-1 (frame-root-window frame))))

and rewriting 'window--transpose' as

(defun window--transpose (window conf do-not-convert-size)
   "Rearrange windows of WINDOW recursively.
CONF should be a cons cell: (HORIZONTAL-SPLIT . VERTICAL-SPLIT) where
HORIZONTAL-SPLIT will be used as the third argument of `split-window'
when splitting a window that was previously horizontally split, and
VERTICAL-SPLIT as third argument of `split-window' for a window that was
previously vertically split.  If DO-NOT-CONVERT-SIZE non-nil, the size
argument of the window-split is converted from vertical to horizontal or
vice versa, with the same proportion of the total split."
   (if (or (not window)
	  (window-live-p window))
       (message "No windows to transpose")
     (let* ((frame (window-frame window))
	   (fwin window)
	   (selwin (frame-selected-window window))
	   (win-tree (car (window-tree-pixel-sizes window)))
	   (win-list (seq-filter 'window-live-p (flatten-list win-tree)))
	   (window--atom-check-inhibit t)
	   (atom-windows
	    (remq nil (mapcar 'window-atom-root
			      win-list))))
       (if (and (not (eq (car atom-windows) window))
	   (or do-not-convert-size
	      (and (not atom-windows)
		   (not (seq-some 'window-fixed-size-p win-list)))))
	  (progn
	    (when atom-windows
	      (delete-dups atom-windows))
	    (while (not (window-live-p fwin))
	      (setq fwin (window-child fwin)))
	    ;; All child windows need to be recursively deleted.
	    (delete-other-windows-internal fwin window)
	    (window--transpose-1 win-tree fwin conf do-not-convert-size atom-windows)
	    ;; Go back to previously selected window.
	    (set-frame-selected-window frame selwin))
	(message "This does not work with fixed size or atom windows.")))
     (window--atom-check (window-frame window))))

But it doesn't seem to work well yet - IIUC it gets me one more window.

martin