* [PATCH] Add XDG utility library
@ 2017-02-01 0:26 Mark Oteiza
2017-02-01 11:19 ` Philipp Stephani
` (2 more replies)
0 siblings, 3 replies; 6+ messages in thread
From: Mark Oteiza @ 2017-02-01 0:26 UTC (permalink / raw)
To: emacs-devel
* etc/NEWS: Mention new library.
* lisp/xdg.el: New file.
---
Will otherwise commit in a week or so.
etc/NEWS | 2 +
lisp/xdg.el | 144 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 146 insertions(+)
create mode 100644 lisp/xdg.el
diff --git a/etc/NEWS b/etc/NEWS
index 12ff21f39a..5f0f440b0b 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -677,6 +677,8 @@ processes on exit.
** New Elisp data-structure library 'radix-tree'.
+** New library 'xdg' with utilities for some XDG standards and specs.
+
\f
* Incompatible Lisp Changes in Emacs 26.1
diff --git a/lisp/xdg.el b/lisp/xdg.el
new file mode 100644
index 0000000000..51218e339d
--- /dev/null
+++ b/lisp/xdg.el
@@ -0,0 +1,144 @@
+;;; xdg.el --- XDG specification and standard support -*- lexical-binding: t -*-
+
+;; Copyright (C) 2017 Free Software Foundation, Inc.
+
+;; Author: Mark Oteiza <mvoteiza@udel.edu>
+;; Created: 27 January 2017
+;; Keywords: files, data
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published
+;; by the Free Software Foundation; either version 3 of the License,
+;; or (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful, but
+;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+;; General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Library providing some convenience functions for the following XDG
+;; standards and specifications
+;;
+;; - XDG Base Directory Specification
+;; - Thumbnail Managing Standard
+;; - xdg-user-dirs configuration
+
+;;; Code:
+
+\f
+;; XDG Base Directory Specification
+;; https://standards.freedesktop.org/basedir-spec/basedir-spec-latest.html
+
+(defmacro xdg--dir-home (environ default-path)
+ (declare (debug (stringp stringp)))
+ (let ((env (make-symbol "env")))
+ `(let ((,env (getenv ,environ)))
+ (if (or (null ,env) (not (file-name-absolute-p ,env)))
+ (expand-file-name ,default-path)
+ ,env))))
+
+(defun xdg-config-home ()
+ "Return the base directory for user specific configuration files."
+ (xdg--dir-home "XDG_CONFIG_HOME" "~/.config"))
+
+(defun xdg-cache-home ()
+ "Return the base directory for user specific cache files."
+ (xdg--dir-home "XDG_CACHE_HOME" "~/.cache"))
+
+(defun xdg-data-home ()
+ "Return the base directory for user specific data files."
+ (xdg--dir-home "XDG_DATA_HOME" "~/.local/share"))
+
+(defun xdg-runtime-dir ()
+ "Return the value of $XDG_RUNTIME_DIR."
+ (getenv "XDG_RUNTIME_DIR"))
+
+(defun xdg-config-dirs ()
+ "Return the config directory search path as a list."
+ (let ((env (getenv "XDG_CONFIG_DIRS")))
+ (if (or (null env) (string= env ""))
+ '("/etc/xdg")
+ (parse-colon-path env))))
+
+(defun xdg-data-dirs ()
+ "Return the data directory search path as a list."
+ (let ((env (getenv "XDG_CONFIG_DIRS")))
+ (if (or (null env) (string= env ""))
+ '("/usr/local/share/" "/usr/share/")
+ (parse-colon-path env))))
+
+\f
+;; Thumbnail Managing Standard
+;; https://specifications.freedesktop.org/thumbnail-spec/thumbnail-spec-latest.html
+
+(defun xdg-thumb-uri (filename)
+ "Return the canonical URI for FILENAME.
+If FILENAME has absolute path /foo/bar.jpg, its canonical URI is
+file:///foo/bar.jpg"
+ (concat "file://" (expand-file-name filename)))
+
+(defun xdg-thumb-name (filename)
+ "Return the appropriate thumbnail filename for FILENAME."
+ (concat (md5 (xdg-thumb-uri filename)) ".png"))
+
+(defun xdg-thumb-mtime (filename)
+ "Return modification time of FILENAME as integral seconds from the epoch."
+ (floor (float-time (nth 5 (file-attributes filename)))))
+
+\f
+;; XDG User Directories
+;; https://www.freedesktop.org/wiki/Software/xdg-user-dirs/
+
+(defconst xdg-line-regexp
+ (eval-when-compile
+ (rx "XDG_"
+ (group-n 1 (or "DESKTOP" "DOWNLOAD" "TEMPLATES" "PUBLICSHARE"
+ "DOCUMENTS" "MUSIC" "PICTURES" "VIDEOS"))
+ "_DIR=\""
+ (group-n 2 (or "/" "$HOME/") (*? (or (not (any "\"")) "\\\"")))
+ "\""))
+ "Regexp matching non-comment lines in xdg-user-dirs config files.")
+
+(defvar xdg-user-dirs nil
+ "Alist of directory keys and values.")
+
+(defun xdg--user-dirs-parse-line ()
+ "Return pair of user-dirs key to directory value in LINE, otherwise nil.
+This should be called at the beginning of a line."
+ (skip-chars-forward "[:blank:]")
+ (when (and (/= (following-char) ?#)
+ (looking-at xdg-line-regexp))
+ (let ((k (match-string 1))
+ (v (match-string 2)))
+ (when (and k v) (cons k v)))))
+
+(defun xdg--user-dirs-parse-file (filename)
+ "Return alist of xdg-user-dirs from FILENAME."
+ (let (elt res)
+ (with-temp-buffer
+ (insert-file-contents filename)
+ (goto-char (point-min))
+ (while (not (eobp))
+ (setq elt (xdg--user-dirs-parse-line))
+ (when (consp elt) (push elt res))
+ (forward-line)))
+ res))
+
+(defun xdg-user-dir (name)
+ "Return the path of user directory referred to by NAME."
+ (when (null xdg-user-dirs)
+ (setq xdg-user-dirs
+ (xdg--user-dirs-parse-file
+ (expand-file-name "user-dirs.dirs" (xdg-config-home)))))
+ (cdr (assoc name xdg-user-dirs)))
+
+(provide 'xdg)
+
+;;; xdg.el ends here
--
2.11.0
^ permalink raw reply related [flat|nested] 6+ messages in thread
* Re: [PATCH] Add XDG utility library
2017-02-01 0:26 [PATCH] Add XDG utility library Mark Oteiza
@ 2017-02-01 11:19 ` Philipp Stephani
2017-02-01 12:14 ` Mark Oteiza
2017-02-01 11:24 ` Philipp Stephani
2017-02-01 15:01 ` Ted Zlatanov
2 siblings, 1 reply; 6+ messages in thread
From: Philipp Stephani @ 2017-02-01 11:19 UTC (permalink / raw)
To: Mark Oteiza, emacs-devel
[-- Attachment #1: Type: text/plain, Size: 463 bytes --]
Mark Oteiza <mvoteiza@udel.edu> schrieb am Mi., 1. Feb. 2017 um 01:28 Uhr:
>
> +(defmacro xdg--dir-home (environ default-path)
> + (declare (debug (stringp stringp)))
> + (let ((env (make-symbol "env")))
> + `(let ((,env (getenv ,environ)))
> + (if (or (null ,env) (not (file-name-absolute-p ,env)))
> + (expand-file-name ,default-path)
> + ,env))))
>
Maybe I'm missing something, but why is this a macro and not a normal
function?
[-- Attachment #2: Type: text/html, Size: 935 bytes --]
^ permalink raw reply [flat|nested] 6+ messages in thread
* Re: [PATCH] Add XDG utility library
2017-02-01 0:26 [PATCH] Add XDG utility library Mark Oteiza
2017-02-01 11:19 ` Philipp Stephani
@ 2017-02-01 11:24 ` Philipp Stephani
2017-02-01 12:17 ` Mark Oteiza
2017-02-01 15:01 ` Ted Zlatanov
2 siblings, 1 reply; 6+ messages in thread
From: Philipp Stephani @ 2017-02-01 11:24 UTC (permalink / raw)
To: Mark Oteiza, emacs-devel
[-- Attachment #1: Type: text/plain, Size: 1900 bytes --]
Mark Oteiza <mvoteiza@udel.edu> schrieb am Mi., 1. Feb. 2017 um 01:28 Uhr:
>
> +;; XDG User Directories
> +;; https://www.freedesktop.org/wiki/Software/xdg-user-dirs/
> +
> +(defconst xdg-line-regexp
> + (eval-when-compile
> + (rx "XDG_"
> + (group-n 1 (or "DESKTOP" "DOWNLOAD" "TEMPLATES" "PUBLICSHARE"
> + "DOCUMENTS" "MUSIC" "PICTURES" "VIDEOS"))
> + "_DIR=\""
> + (group-n 2 (or "/" "$HOME/") (*? (or (not (any "\"")) "\\\"")))
> + "\""))
> + "Regexp matching non-comment lines in xdg-user-dirs config files.")
> +
> +(defvar xdg-user-dirs nil
> + "Alist of directory keys and values.")
> +
> +(defun xdg--user-dirs-parse-line ()
> + "Return pair of user-dirs key to directory value in LINE, otherwise nil.
> +This should be called at the beginning of a line."
> + (skip-chars-forward "[:blank:]")
> + (when (and (/= (following-char) ?#)
> + (looking-at xdg-line-regexp))
> + (let ((k (match-string 1))
> + (v (match-string 2)))
> + (when (and k v) (cons k v)))))
> +
> +(defun xdg--user-dirs-parse-file (filename)
> + "Return alist of xdg-user-dirs from FILENAME."
> + (let (elt res)
> + (with-temp-buffer
> + (insert-file-contents filename)
> + (goto-char (point-min))
> + (while (not (eobp))
> + (setq elt (xdg--user-dirs-parse-line))
> + (when (consp elt) (push elt res))
> + (forward-line)))
> + res))
> +
> +(defun xdg-user-dir (name)
> + "Return the path of user directory referred to by NAME."
> + (when (null xdg-user-dirs)
> + (setq xdg-user-dirs
> + (xdg--user-dirs-parse-file
> + (expand-file-name "user-dirs.dirs" (xdg-config-home)))))
> + (cdr (assoc name xdg-user-dirs)))
>
This parsing seems a bit brittle (what if the file contains ${HOME} instead
of $HOME?); probably this should call the xdg-user-dir program instead.
[-- Attachment #2: Type: text/html, Size: 3593 bytes --]
^ permalink raw reply [flat|nested] 6+ messages in thread
* Re: [PATCH] Add XDG utility library
2017-02-01 11:19 ` Philipp Stephani
@ 2017-02-01 12:14 ` Mark Oteiza
0 siblings, 0 replies; 6+ messages in thread
From: Mark Oteiza @ 2017-02-01 12:14 UTC (permalink / raw)
To: Philipp Stephani; +Cc: emacs-devel
On 01/02/17 at 11:19am, Philipp Stephani wrote:
> Mark Oteiza <mvoteiza@udel.edu> schrieb am Mi., 1. Feb. 2017 um 01:28 Uhr:
>
> >
> > +(defmacro xdg--dir-home (environ default-path)
> > + (declare (debug (stringp stringp)))
> > + (let ((env (make-symbol "env")))
> > + `(let ((,env (getenv ,environ)))
> > + (if (or (null ,env) (not (file-name-absolute-p ,env)))
> > + (expand-file-name ,default-path)
> > + ,env))))
> >
>
> Maybe I'm missing something, but why is this a macro and not a normal
> function?
Because its only use is the write the body of a few functions.
^ permalink raw reply [flat|nested] 6+ messages in thread
* Re: [PATCH] Add XDG utility library
2017-02-01 11:24 ` Philipp Stephani
@ 2017-02-01 12:17 ` Mark Oteiza
0 siblings, 0 replies; 6+ messages in thread
From: Mark Oteiza @ 2017-02-01 12:17 UTC (permalink / raw)
To: Philipp Stephani; +Cc: emacs-devel
On 01/02/17 at 11:24am, Philipp Stephani wrote:
> Mark Oteiza <mvoteiza@udel.edu> schrieb am Mi., 1. Feb. 2017 um 01:28 Uhr:
>
> >
> > +;; XDG User Directories
> > +;; https://www.freedesktop.org/wiki/Software/xdg-user-dirs/
> > +
> > +(defconst xdg-line-regexp
> > + (eval-when-compile
> > + (rx "XDG_"
> > + (group-n 1 (or "DESKTOP" "DOWNLOAD" "TEMPLATES" "PUBLICSHARE"
> > + "DOCUMENTS" "MUSIC" "PICTURES" "VIDEOS"))
> > + "_DIR=\""
> > + (group-n 2 (or "/" "$HOME/") (*? (or (not (any "\"")) "\\\"")))
> > + "\""))
> > + "Regexp matching non-comment lines in xdg-user-dirs config files.")
> > +
> > +(defvar xdg-user-dirs nil
> > + "Alist of directory keys and values.")
> > +
> > +(defun xdg--user-dirs-parse-line ()
> > + "Return pair of user-dirs key to directory value in LINE, otherwise nil.
> > +This should be called at the beginning of a line."
> > + (skip-chars-forward "[:blank:]")
> > + (when (and (/= (following-char) ?#)
> > + (looking-at xdg-line-regexp))
> > + (let ((k (match-string 1))
> > + (v (match-string 2)))
> > + (when (and k v) (cons k v)))))
> > +
> > +(defun xdg--user-dirs-parse-file (filename)
> > + "Return alist of xdg-user-dirs from FILENAME."
> > + (let (elt res)
> > + (with-temp-buffer
> > + (insert-file-contents filename)
> > + (goto-char (point-min))
> > + (while (not (eobp))
> > + (setq elt (xdg--user-dirs-parse-line))
> > + (when (consp elt) (push elt res))
> > + (forward-line)))
> > + res))
> > +
> > +(defun xdg-user-dir (name)
> > + "Return the path of user directory referred to by NAME."
> > + (when (null xdg-user-dirs)
> > + (setq xdg-user-dirs
> > + (xdg--user-dirs-parse-file
> > + (expand-file-name "user-dirs.dirs" (xdg-config-home)))))
> > + (cdr (assoc name xdg-user-dirs)))
> >
>
> This parsing seems a bit brittle (what if the file contains ${HOME} instead
> of $HOME?); probably this should call the xdg-user-dir program instead.
Then it's not valid. There's no point in depending on a binary for
this.
https://cgit.freedesktop.org/xdg/xdg-user-dirs/tree/xdg-user-dir-lookup.c
^ permalink raw reply [flat|nested] 6+ messages in thread
* Re: [PATCH] Add XDG utility library
2017-02-01 0:26 [PATCH] Add XDG utility library Mark Oteiza
2017-02-01 11:19 ` Philipp Stephani
2017-02-01 11:24 ` Philipp Stephani
@ 2017-02-01 15:01 ` Ted Zlatanov
2 siblings, 0 replies; 6+ messages in thread
From: Ted Zlatanov @ 2017-02-01 15:01 UTC (permalink / raw)
To: emacs-devel
On Tue, 31 Jan 2017 19:26:06 -0500 Mark Oteiza <mvoteiza@udel.edu> wrote:
MO> * etc/NEWS: Mention new library.
MO> * lisp/xdg.el: New file.
MO> ---
MO> Will otherwise commit in a week or so.
Looks great to me :)
Ted
^ permalink raw reply [flat|nested] 6+ messages in thread
end of thread, other threads:[~2017-02-01 15:01 UTC | newest]
Thread overview: 6+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2017-02-01 0:26 [PATCH] Add XDG utility library Mark Oteiza
2017-02-01 11:19 ` Philipp Stephani
2017-02-01 12:14 ` Mark Oteiza
2017-02-01 11:24 ` Philipp Stephani
2017-02-01 12:17 ` Mark Oteiza
2017-02-01 15:01 ` Ted Zlatanov
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).