help-at-pt.el

help-at-pt.el

[Luc Teirlinck]

The attached file implements functionality to make the help provided
by the help-echo property accessible to the keyboard user, in three
ways: on demand, through a customizable timer and by motion commands.

These are things we discussed in August, but they got delayed, because
some additional highlighting functionality I originally included turned
out to keep getting more complicated through all kinds of special
exceptional cases that kept cropping up.  I now decided to put the
highlighting stuff in a different file that I will submit later.  It
does not have _that_ much to do with the functionality in the attached
file anyway.  I have been using the attached code for more than two
months without problems now.

I do not know how new files are supposed to get their arch tags.

In as far as the key bindings go, I suggest binding 'help-at-pt-print
to C-h C-b, which seems to be an available C-h key.  (The "b" kind of
standing for help in the _b_uffer.)  If this is acceptable, I would
include this line in help.el:

(define-key help-map "\C-b" 'help-at-pt-print)

Binding the two motion commands could be left up to the user.
Bindings of C-tab and C-M-tab are suggested in the file.  Uncommenting
three lines at the end will enable all suggested bindings.

The kbd-help text-property could be used to provide an alternate help
string when help-echo is too mouse-specific.  It can also be set to
`t' to indicate that the help-echo property _is_ relevant to the
keyboard user.  This is relevant if the user sets
`help-at-pt-print-when-idle' to a list containing kbd-help.

The function `scan-buf-move-to-region' is more general than needed for
the present file, because I also plan to use it in the file I plan to
submit later.

Please let me know whether it would be OK to add help-at-pt.el (and the
related changes suggested below) to the Emacs CVS, in which case I
would include the standard 
";; This file is part of GNU Emacs." and related stuff.

For the file to function I also need the following small addition to
textprop.c (we discussed this before and I have used it for two
months) and maybe also an added line to intervals.h (see below).

===File ~/textprop-diff=====================================
cd ~/
diff -c /home/teirllm/emacscvsdir/emacs/src/textprop.c /home/teirllm/textprop.c
*** /home/teirllm/emacscvsdir/emacs/src/textprop.c	Mon Oct 20 11:00:24 2003
--- /home/teirllm/textprop.c	Tue Sep  2 08:19:40 2003
***************
*** 703,708 ****
--- 703,730 ----
  {
    return get_char_property_and_overlay (position, prop, object, 0);
  }
+ 
+ DEFUN ("get-char-property-and-overlay", Fget_char_property_and_overlay, 
+ Sget_char_property_and_overlay, 2, 3, 0,
+        doc: /* Return a cons whose car is the value of POSITION's
+ property PROP, in OBJECT and whose cdr is the overlay in which the
+ property was found, or nil if it was found as a text property.  OBJECT
+ is optional and defaults to the current buffer.  If POSITION is at the
+ end of OBJECT, the value is nil.  If OBJECT is a buffer, then overlay
+ properties are considered as well as text properties.  If OBJECT is a
+ window, then that window's buffer is used, but window-specific
+ overlays are considered only if they are associated with OBJECT.  */)
+      (position, prop, object)
+      Lisp_Object position, object;
+      register Lisp_Object prop;
+ {
+   Lisp_Object overlay;
+   Lisp_Object val
+     = get_char_property_and_overlay (position, prop, object, &overlay);
+   return Fcons(val, overlay);
+ }
+ 
+ 
  \f
  DEFUN ("next-char-property-change", Fnext_char_property_change,
         Snext_char_property_change, 1, 2, 0,
***************
*** 2277,2282 ****
--- 2299,2305 ----
    defsubr (&Stext_properties_at);
    defsubr (&Sget_text_property);
    defsubr (&Sget_char_property);
+   defsubr (&Sget_char_property_and_overlay);
    defsubr (&Snext_char_property_change);
    defsubr (&Sprevious_char_property_change);
    defsubr (&Snext_single_char_property_change);

Diff finished at Mon Oct 20 11:04:07
============================================================

I also have been using the following addition to intervals.h, but I do
not whether it is really necessary:

===File ~/intervals.h-diff==================================
cd ~/
diff -c /home/teirllm/emacscvsdir/emacs/src/intervals.h /home/teirllm/intervals.h
*** /home/teirllm/emacscvsdir/emacs/src/intervals.h	Mon Oct 20 11:00:21 2003
--- /home/teirllm/intervals.h	Tue Sep  2 08:16:48 2003
***************
*** 328,333 ****
--- 328,334 ----
  extern Lisp_Object Qfront_sticky, Qrear_nonsticky;
  
  EXFUN (Fget_char_property, 3);
+ EXFUN (Fget_char_property_and_overlay, 3);
  EXFUN (Fget_text_property, 3);
  EXFUN (Ftext_properties_at, 2);
  EXFUN (Fnext_property_change, 3);

Diff finished at Mon Oct 20 11:05:11
============================================================

===File ~/help-at-pt.el=====================================
;;; help-at-pt.el --- local help through the keyboard

;; Copyright (C) 2003 Free Software Foundation, Inc.

;; Author: Luc Teirlinck <teirllm@auburn.edu>
;; Keywords: help

;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2 of the
;; License, or (at your option) any later version.

;; This program is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program; if not, write to the Free Software
;; Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111,
;; USA.

;;; Commentary:

;; This file contains functionality to make the help provided by the
;; help-echo text or overlay property available to the keyboard user.
;; It also supports a more keyboard oriented alternative to
;; `help-echo', namely a new text or overlay property `kbd-help'.
;;
;; It provides facilities to access the local help available at point
;; either on demand, using the command `help-at-pt-print', or
;; automatically after a suitable idle time, through the customizable
;; variable `help-at-pt-print-when-idle'.
;;
;; You can get a more global overview of the local help available in
;; the buffer, using the commands `scan-buf-next-region' and
;; `scan-buf-previous-region', which move to the start of the next or
;; previous region with available local help and print the help found
;; there.
;;
;; You do not have to do anything special to use the functionality
;; provided by this file, because all important functions autoload.

;;; Code:

(defgroup help-at-pt nil
  "Features for displaying local help."
  :group 'convenience
  :version "21.4")

;;;###autoload
(defun help-at-pt-string (&optional kbd)
  "Return the help-echo string at point.
Normally, the string produced by the `help-echo' text or overlay
property, or nil, is returned.
If KBD is non-nil, `kbd-help' is used instead, and any
`help-echo' property is ignored.  In this case, the return value
can also be t, if that is the value of the `kbd-help' property."
  (let* ((prop (if kbd 'kbd-help 'help-echo))
	 (pair (get-char-property-and-overlay (point) prop))
	 (val (car pair))
	 (ov (cdr pair)))
    (if (functionp val)
	(funcall val (selected-window) (if ov ov (current-buffer)) (point))
      (eval val))))

;;;###autoload
(defun help-at-pt-kbd-string ()
  "Return the keyboard help string at point.
If the `kbd-help' text or overlay property at point produces a
string, return it.  Otherwise, use the `help-echo' property.  If
this produces no string either, return nil."
  (let ((kbd (help-at-pt-string t))
	(echo (help-at-pt-string)))
    (if (and kbd (not (eq kbd t))) kbd echo)))

;;;###autoload
(defun help-at-pt-print (&optional arg)
  "Display local help in the echo area..
This displays a short help message, namely the string produced by
the `kbd-help' property at point.  If `kbd-help' does not produce
a string, but the `help-echo' property does, then that string is
printed instead.

A numeric argument ARG prevents display of a message in case
there is no help.  While ARG can be used interactively, it is
mainly meant for use from Lisp."
  (interactive "P")
  (let ((help (help-at-pt-kbd-string)))
    (if help
	(message "%s" help)
      (if (not arg) (message "No local help at point")))))

(defcustom help-at-pt-timer-delay 1
  "*Delay before displaying local help.
This is used if `help-at-pt-print-when-idle' is enabled.
The value may be an integer or floating point number."
  :group 'help-at-pt
  :type 'number)

(defvar help-at-pt-timer nil
  "Non-nil means that a timer is set that checks for local help.
If non-nil, this is the value returned by the call of
`run-with-idle-timer' that set that timer.  This variable is used
internally to enable `help-at-pt-print-when-idle'.  Do not set it
yourself.")

;;;###autoload
(defun help-at-pt-cancel-timer ()
  "Cancel any timer set by `help-at-pt-set-timer'.
This disables `help-at-pt-print-when-idle'."
  (interactive)
  (let ((inhibit-quit t))
    (when help-at-pt-timer
      (cancel-timer help-at-pt-timer)
      (setq help-at-pt-timer nil))))

;;;###autoload
(defun help-at-pt-set-timer ()
  "Enable `help-at-pt-print-when-idle'.
This is done by setting a timer, if none is currently running."
  (interactive)
  (unless help-at-pt-timer
    (setq help-at-pt-timer
	  (run-with-idle-timer
	   help-at-pt-timer-delay t #'help-at-pt-maybe-print))))

;;;###autoload
(defcustom help-at-pt-print-when-idle 'never
  "*Automatically show local help on point-over.
If the value is t, the string obtained from any `kbd-help' or
`help-echo' property at point is automatically printed in the
echo area, if nothing else is already displayed there, or after a
quit.  If both `kbd-help' and `help-echo' produce help strings,
`kbd-help' is used.  If the value is a list, the help only gets
printed if there is a text or overlay property at point that is
included in this list.  Suggested properties are `keymap',
`local-map', `button' and `kbd-help'.  Any value other than t or
a non-empty list disables the feature.

This variable only takes effect after a call to
`help-at-pt-set-timer'.  The help gets printed after Emacs has
been idle for `help-at-pt-timer-delay' seconds.  You can call
`help-at-pt-cancel-timer' to cancel the timer set by, and the
effect of, `help-at-pt-set-timer'.

When this variable is set through Custom, `help-at-pt-set-timer'
is called automatically, unless the value is `never', in which
case `help-at-pt-cancel-timer' is called.  Specifying an empty
list of properties through Custom will set the timer, thus
enabling buffer local values.  It sets the actual value to nil.
Thus, Custom distinguishes between a nil value and other values
that disable the feature, which Custom identifies with `never'.
The default is `never'."
  :group 'help-at-pt
  :type '(choice  (const :tag "Always"
			 :format "%t\n%h"
			 :doc
			 "This can get noisy.
The text printed from the `help-echo' property is often only
relevant when using the mouse.  If you mind about too many
messages getting printed in the echo area, use \"In certain
situations\".  See the documentation there for more information."
			 t)
		  (repeat :tag "In certain situations"
			  ;; unless we specify 0 offset the doc string
			  ;; for this choice gets indented very
			  ;; differently than for the other two
			  ;; choices, when "More" is selected.
			  :offset 0
			  :format "%{%t%}:\n%v%i\n%h"
			  :doc
			  "List of text properties.
Presence of any of these properties will trigger display of
available local help.
If you use this alternative through Custom without listing any
properties, a timer will be set anyway.  This will enable buffer
local values.  Use \"Never\" if you do not want a timer to be set.

Suggested properties:
The `keymap' and `local-map' properties change keybindings in
parts of the buffer.  Some of these keymaps are mode independent
and are not mentioned in the mode documentation.  Hence, the help
text is likely to be useful.
Specifying `button' is relevant in Custom and similar buffers,
Most, but not all, of the text shown this way is available by
default when using tab, but not on regular point-over.
The presence of a `kbd-help' property guarantees that non mouse
specific help is available."
			  :value (keymap local-map button kbd-help)
			  symbol)
		  (other :tag "Never"
			 :format "%t\n%h"
			 :doc
			 "This normally disables buffer local values.
If you choose this value through Custom and a timer checking for
local help is currently running, it will be canceled.  No new
timer will be set.  Call `help-at-pt-set-timer' after choosing
this option, or use \"In certain situations\" and specify no text
properties, to enable buffer local values."
			 never))
  :initialize 'custom-initialize-default
  :set #'(lambda (variable value)
	   (set variable value)
	   (if (eq value 'never)
	       (help-at-pt-cancel-timer)
	     (help-at-pt-set-timer)))
  :set-after '(help-at-pt-timer-delay)
  :require 'help-at-pt)

;; Function for use in `help-at-pt-set-timer'.
(defun help-at-pt-maybe-print ()
  (and (or (eq help-at-pt-print-when-idle t)
	   (and (consp help-at-pt-print-when-idle)
		(catch 'found
		  (dolist (prop help-at-pt-print-when-idle)
		    (if (get-char-property (point) prop)
			(throw 'found t))))))
       (or (not (current-message))
	   (string= (current-message) "Quit"))
       (help-at-pt-print t)))

;;;###autoload
(defun scan-buf-move-to-region (prop &optional arg hook)
  "Go to the start of the next region with non-nil PROP property.
Then run HOOK, which should be a quoted symbol that is a normal
hook.variable, or an expression evaluating to such a symbol.
Adjacent areas with different non-nil PROP properties are
considered different regions.

With numeric argument ARG, move to the start of the ARGth next
such region, then run HOOK.  If ARG is negative, move backward.
If point is already in a region, then that region does not count
toward ARG.  If ARG is 0 and point is inside a region, move to
the start of that region.  If ARG is 0 and point is not in a
region, print a message to that effect, but do not move point and
do not run HOOK.  If there are not enough regions to move over,
an error results and the number of available regions is mentioned
in the error message.  Point is not moved and HOOK is not run."
  (cond ((> arg 0)
	 (if (= (point) (point-max))
	     (error "No further `%s' regions" prop))
	 (let ((pos (point)))
	   (dotimes (x arg)
	     (setq pos (next-single-char-property-change pos prop))
	     (unless (get-char-property pos prop)
	       (setq pos (next-single-char-property-change pos prop))
	       (unless (get-char-property pos prop)
		 (cond ((= x 0)
			(error "No further `%s' regions" prop))
		       ((= x 1)
			(error "There is only one further `%s' region" prop))
		       (t
			(error
			 "There are only %d further `%s' regions"
			 x prop))))))
	   (goto-char pos)
	   (run-hooks hook)))
	((= arg 0)
	 (let ((val (get-char-property (point) prop)))
	   (cond ((not val)
		  (message "Point is not in a `%s' region" prop))
		 ((eq val (get-char-property (1- (point)) prop))
		  (goto-char
		   (previous-single-char-property-change (point) prop))
		  (run-hooks hook))
		 (t (run-hooks hook)))))
	((< arg 0)
	 (let ((pos (point)) (val (get-char-property (point) prop)))
	   (and val
		(eq val (get-char-property (1- pos) prop))
		(setq pos
		      (previous-single-char-property-change pos prop)))
	   (if (= pos (point-min))
	       (error "No prior `%s' regions" prop))
	   (dotimes (x (- arg))
	     (setq pos (previous-single-char-property-change pos prop))
	     (unless (get-char-property pos prop)
	       (setq pos (previous-single-char-property-change pos prop))
	       (unless (get-char-property pos prop)
		 (cond ((= x 0)
			(error "No prior `%s' regions" prop))
		       ((= x 1)
			(error "There is only one prior `%s' region" prop))
		       (t
			(error "There are only %d prior `%s' regions"
			       x prop))))))
	   (goto-char pos)
	   (run-hooks hook)))))

;; To be moved to a different file and replaced by a defcustom in a
;; future version.
(defvar scan-buf-move-hook '(help-at-pt-print)
  "*Normal hook run by `scan-buf-next-region'.
Also used by `scan-buf-previous-region'.  The hook is run after
positioning point.")

;;;###autoload
(defun scan-buf-next-region (&optional arg)
  "Go to the start of the next region with non-nil help-echo.
Print the help found there using `help-at-pt-print'.  Adjacent
areas with different non-nil help-echo properties are considered
different regions.

With numeric argument ARG, move to the start of the ARGth next
help-echo region.  If ARG is negative, move backward.  If point
is already in a help-echo region, then that region does not count
toward ARG.  If ARG is 0 and point is inside a help-echo region,
move to the start of that region.  If ARG is 0 and point is not
in such a region, just print a message to that effect.  If there
are not enough regions to move over, an error results and the
number of available regions is mentioned in the error message.

A potentially confusing subtlety is that point can be in a
help-echo region without any local help being available.  This is
because `help-echo' can be a function evaluating to nil.  This
rarely happens in practice."
  (interactive "p")
  (scan-buf-move-to-region 'help-echo arg 'scan-buf-move-hook))

;;;###autoload
(defun scan-buf-previous-region (&optional arg)
  "Go to the start of the previous region with non-nil help-echo.
Print the help found there using `help-at-pt-print'.  Adjacent
areas with different non-nil help-echo properties are considered
different regions.  With numeric argument ARG, behaves like
`scan-buf-next-region' with argument -ARG.."
  (interactive "p")
  (scan-buf-move-to-region 'help-echo (- arg) 'scan-buf-move-hook))

(defvar help-at-pt-unload-hook '(help-at-pt-cancel-timer)
  "Normal hook run when `help-at-pt' is unloaded.")

;; Suggested key bindings:
;;
;; (global-set-key "\C-h\C-b" 'help-at-pt-print) 
;; (global-set-key [C-tab] 'scan-buf-next-region)
;; (global-set-key [C-M-tab] 'scan-buf-previous-region)

(provide 'help-at-pt)

;;; help-at-pt.el ends here
============================================================

Re: help-at-pt.el

[Miles Bader]

Luc Teirlinck <teirllm@dms.auburn.edu> writes:
> I do not know how new files are supposed to get their arch tags.

It will get done automatically by CVS<->arch synchronization.

-miles
-- 
Ich bin ein Virus. Mach' mit und kopiere mich in Deine .signature.

Re: help-at-pt.el

[Kevin Rodgers]

Luc Teirlinck wrote:

> In as far as the key bindings go, I suggest binding 'help-at-pt-print
> to C-h C-b, which seems to be an available C-h key.  (The "b" kind of
> standing for help in the _b_uffer.)  If this is acceptable, I would
> include this line in help.el:
> 
> (define-key help-map "\C-b" 'help-at-pt-print)


How about `C-h .', with "dot" being a mnemonic for point?


> Binding the two motion commands could be left up to the user.
> Bindings of C-tab and C-M-tab are suggested in the file.  Uncommenting
> three lines at the end will enable all suggested bindings.


Shouldn't they be named help-at-pt-next-region and help-at-pt-previous-region,
and bound to keys with the `C-h' prefix?

-- 
Kevin Rodgers

Re: help-at-pt.el

[Luc Teirlinck]

Kevin Rodgers wrote:

   How about `C-h .', with "dot" being a mnemonic for point?

(Meant is: as a keybinding for 'help-at-pt-print, instead of the
originally proposed C-h C-b.)

That might indeed be a better alternative.

   Shouldn't they be named help-at-pt-next-region and
   help-at-pt-previous-region, and bound to keys with the `C-h'
   prefix?

These are two questions.  In as far as the keybinding is concerned,
then for motion commands that can get repeated several times in a row,
it usually is more convenient to have them executed with a single
keystroke.  That usually means a modified <tab> or a modified arrow
key, but since tab is also used for completion and since everybody and
everything (including window managers) defining a motion or cycling
command, wants to use a modified <tab> or a modified arrow key for
exactly the same reasons I want to, it gets, of course, difficult to
find unused modifiers for them.  We could actually use C-h <right> and
C-h <left> which seem to be undefined.  (Here, C-f could not be used
as a synonym for <right> because C-h C-f runs `view-emacs-FAQ').  One
could then do C-x z z z... if one wants to scan a large piece of the
buffer this way.

The names for the commands derive from the fact that I have a second
file scan-buf.el in preparation.  All functions and variables
currently in help-at-pt.el would stay there, except the variable
`scan-buf-move-hook', which would move to scan-buf.el.  The
`help-echo' in the two commands would be replaced by a variable, whose
normal value is 'help-echo, so the commands would normally keep doing
what they do know, except that if one wanted to study some other text
property than 'help-echo, one could just temporarily reset the
variable.  One will also be able to customize `scan-buf-move-hook' to
print information adapted to the text property one is studying.  If
that is 'help-echo, it just prints what it prints now.  There also
will be a command that highlights all regions with a non-nil value for
the property one is studying, so one can see where one will move to
and what the exact extent of the region one moved to is.

Using exclusively the machinery currently already in help-at-pt.el
will not require loading scan-buf.el.

I named everything that is really help-echo specific and is really
local, namely related to where point is right now with the prefix
`help-at-point', whereas I named everything that will work later for
arbitrary text properties and that can be used to scan the entire
buffer with the prefix `scan-buf'.  These will also be the two Custom
groups.  In as far as splitting functions over files is concerned, I
did this in such a way that people who would never use the more
general machinery would not need to load it anyway to be able to use
the more specialized one.  Also, people only needing the specialized
functionality will not have their customization buffer cluttered with
the more sophisticated general stuff.  Trying to reconcile different
concerns lead to some functions in `help-at-pt' being named with the
scan-buf prefix, named after scan-buf.el.  I do not believe that this
is really bad, but, of course, I could easily do some renaming if
people would believe that this would be more appropriate.

Sincerely,

Luc.

Re: help-at-pt.el

[Richard Stallman]

    How about `C-h .', with "dot" being a mnemonic for point?

That looks good to me.