From: Eshel Yaron via "Bug reports for GNU Emacs, the Swiss army knife of text editors" <bug-gnu-emacs@gnu.org>
To: Eli Zaretskii <eliz@gnu.org>
Cc: 64126@debbugs.gnu.org
Subject: bug#64126: [PATCH] New command 'eww-copy-alternate-url'
Date: Wed, 21 Jun 2023 20:20:27 +0300 [thread overview]
Message-ID: <m14jn0pw9w.fsf@eshelyaron.com> (raw)
In-Reply-To: <83r0q452u9.fsf@gnu.org> (Eli Zaretskii's message of "Wed, 21 Jun 2023 17:04:14 +0300")
[-- Attachment #1: Type: text/plain, Size: 827 bytes --]
Eli Zaretskii <eliz@gnu.org> writes:
>> From: Eshel Yaron <me@eshelyaron.com>
>>
>> >> +*** New command 'eww-copy-alternate-url'.
>> >> +It copies an alternate link to the page currently visited in EWW into
>> >> +the kill ring.
>> >
>> > Searching the Internet for "alternate link" brings this:
>> >
>> > A type of hyperlink that gives alternate representations of the
>> > current document.
>> >
>> > Is this what is meant here? If so, why are you talking about RSS
>> > feeds?
>> >
>>
>> Yes, websites very often use these alternate links to point to their
>> RSS/Atom feeds. Should I add a couple of words about that in the NEWS
>> entry as well?
>
> Yes, a few more words of explanation would be good there.
Sure, I've added a few words about alternate links to the NEWS entry in
the following (updated) patch:
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: v4-0001-New-command-eww-copy-alternate-url.patch --]
[-- Type: text/x-patch, Size: 6621 bytes --]
From 6f2de147056000d2007d7715f1f616ff6a37a508 Mon Sep 17 00:00:00 2001
From: Eshel Yaron <me@eshelyaron.com>
Date: Sat, 17 Jun 2023 13:48:51 +0300
Subject: [PATCH v4] New command 'eww-copy-alternate-url'
This adds a new command to EWW that copies an alternate link to the
currently visited page into the kill ring. This is useful for
subscribing to website feeds, etc.
* lisp/net/eww.el (eww--alternate-urls)
(eww-read-alternate-url): New functions.
(eww-copy-alternate-url): New command.
(eww-mode-map): Bind it to 'A'.
* doc/misc/eww.texi (Basics): Document it.
* etc/NEWS: Announce it.
---
doc/misc/eww.texi | 15 +++++++++
etc/NEWS | 7 +++++
lisp/net/eww.el | 79 +++++++++++++++++++++++++++++++++++++++++++++++
3 files changed, 101 insertions(+)
diff --git a/doc/misc/eww.texi b/doc/misc/eww.texi
index c02e9db11c9..cff48bd601e 100644
--- a/doc/misc/eww.texi
+++ b/doc/misc/eww.texi
@@ -115,6 +115,21 @@ Basics
@kbd{w} calls @code{eww-copy-page-url}, which will copy the current
page's URL to the kill ring instead.
+@findex eww-copy-alternate-url
+@kindex A
+ The @kbd{A} command (@code{eww-copy-alternate-url}) copies the URL
+of an alternate link of the current page into the kill ring. If the
+page specifies multiple alternate links, this command prompts for one
+of them in the minibuffer, with completion. Alternate links are
+references that an @acronym{HTML} page may include to point to other
+documents that act as its alternative representations. Notably,
+@acronym{HTML} pages can use alternate links to point to their
+translated versions and to @acronym{RSS} feeds. Alternate links
+appear in the @samp{<head>} section of @acronym{HTML} pages as
+@samp{<link>} elements with @samp{rel} attribute equal to
+@samp{``alternate''}, they are part of the page's metadata and are not
+visible in its rendered content.
+
@findex eww-open-in-new-buffer
@kindex M-RET
The @kbd{M-@key{RET}} command (@code{eww-open-in-new-buffer}) opens the
diff --git a/etc/NEWS b/etc/NEWS
index d703b7e77be..c2299c2998e 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -258,6 +258,13 @@ The interactive minibuffer prompt when invoking 'eww' now provides
completions from 'eww-suggest-uris'. 'eww-suggest-uris' now includes
bookmark URIs.
++++
+*** New command 'eww-copy-alternate-url'.
+It copies an alternate link to the page currently visited in EWW into
+the kill ring. Alternate links are optional metadata that HTML pages
+use for linking to their alternative representations, such as
+translated versions or associated RSS feeds.
+
** go-ts-mode
+++
diff --git a/lisp/net/eww.el b/lisp/net/eww.el
index 61f0f47373d..89f7ba37cc1 100644
--- a/lisp/net/eww.el
+++ b/lisp/net/eww.el
@@ -1086,6 +1086,7 @@ eww-mode-map
"&" #'eww-browse-with-external-browser
"d" #'eww-download
"w" #'eww-copy-page-url
+ "A" #'eww-copy-alternate-url
"C" #'url-cookie-list
"v" #'eww-view-source
"R" #'eww-readable
@@ -2576,4 +2577,82 @@ eww-bookmark-jump
(provide 'eww)
+;;; Alternate links (RSS and Atom feeds, etc.)
+
+(defun eww--alternate-urls (dom &optional base)
+ "Return an alist of alternate links in DOM.
+
+Each element is a list of the form (URL TYPE TITLE) where URL is
+the href attribute of the link expanded relative to BASE, TYPE is
+its type attribute, and TITLE is its title attribute. If any of
+these attributes is absent, the corresponding element is nil."
+ (let ((alternates
+ (seq-filter
+ (lambda (attrs) (string= (alist-get 'rel attrs)
+ "alternate"))
+ (mapcar #'dom-attributes (dom-by-tag dom 'link)))))
+ (mapcar (lambda (alternate)
+ (list (url-expand-file-name (alist-get 'href alternate)
+ base)
+ (alist-get 'type alternate)
+ (alist-get 'title alternate)))
+ alternates)))
+
+(defun eww-read-alternate-url ()
+ "Get the URL of an alternate link of this page.
+
+If there is just one alternate link, return its URL. If there
+are multiple alternate links, prompt for one in the minibuffer
+with completion. If there are none, return nil."
+ (when-let ((alternates (eww--alternate-urls
+ (plist-get eww-data :dom)
+ (plist-get eww-data :url))))
+ (let ((url-max-width
+ (seq-max (mapcar #'string-pixel-width
+ (mapcar #'car alternates))))
+ (title-max-width
+ (seq-max (mapcar #'string-pixel-width
+ (mapcar #'caddr alternates))))
+ (sep-width (string-pixel-width " ")))
+ (if (cdr alternates)
+ (let ((completion-extra-properties
+ (list :annotation-function
+ (lambda (feed)
+ (let* ((attrs (alist-get feed
+ alternates
+ nil
+ nil
+ #'string=))
+ (type (car attrs))
+ (title (cadr attrs)))
+ (concat
+ (propertize " " 'display
+ `(space :align-to
+ (,(+ sep-width
+ url-max-width))))
+ title
+ (when type
+ (concat
+ (propertize " " 'display
+ `(space :align-to
+ (,(+ (* 2 sep-width)
+ url-max-width
+ title-max-width))))
+ "[" type "]"))))))))
+ (completing-read "Alternate URL: " alternates nil t))
+ (caar alternates)))))
+
+(defun eww-copy-alternate-url ()
+ "Copy an alternate URL of the current page into the kill ring.
+
+Alternate links are references that an HTML page may include to
+point to its alternative representations, such as a translated
+version or an RSS feed."
+ (interactive nil eww-mode)
+ (if-let ((url (eww-read-alternate-url)))
+ (progn
+ (kill-new url)
+ (message "Copied %s to kill ring" url))
+ (user-error "No alternate links found on this page!")))
+
;;; eww.el ends here
--
2.41.0
next prev parent reply other threads:[~2023-06-21 17:20 UTC|newest]
Thread overview: 10+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-06-17 11:07 bug#64126: [PATCH] New command 'eww-copy-alternate-url' Eshel Yaron via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-06-17 13:07 ` Eli Zaretskii
2023-06-17 14:08 ` Eshel Yaron via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-06-17 17:08 ` Eshel Yaron via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-06-21 6:01 ` Eshel Yaron via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-06-21 11:00 ` Eli Zaretskii
2023-06-21 12:02 ` Eshel Yaron via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-06-21 14:04 ` Eli Zaretskii
2023-06-21 17:20 ` Eshel Yaron via Bug reports for GNU Emacs, the Swiss army knife of text editors [this message]
2023-06-24 12:00 ` Eli Zaretskii
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.gnu.org/software/emacs/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=m14jn0pw9w.fsf@eshelyaron.com \
--to=bug-gnu-emacs@gnu.org \
--cc=64126@debbugs.gnu.org \
--cc=eliz@gnu.org \
--cc=me@eshelyaron.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).