From: Spencer Baugh <sbaugh@janestreet.com>
To: 67310@debbugs.gnu.org
Cc: dmitry@gutov.dev, eliz@gnu.org, juri@linkov.net
Subject: bug#67310: [PATCH] Include the project--list as history when prompting for a project
Date: Mon, 20 Nov 2023 14:58:32 -0500 [thread overview]
Message-ID: <ier8r6s42on.fsf@janestreet.com> (raw)
[-- Attachment #1: Type: text/plain, Size: 1089 bytes --]
Tags: patch
The following patch uses project--list as a minibuffer history variable.
Now one can more easily switch between several related projects.
Independent from ongoing discussion about how to persist project--list
in bug#66993, this should be a useful improvement on its own.
This patch takes special care to avoid relying on savehist's persistent
mechanism, since savehist now knows about project--list as a minibuffer
history variable.
This patch does change the in-memory format of project--list, but not
the on-disk format, and project-known-project-roots still works, so this
patch should be backwards compatible.
In GNU Emacs 29.1.90 (build 2, x86_64-pc-linux-gnu, X toolkit, cairo
version 1.15.12, Xaw scroll bars) of 2023-11-20 built on
igm-qws-u22796a
Repository revision: dd8669b14b8a2b9a6d214a9d142dd8ac604f83d2
Repository branch: emacs-29
Windowing system distributor 'The X.Org Foundation', version 11.0.12011000
System Description: Rocky Linux 8.8 (Green Obsidian)
Configured using:
'configure --config-cache --with-x-toolkit=lucid
--with-gif=ifavailable'
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-Include-the-project-list-as-history-when-prompting-f.patch --]
[-- Type: text/patch, Size: 9830 bytes --]
From 89a4df13ca4c678bd9915e134c078607486348fe Mon Sep 17 00:00:00 2001
From: Spencer Baugh <sbaugh@janestreet.com>
Date: Mon, 20 Nov 2023 14:38:22 -0500
Subject: [PATCH] Include the project--list as history when prompting for a
project
The project--list is already ordered such that the most recently used
projects are at the front. Now we pass it as the history variable
when prompting for a project, so it can be used as minibuffer history.
To support this, we minorly change its in-memory format: Instead of a
list of lists, each containing a project-root, it's just a list of
project-roots directly. This lets us pass it directly to functions
completing-read and add-to-history. The persistent format (what's
saved in project-list-file) remains the same.
Since project--list is now a minibuffer history variable, if the user
has savehist enabled, project--list will be saved and restored by
savehist. To avoid that overriding our own persistence mechanism, we
need a separate project--list-initialized variable.
* lisp/progmodes/project.el (project--list): Update docstring for new
format.
(project--list-initialized): Add.
(project--ensure-read-project-list): Check project--list-initialized.
(project-known-project-roots, project-remember-projects-under)
(project--read-project-list, project--write-project-list)
(project-remember-project, project--remove-from-project-list): Support
new format for project--list.
(project-prompt-project-dir): Pass project--list as HIST to
completing-read.
(project--name-history, project-prompt-project-name): Pass a
preprocessed project--list as HIST to completing-read.
---
lisp/progmodes/project.el | 99 +++++++++++++++++++++++++--------------
1 file changed, 63 insertions(+), 36 deletions(-)
diff --git a/lisp/progmodes/project.el b/lisp/progmodes/project.el
index 95db9d0ef4c..bba1248fd73 100644
--- a/lisp/progmodes/project.el
+++ b/lisp/progmodes/project.el
@@ -1678,11 +1678,18 @@ project-list-file
:group 'project)
(defvar project--list 'unset
- "List structure containing root directories of known projects.
-With some possible metadata (to be decided).")
+ "List of root directories of known projects.
+
+This is also the minibuffer history variable for
+`project-prompt-project-dir' and `project-prompt-project-name'.")
+
+(defvar project--list-initialized nil)
(defun project--read-project-list ()
- "Initialize `project--list' using contents of `project-list-file'."
+ "Initialize `project--list' using contents of `project-list-file'.
+
+We expect `project-list-file' to contain a list of one-element
+lists, each containing a project root."
(let ((filename project-list-file))
(setq project--list
(when (file-exists-p filename)
@@ -1691,11 +1698,12 @@ project--read-project-list
(mapcar
(lambda (elem)
(let ((name (car elem)))
- (list (if (file-remote-p name) name
- (abbreviate-file-name name)))))
+ (if (file-remote-p name) name
+ (abbreviate-file-name name))))
(read (current-buffer))))))
+ (setq project--list-initialized t)
(unless (seq-every-p
- (lambda (elt) (stringp (car-safe elt)))
+ (lambda (elt) (stringp elt))
project--list)
(warn "Contents of %s are in wrong format, resetting"
project-list-file)
@@ -1703,20 +1711,22 @@ project--read-project-list
(defun project--ensure-read-project-list ()
"Initialize `project--list' if it isn't already initialized."
- (when (eq project--list 'unset)
+ (unless project--list-initialized
(project--read-project-list)))
(defun project--write-project-list ()
- "Save `project--list' in `project-list-file'."
+ "Save `project--list' in `project-list-file'.
+
+We store `project--list' as a list of one-element lists, each
+containing a project root."
(let ((filename project-list-file))
(with-temp-buffer
(insert ";;; -*- lisp-data -*-\n")
(let ((print-length nil)
(print-level nil))
- (pp (mapcar (lambda (elem)
- (let ((name (car elem)))
- (list (if (file-remote-p name) name
- (expand-file-name name)))))
+ (pp (mapcar (lambda (name)
+ (list (if (file-remote-p name) name
+ (expand-file-name name))))
project--list)
(current-buffer)))
(write-region nil nil filename nil 'silent))))
@@ -1728,11 +1738,10 @@ project-remember-project
has changed, and NO-WRITE is nil."
(project--ensure-read-project-list)
(let ((dir (abbreviate-file-name (project-root pr))))
- (unless (equal (caar project--list) dir)
- (dolist (ent project--list)
- (when (equal dir (car ent))
- (setq project--list (delq ent project--list))))
- (push (list dir) project--list)
+ (unless (equal (car project--list) dir)
+ (let ((history-delete-duplicates t)
+ (history-length t))
+ (add-to-history 'project--list dir))
(unless no-write
(project--write-project-list)))))
@@ -1743,10 +1752,11 @@ project--remove-from-project-list
from the list using REPORT-MESSAGE, which is a format string
passed to `message' as its first argument."
(project--ensure-read-project-list)
- (when-let ((ent (assoc (abbreviate-file-name project-root) project--list)))
- (setq project--list (delq ent project--list))
- (message report-message project-root)
- (project--write-project-list)))
+ (let ((dir (abbreviate-file-name project-root)))
+ (when (member dir project--list)
+ (setq project--list (delete dir project--list))
+ (message report-message project-root)
+ (project--write-project-list))))
;;;###autoload
(defun project-forget-project (project-root)
@@ -1772,24 +1782,34 @@ project-prompt-project-dir
(pr-dir ""))
(while (equal pr-dir "")
;; If the user simply pressed RET, do this again until they don't.
- (setq pr-dir (completing-read "Select project: " choices nil t)))
+ (setq pr-dir
+ (let ((history-delete-duplicates t)
+ (history-length t))
+ (completing-read "Select project: " choices nil t nil 'project--list))))
(if (equal pr-dir dir-choice)
(read-directory-name "Select directory: " default-directory nil t)
pr-dir)))
+(defvar project--name-history)
+
(defun project-prompt-project-name ()
"Prompt the user for a project, by name, that is one of the known project roots.
The project is chosen among projects known from the project list,
see `project-list-file'.
It's also possible to enter an arbitrary directory not in the list."
(let* ((dir-choice "... (choose a dir)")
+ project--name-history
(choices
(let (ret)
- (dolist (dir (project-known-project-roots))
+ ;; Iterate in reverse order so project--name-history is in
+ ;; the correct order.
+ (dolist (dir (reverse project--list))
;; we filter out directories that no longer map to a project,
;; since they don't have a clean project-name.
- (if-let (proj (project--find-in-directory dir))
- (push (cons (project-name proj) proj) ret)))
+ (when-let (proj (project--find-in-directory dir))
+ (let ((name (project-name proj)))
+ (push name project--name-history)
+ (push (cons name proj) ret))))
ret))
;; XXX: Just using this for the category (for the substring
;; completion style).
@@ -1798,17 +1818,23 @@ project-prompt-project-name
(pr-name ""))
(while (equal pr-name "")
;; If the user simply pressed RET, do this again until they don't.
- (setq pr-name (completing-read "Select project: " table nil t)))
+ (setq pr-name
+ (let ((history-add-new-input nil))
+ (completing-read "Select project: " table nil t nil 'project--name-history))))
(if (equal pr-name dir-choice)
(read-directory-name "Select directory: " default-directory nil t)
- (let ((proj (assoc pr-name choices)))
- (if (stringp proj) proj (project-root (cdr proj)))))))
+ (let* ((proj (assoc pr-name choices))
+ (root (project-root (cdr proj))))
+ (let ((history-delete-duplicates t)
+ (history-length t))
+ (add-to-history 'project--list root))
+ root))))
;;;###autoload
(defun project-known-project-roots ()
"Return the list of root directories of all known projects."
(project--ensure-read-project-list)
- (mapcar #'car project--list))
+ project--list)
;;;###autoload
(defun project-execute-extended-command ()
@@ -1866,13 +1892,14 @@ project-remember-projects-under
projects."
(interactive "DDirectory: \nP")
(project--ensure-read-project-list)
- (let ((dirs (if recursive
- (directory-files-recursively dir "" t)
- (directory-files dir t)))
- (known (make-hash-table :size (* 2 (length project--list))
- :test #'equal))
- (count 0))
- (dolist (project (mapcar #'car project--list))
+ (let* ((dirs (if recursive
+ (directory-files-recursively dir "" t)
+ (directory-files dir t)))
+ (roots (project-known-project-roots))
+ (known (make-hash-table :size (* 2 (length roots))
+ :test #'equal))
+ (count 0))
+ (dolist (project roots)
(puthash project t known))
(dolist (subdir dirs)
(when-let (((file-directory-p subdir))
--
2.39.3
next reply other threads:[~2023-11-20 19:58 UTC|newest]
Thread overview: 30+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-11-20 19:58 Spencer Baugh [this message]
2023-11-21 11:06 ` bug#67310: [PATCH] Include the project--list as history when prompting for a project Dmitry Gutov
2023-11-21 11:14 ` Dmitry Gutov
2023-11-21 15:17 ` Spencer Baugh
2023-11-22 1:40 ` Dmitry Gutov
2023-11-22 16:18 ` Spencer Baugh
2023-11-22 18:44 ` Dmitry Gutov
2023-11-22 23:14 ` Spencer Baugh
2023-11-23 2:55 ` Dmitry Gutov
2023-11-24 15:50 ` Spencer Baugh
2023-11-25 2:07 ` Dmitry Gutov
2023-11-25 17:50 ` Juri Linkov
2023-11-27 17:10 ` Juri Linkov
2023-12-10 3:04 ` Dmitry Gutov
2023-12-10 17:43 ` Juri Linkov
2023-12-10 20:32 ` Dmitry Gutov
2023-12-11 17:12 ` Juri Linkov
2023-12-12 0:21 ` Dmitry Gutov
2023-12-14 1:02 ` sbaugh
2023-12-19 17:35 ` Juri Linkov
2023-11-23 6:38 ` Eli Zaretskii
2023-11-25 1:54 ` Dmitry Gutov
2023-11-25 8:42 ` Eli Zaretskii
2023-11-25 14:05 ` Dmitry Gutov
2023-11-25 14:10 ` Eli Zaretskii
2023-11-25 15:06 ` Dmitry Gutov
2023-11-25 15:57 ` Eli Zaretskii
2023-11-25 16:35 ` Dmitry Gutov
2023-11-22 1:42 ` Dmitry Gutov
2023-11-22 16:21 ` Spencer Baugh
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.gnu.org/software/emacs/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=ier8r6s42on.fsf@janestreet.com \
--to=sbaugh@janestreet.com \
--cc=67310@debbugs.gnu.org \
--cc=dmitry@gutov.dev \
--cc=eliz@gnu.org \
--cc=juri@linkov.net \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).