(defvar xmltok-start) ;; from xmltok.el
(defun nxml-compute-indent-in-delimited-token-override (pos open-delim close-delim)
  "Return the indent for a line that start inside a token with delimiters.
OPEN-DELIM and CLOSE-DELIM are strings giving the opening and closing
delimiters.  POS is the position of the first non-whitespace character
of the line.  This expects the xmltok-* variables to be set up as by
`xmltok-forward'.
Fix: https://debbugs.gnu.org/cgi/bugreport.cgi?bug=73206"
  (cond ((let ((end (+ pos (length close-delim))))
	   (and (<= end (point-max))
		(string= (buffer-substring-no-properties pos end)
			 close-delim)))
	 (goto-char xmltok-start))
	((progn
	   (goto-char pos)
	   (forward-line -1)
           (while (looking-at "^[[:blank:]]*$")
	     (forward-line -1))
	   (<= (point) xmltok-start))
	 (goto-char (+ xmltok-start (length open-delim)))
	 (when (and (string= open-delim "<!--")
		    (looking-at " "))
	   (goto-char (1+ (point)))))
	(t (back-to-indentation)))
  (current-column))

(when (version<= emacs-version "29")
  ;; Assume https://debbugs.gnu.org/cgi/bugreport.cgi?bug=73206 will be fixed in Emacs 30
  (eval-after-load 'nxml-mode
    '(advice-add 'nxml-compute-indent-in-delimited-token
                 :override
                 #'nxml-compute-indent-in-delimited-token-override)))