bug#46476: Feature request: Right-aligning part of the modeline

["Paweł Kraśnicki" <paul.krasnicki@gmail.com>]

> Can you describe how is this done in Lisp?

Sure. The most common solution is to use a text property that displays a space
with the `:align-to' property. Here's a simplified version of the code from the
popular `powerline' package:

(defvar ml-text-scale-factor 1.0
  "Ratio of mode-line text size to default text size, as a float.
This is needed to make sure the text is properly aligned.")

(defun ml-fill-to-center (reserve face)
  "Return empty space to the center, leaving RESERVE space on the right."
  (setq reserve (* ml-text-scale-factor reserve))
  (propertize " "
              'display `((space :align-to (- (+ center (.5 . right-margin))
                                             ,reserve
                                             (.5 . left-margin))))
              'face face))

(defun ml-fill-to-right (reserve face)
  "Return empty space, leaving RESERVE space on the right."
  (setq reserve (* ml-text-scale-factor reserve))
  (when (and window-system (eq 'right (get-scroll-bar-mode)))
    (setq reserve (- reserve 2))) ; May be 3 instead of 2 with some toolkits?
  (propertize " "
              'display `((space :align-to (- (+ right right-fringe right-margin)
                                             ,reserve)))
              'face face))

(defun ml-render-2-part (left right &optional fill-face)
  "Show a modeline with left and right aligned parts."
  (concat left
          (ml-fill-to-right (string-width (format-mode-line right)) fill-face)
          right))

(defun ml-render-3-part (left center right &optional fill-face)
  "Show a modeline with left, center, and right aligned parts."
  (concat left
          (ml-fill-to-center (/ (string-width (format-mode-line center)) 2.0)
                             fill-face)
          center
          (ml-fill-to-right (string-width (format-mode-line right)) fill-face)
          right))

;; (setq mode-line-format '((:eval (ml-render-2-part "l" "r"))))
;; (setq mode-line-format '((:eval (ml-render-3-part "lllll" "c" "r"))))

> The immediate question about this I have is what to do when the
> mode-line string is too long for the window's width?  Right now, we
> simply chop the stuff on the right that doesn't fit, but if the
> mode-line string has 2 or 3 different part, that should be revised,
> right?

I'm not sure. With the current Lisp solutions, the modeline gets chopped on the
right too, and it seems that people either don't mind that at all, or they use
custom "segment" logic. The idea here is that the modeline is composed of a few
segments, with each having a priority number. As the window shrinks, the
segments get hidden in discrete jumps starting from the lowest priority, until
only the segment(s) with the highest priority number remain. I think there may
not be any demand for an intermediate solution that would let the user configure
hiding with granularity of left/center/right.