bug#27647: 26.0.50; Line numbers implemented natively disappear momentarily when frame out of focus

[Kaushal Modi <kaushal.modi@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 4758 bytes --]

On Tue, Jul 11, 2017 at 10:38 AM Kaushal Modi <kaushal.modi@gmail.com>
wrote:

>
> I will set up the Lisp watchpoints and debug more, thanks.
>
> I have one more data point. Apparently I do not need to "click" on the
> emacs frame to make the line numbers reappear. They reappeared seemingly
> randomly or just as I was just hovering the mouse over the emacs frame..
> odd.  This happened just as I was preparing to record "line num
> reappearance on click" effect, but the line numbers reappeared by
> themselves even before I clicked.
>

This is what I see (I was able to record the moment when the lines
reappeared on clicking anywhere in the window):
http://i.imgur.com/5C5FmGS.gifv

When the above happened, the point was in a Fundamental Mode buffer window
and the other window had this file in emacs-lisp-mode. I do not have
display-line-numbers set to t globally; so fundamental-mode has that value
at nil and the elisp window had that set to t. Again the line num
disappearance happened when the emacs frame was out of focus.

Interestingly the variable watcher did not get triggered.

This is how I set the watcher:

=====
(defvar modi/variables-to-be-watched '(display-line-numbers)
  "List of variables to be watched.
Used by `modi/set-variable-watchers' and
`modi/unset-variable-watchers'")

(defun modi/variable-watcher-fn (symbol newval operation where)
  "Print message when the value of variable SYMBOL changes.
The message shows the NEWVAL it changed to, the OPERATION that
caused that, and the buffer WHERE that happened if the value
change was buffer-local."
  (message (format "[Watcher: %s] Now set to %S, by `%S'%s"
                   (symbol-name symbol)
                   newval
                   operation
                   (if where
                       (format " in %S" where)
                     ""))))

(defun modi/set-variable-watchers ()
  "Enable printing messages when any watched variable changes.
The variables to be watched should be added to
`modi/variables-to-be-watched'."
  (interactive)
  (dolist (var modi/variables-to-be-watched)
    (add-variable-watcher var #'modi/variable-watcher-fn)))

(modi/set-variable-watchers)
=====

When I revert-buffer in an emacs-lisp-mode file, I see these:

[Watcher: display-line-numbers] Now set to nil, by ‘makunbound’ in #<buffer
setup-linum.el>
[Watcher: display-line-numbers] Now set to nil, by ‘set’ in #<buffer
setup-linum.el>
[Watcher: display-line-numbers] Now set to t, by ‘set’ in #<buffer
setup-linum.el>

But none of those [Watcher:..] messages showed up when the line numbers
auto-disappeared and also when re-appeared on the click in the buffer.

Not sure if this would help, but here is how I enable the line numbers
(modified compared to the version I posted earlier in this thread):

=====
(defvar modi/native-linum-default t
  "Value set for `display-line-numbers' when enabled.
Valid values are t, `visual', `relative' and nil. See
`display-line-numbers' for more information.")

(defun modi/native-linum--on (&optional global)
  "Enable native line number display in the current buffer.
If GLOBAL is non-nil, enable this globally."
  (interactive "P")
  (if global
      (setq-default display-line-numbers modi/native-linum-default)
    (setq-local display-line-numbers modi/native-linum-default)))

(defun modi/native-linum--off (&optional global)
  "Disable native line number display in the current buffer.
If GLOBAL is non-nil, disable this globally."
  (interactive "P")
  (if global
      (setq-default display-line-numbers nil)
    (setq-local display-line-numbers nil)))

(defun modi/turn-on-native-linum ()
  "Turn on native line numbers in specific modes.
In enabled state, `display-line-numbers' is set to
`modi/native-linum-default'."
  (interactive)
  (if modi/linum-mode-enable-global
      (progn
        (dolist (hook modi/linum-mode-hooks)
          (remove-hook hook #'modi/native-linum--on))
        (modi/native-linum--on :global))
    (progn
      (modi/native-linum--off :global)
      (dolist (hook modi/linum-mode-hooks)
        (add-hook hook #'modi/native-linum--on)))))

(defun modi/linum--enable (&optional frame)
  "Set “linum” using the default package set by the user in
`modi/linum-fn-default'.

The optional FRAME argument is added as it is needed if this
function is added to the `after-make-frame-functions' hook."
  (modi/turn-on-native-linum))

(if (daemonp)
    (add-hook 'after-make-frame-functions #'modi/linum--enable)
  (add-hook 'after-init-hook #'modi/linum--enable))
=====

Does anything look problematic in the above code from a quick glance.


-- 

Kaushal Modi

[-- Attachment #2: Type: text/html, Size: 6726 bytes --]