#! /usr/bin/env zsh
#set -x

# Build Emacs from scratch.

# Display usage information and exit.
function usage () {
    cat <<EOF
Usage $0 [options]

Build Emacs starting from a clean Git repository.  When run without
addtional command-line flags, build with native compilation.

--asan		build with address sanitizer and -O1 (this takes 3x the
		time of a build without)
--bootstrap	make bootstrap
--checking	configure with --emanle-checking
--configure	run configure only
--debug		configure with -g -O0
--elc		build without native compilation
--help		show this help
--no-cache      delete config cache

Add 'compdef _gnu_generic make-emacs' to your ~/.zshrc for options
completion on the command line.
EOF
    exit 1
}

# Parse command line options. 
zmodload zsh/zutil
if ! zparseopts -E -D -F -- \
     -asan=asan \
     -bootstrap=bootstrap \
     -checking=checking \
     -configure=conf \
     -debug=debug \
     -elc=elc \
     -help=help \
     -no-cache=no_cache \
	|| [ "$help" != "" ]
then
    usage
fi

# Go to the root of the current worktree.
while ! test -f configure.ac; do
    if [ "$(pwd)" = "/" ]; then
	echo "Not in worktree"
	exit 
    fi
    cd ..
done

# The file to use as config.cache
worktree="$(basename $(pwd))"
config_cache=~"/tmp/config.cache.$worktree"

# Delete the config cache file if --no-config is specified.
if [ "$no_cache" != "" ]; then
    rm -f $config_cache
fi

# Flags and options to pass to configure.
config_flags=(--cache-file $config_cache)

# Configure with --enable-checking
if [ "$checking" != "" ]; then
    config_flags+=(--enable-checking)
fi

# Build with native compiler unless --elc is specified.
if [ "$elc" = "" ]; then
    config_flags+=(--with-native-compilation)
fi

config_flags+=(--disable-silent-rules)
#config_flags+=(--with-tree-sitter)

# Define CFLAGS and LDFLAGS for address sanitizer if --asan is
# specified.
if [ "$asan" != "" ]; then
    config_flags+=(LDFLAGS="-fsanitize=address -fno-omit-frame-pointer"
		   CFLAGS="-g -O0 -fsanitize=address -fno-omit-frame-pointer")
elif [ "$debug" != "" ]; then
    config_flags+=(CFLAGS="-g -O0")
fi

# Clean Git repo, configure and make install.  Also, build a
# compilation database while we're at it.
function build_emacs_from_scratch () {
    git clean -qxdf \
	&& ./autogen.sh \
	&& ./configure $config_flags[@] \
	&& bear -- gmake --output-sync=line \
	&& emacs-fixup-compile-commands.py \
	&& gmake install
}

function bootstrap_emacs () {
    ./configure $config_flags[@] \
	&& bear -- make bootstrap \
}

# Note that the zsh built-in 'time' is not able to time shell
# functions directly, it just prints nothing.  We have to use a
# sub-shell instead.
TIMEFMT=$'\nreal\t%*E\nuser\t%*U\nsys\t%*S'

if [ "$conf" != "" ]; then
    time ./configure $config_flags[@]
elif [ "$bootstrap" != "" ]; then
    time (bootstrap_emacs)
else
    time (build_emacs_from_scratch)
fi

echo "$0 $config_flags[@] complete."
    
# End.