unofficial mirror of bug-gnu-emacs@gnu.org 
 help / color / mirror / code / Atom feed
* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
@ 2021-06-08 10:31 pillule
  2021-06-08 11:49 ` Eli Zaretskii
  0 siblings, 1 reply; 8+ messages in thread
From: pillule @ 2021-06-08 10:31 UTC (permalink / raw)
  To: 48917

[-- Attachment #1: Type: text/plain, Size: 1012 bytes --]


Hi,

This is not directly related to bug#48916 but nonetheless derive 
from a same logic of window management.

Actually the user can choose if windmove will create a window when 
it encounter the edges of the frame. I propose to let the user 
eventually provides instead a function that will be triggered in 
that case.

The function will receive as arguments the `dir' and `window' 
bindings of `windmove-do-window-select' so it can adapt its 
behavior accordingly.

The simplest use case I found for this feature is to creates a 
dispatch function that choose from the direction to display eg, a 
dired side window on the left, a shell side window on the top, a 
message side window on the bottom, another thing on the right ; 
and that act as a toggle, eg :

windmove-left : creates a dired side window
windmove-left again : delete the dired side window

From here the function can be tuned again to behave differently in 
different contexts with eg, a local binding or by inspecting the 
WINDOW argument.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: allow user to choose what function is used when windmove create a window --]
[-- Type: text/x-diff, Size: 1877 bytes --]

From cf9007ce6fdba60a1c27b0952833139731c9fe8c Mon Sep 17 00:00:00 2001
From: Trust me I am a doctor <pillule@riseup.net>
Date: Tue, 8 Jun 2021 11:44:54 +0200
Subject: [PATCH] User option to choose a function triggered by windmove-create

* lisp/windmove.el
  (windmove-create-window): add a defcustom choice
  (windmove-do-window-select): trigger custom functions
---
 lisp/windmove.el | 11 ++++++++---
 1 file changed, 8 insertions(+), 3 deletions(-)

diff --git a/lisp/windmove.el b/lisp/windmove.el
index f558903681..d648613e10 100644
--- a/lisp/windmove.el
+++ b/lisp/windmove.el
@@ -142,11 +142,14 @@ windmove-wrap-around
   :group 'windmove)
 
 (defcustom windmove-create-window nil
-  "Whether movement off the edge of the frame creates a new window.
+  "Whether movement off the edge of the frame creates a new window or
+trigger a custom function.
 If this variable is set to t, moving left from the leftmost window in
 a frame will create a new window on the left, and similarly for the other
 directions."
-  :type 'boolean
+  :type '(choice (const :tag "Don't create new windows" nil)
+          (const :tag "Create new windows" t)
+          (function :tag "Provide a function"))
   :group 'windmove
   :version "27.1")
 
@@ -357,7 +360,9 @@ windmove-do-window-select
                (or (null other-window)
                    (and (window-minibuffer-p other-window)
                         (not (minibuffer-window-active-p other-window)))))
-      (setq other-window (split-window window nil dir)))
+      (setq other-window (if (functionp windmove-create-window)
+                             (funcall windmove-create-window dir window)
+                           (split-window window nil dir))))
     (cond ((null other-window)
            (user-error "No window %s from selected window" dir))
           ((and (window-minibuffer-p other-window)
-- 
2.20.1


[-- Attachment #3: Type: text/plain, Size: 441 bytes --]


The second attachment is a library I am currently working on that 
implement a functional dired side window and its windmove bindings 
in 200 loc, so you can eventually try it and feel what I am 
requesting.
I wrote it for testing purposes for bug#48493 so some of its 
functionalities relies on fixes that are not yet available, and it 
is less about dired in a side window than implementing local 
bindings on couples of buffer/windows.


[-- Attachment #4: moirai early stage --]
[-- Type: application/gzip, Size: 34691 bytes --]

^ permalink raw reply	[flat|nested] 8+ messages in thread

* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
  2021-06-08 10:31 bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window pillule
@ 2021-06-08 11:49 ` Eli Zaretskii
  2021-06-08 14:12   ` pillule
  0 siblings, 1 reply; 8+ messages in thread
From: Eli Zaretskii @ 2021-06-08 11:49 UTC (permalink / raw)
  To: pillule; +Cc: 48917

> From: pillule <pillule@riseup.net>
> Date: Tue, 08 Jun 2021 12:31:58 +0200
> 
>  (defcustom windmove-create-window nil
> -  "Whether movement off the edge of the frame creates a new window.
> +  "Whether movement off the edge of the frame creates a new window or
> +trigger a custom function.

The first line of a doc string should be a single complete sentence.
(The reason for this is that some Emacs commands, like "M-x apropos",
show only the first line of the doc string.)

>  If this variable is set to t, moving left from the leftmost window in
>  a frame will create a new window on the left, and similarly for the other
>  directions."
> -  :type 'boolean
> +  :type '(choice (const :tag "Don't create new windows" nil)
> +          (const :tag "Create new windows" t)
> +          (function :tag "Provide a function"))
>    :group 'windmove
>    :version "27.1")

The :version tag should be updated, because the defcustom was changed.





^ permalink raw reply	[flat|nested] 8+ messages in thread

* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
  2021-06-08 11:49 ` Eli Zaretskii
@ 2021-06-08 14:12   ` pillule
  2021-06-12 22:09     ` Juri Linkov
  0 siblings, 1 reply; 8+ messages in thread
From: pillule @ 2021-06-08 14:12 UTC (permalink / raw)
  To: Eli Zaretskii; +Cc: pillule, 48917

[-- Attachment #1: Type: text/plain, Size: 1040 bytes --]


Eli Zaretskii <eliz@gnu.org> writes:

>> From: pillule <pillule@riseup.net>
>> Date: Tue, 08 Jun 2021 12:31:58 +0200
>>
>>  (defcustom windmove-create-window nil
>> -  "Whether movement off the edge of the frame creates a new 
>> window.
>> +  "Whether movement off the edge of the frame creates a new 
>> window or
>> +trigger a custom function.
>
> The first line of a doc string should be a single complete 
> sentence.
> (The reason for this is that some Emacs commands, like "M-x 
> apropos",
> show only the first line of the doc string.)
>
>>  If this variable is set to t, moving left from the leftmost 
>>  window in
>>  a frame will create a new window on the left, and similarly 
>>  for the other
>>  directions."
>> -  :type 'boolean
>> +  :type '(choice (const :tag "Don't create new windows" nil)
>> +          (const :tag "Create new windows" t)
>> +          (function :tag "Provide a function"))
>>    :group 'windmove
>>    :version "27.1")
>
> The :version tag should be updated, because the defcustom was 
> changed.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: allow user to choose what function is used when windmove create a window --]
[-- Type: text/x-diff, Size: 2155 bytes --]

From 6438107565875ff69f533c244a9601192218e7c9 Mon Sep 17 00:00:00 2001
From: Trust me I am a doctor <pillule@riseup.net>
Date: Tue, 8 Jun 2021 11:44:54 +0200
Subject: [PATCH] User option to choose a function triggered by windmove-create

* lisp/windmove.el (windmove-create-window): Add a defcustom choice.
(windmove-do-window-select): Trigger custom functions.
---
 lisp/windmove.el | 17 +++++++++++------
 1 file changed, 11 insertions(+), 6 deletions(-)

diff --git a/lisp/windmove.el b/lisp/windmove.el
index f558903681..d410e387d4 100644
--- a/lisp/windmove.el
+++ b/lisp/windmove.el
@@ -142,13 +142,16 @@ windmove-wrap-around
   :group 'windmove)
 
 (defcustom windmove-create-window nil
-  "Whether movement off the edge of the frame creates a new window.
+  "Whether movement off the edge of the frame create a window.
 If this variable is set to t, moving left from the leftmost window in
 a frame will create a new window on the left, and similarly for the other
-directions."
-  :type 'boolean
-  :group 'windmove
-  :version "27.1")
+directions.
+The variable may also be a function to be called in this circumstance,
+the function should accept as agument a DIRECTION, and the selected WINDOW."
+  :type '(choice (const :tag "Don't create new windows" nil)
+          (const :tag "Create new windows" t)
+          (function :tag "Provide a function"))
+  :version "28.0.50")
 
 ;; If your Emacs sometimes places an empty column between two adjacent
 ;; windows, you may wish to set this delta to 2.
@@ -357,7 +360,9 @@ windmove-do-window-select
                (or (null other-window)
                    (and (window-minibuffer-p other-window)
                         (not (minibuffer-window-active-p other-window)))))
-      (setq other-window (split-window window nil dir)))
+      (setq other-window (if (functionp windmove-create-window)
+                             (funcall windmove-create-window dir window)
+                           (split-window window nil dir))))
     (cond ((null other-window)
            (user-error "No window %s from selected window" dir))
           ((and (window-minibuffer-p other-window)
-- 
2.20.1


[-- Attachment #3: Type: text/plain, Size: 4 bytes --]


--

^ permalink raw reply	[flat|nested] 8+ messages in thread

* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
  2021-06-08 14:12   ` pillule
@ 2021-06-12 22:09     ` Juri Linkov
  2021-06-15 22:04       ` pillule
  0 siblings, 1 reply; 8+ messages in thread
From: Juri Linkov @ 2021-06-12 22:09 UTC (permalink / raw)
  To: pillule; +Cc: 48917

>>>    :version "27.1")
>>
>> The :version tag should be updated, because the defcustom was changed.
>
> -  :version "27.1")
> +  :version "28.0.50")

Thanks for sending two patches in bug#48916 and bug#48917.
If you have not signed papers yet, I guess
these patches are small enough to push.

But in both patches please change the :version tag to "28.1".





^ permalink raw reply	[flat|nested] 8+ messages in thread

* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
  2021-06-12 22:09     ` Juri Linkov
@ 2021-06-15 22:04       ` pillule
  2021-06-15 22:20         ` pillule
  2021-06-15 23:32         ` Juri Linkov
  0 siblings, 2 replies; 8+ messages in thread
From: pillule @ 2021-06-15 22:04 UTC (permalink / raw)
  To: Juri Linkov; +Cc: pillule, 48917

[-- Attachment #1: Type: text/plain, Size: 815 bytes --]


Juri Linkov <juri@linkov.net> writes:

>>>>    :version "27.1")
>>>
>>> The :version tag should be updated, because the defcustom was changed.
>>
>> -  :version "27.1")
>> +  :version "28.0.50")

Done.

> Thanks for sending two patches in bug#48916 and bug#48917.
> If you have not signed papers yet, I guess
> these patches are small enough to push.
>
> But in both patches please change the :version tag to "28.1".

I get the papers now \o/

I was a little bit worried that this user-option is quite obscure to understand,
so among other little docstring fixes, I documented an usage with
'display-buffer-alist' in the commentary section of the package.

Please let me know if it is not desirable, in which case I will remove it.

Also I added the parent function ARG to be passed, it is an universal-argument.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: allow user to choose what function is used when windmove create a window --]
[-- Type: text/x-diff, Size: 6259 bytes --]

From f276e2b7fe96512b1ed88be8f8da66faab7a24e4 Mon Sep 17 00:00:00 2001
From: Trust me I am a doctor <pillule@riseup.net>
Date: Tue, 8 Jun 2021 11:44:54 +0200
Subject: [PATCH] User option to choose a function triggered by windmove-create

* lisp/windmove.el (windmove-create-window): Add a defcustom choice.
(windmove-do-window-select): Trigger custom functions, update the
docstring.

Commentary: document the usage of this user option with a basic
'display-buffer-alist', a dispatcher function for
'windmove-create-window' and an alist to hold the dispatch.
---
 lisp/windmove.el | 92 ++++++++++++++++++++++++++++++++++++++++++++----
 1 file changed, 85 insertions(+), 7 deletions(-)

diff --git a/lisp/windmove.el b/lisp/windmove.el
index f558903681..e49b6ad654 100644
--- a/lisp/windmove.el
+++ b/lisp/windmove.el
@@ -110,6 +110,72 @@
 ;;    (setq windmove-wrap-around t)
 ;;
 
+;; Configuring windmove to display side windows :
+;;
+;; Assuming you have customized your 'display-buffer-alist' to
+;; uses side-windows, see (info "(elisp) Choosing Window")
+;;
+;; Or refer to this basic example :
+;;
+;; (customize-set-variable 'display-buffer-alist
+;; 			'(("\\*Ibuffer\\*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . left) (window-width . 42))
+;; 			  ("\\*Info.*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . right) (window-width . 80))
+;; 			  ("\\*e?shell.*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . top))
+;; 			  ("\\*Messages.*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . bottom))))
+;;
+;; You can create a function that will dispatch the calls by direction :
+;;
+;; (defun windmove-create-side-window (dir arg window)
+;;   "Intermedary function choosing what to call on direction DIR.
+;; If the selected-window is a side-window, delete it, otherwise,
+;; select the relevant window from `windmove-dispatch-sides-functions'.
+;; Only pass ARG and WINDOW to the childs functions."
+;;   ;; normalise the direction
+;;   (let ((dir (pcase dir (`up 'top) (`down 'bottom) (_ dir))))
+;;     (funcall (if (eq dir (window-parameter window 'window-side))
+;;                  (lambda (_dir _arg window)
+;;                    (prog1 (get-mru-window) (delete-window window)))
+;;                (alist-get dir windmove-dispatch-sides-functions))
+;;              dir arg window)))
+;;
+;; Then assign it to 'windmove-create-window'
+;;
+;; (customize-set-variable 'windmove-create-window
+;;                         #'windmove-create-side-window)
+;;
+;; You can then specify an alist to actually hold the functions
+;; to be called with their directions :
+;;
+;; (defvar windmove-dispatch-sides-functions
+;;   '((left . (lambda (_dir _arg _window)
+;;               (ibuffer 'other-window)
+;;               (get-buffer-window "*Ibuffer*")))
+;;     (right . (lambda (_dir _arg _window)
+;;                (let ((buffer (get-buffer "*info*")))
+;;                  (if buffer
+;;                      (display-buffer buffer)
+;;                    (info))
+;;                  (get-buffer-window "*info*"))))
+;;     (top . (lambda (_dir _arg _window)
+;;              (shell)
+;;              (get-buffer-window "*shell*")))
+;;     (bottom . (lambda (_arg _dir _window)
+;;                 (view-echo-area-messages)
+;;                 'no-select)))
+;;   "Alist to dispatch by direction the calls of `windmove-create-side-window'")
+;;
+;; And also activate this recommended setting :
+;;
+;; (customize-set-variable 'windmove-allow-all-windows t)
+
 ;; Acknowledgments:
 ;;
 ;; Special thanks to Julian Assange (proff@iq.org), whose
@@ -142,13 +208,21 @@ windmove-wrap-around
   :group 'windmove)
 
 (defcustom windmove-create-window nil
-  "Whether movement off the edge of the frame creates a new window.
+  "Whether movement off the edge of the frame create a new window.
 If this variable is set to t, moving left from the leftmost window in
 a frame will create a new window on the left, and similarly for the other
-directions."
-  :type 'boolean
-  :group 'windmove
-  :version "27.1")
+directions.
+This variable may also be a function to be called in this circumstance
+by `windmove-do-window-select'.  The function should accept then as
+argument the DIRECTION targeted, an interactive ARG and a WINDOW
+corresponding to the currently selected window.  It should also returns
+or a valid window that `windmove-do-window-select' will select,
+or the symbol 'no-select to ignore that final selection.
+The comments of windmove.el show an example of this utilisation."
+  :type '(choice (const :tag "Don't create new windows" nil)
+          (const :tag "Create new windows" t)
+          (function :tag "Provide a function"))
+  :version "28.1")
 
 ;; If your Emacs sometimes places an empty column between two adjacent
 ;; windows, you may wish to set this delta to 2.
@@ -350,19 +424,23 @@ windmove-do-window-select
   "Move to the window at direction DIR as seen from WINDOW.
 DIR, ARG, and WINDOW are handled as by `windmove-find-other-window'.
 If no window is at direction DIR, an error is signaled.
-If `windmove-create-window' is non-nil, try to create a new window
+If `windmove-create-window' is a function, call that function with
+DIR, ARG and WINDOW, if it is non-nil, try to create a new window
 in direction DIR instead."
   (let ((other-window (windmove-find-other-window dir arg window)))
     (when (and windmove-create-window
                (or (null other-window)
                    (and (window-minibuffer-p other-window)
                         (not (minibuffer-window-active-p other-window)))))
-      (setq other-window (split-window window nil dir)))
+      (setq other-window (if (functionp windmove-create-window)
+                             (funcall windmove-create-window dir arg window)
+                           (split-window window nil dir))))
     (cond ((null other-window)
            (user-error "No window %s from selected window" dir))
           ((and (window-minibuffer-p other-window)
                 (not (minibuffer-window-active-p other-window)))
            (user-error "Minibuffer is inactive"))
+          ((eq other-window 'no-select))
           (t
            (select-window other-window)))))
 
-- 
2.20.1


[-- Attachment #3: Type: text/plain, Size: 4 bytes --]


--

^ permalink raw reply	[flat|nested] 8+ messages in thread

* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
  2021-06-15 22:04       ` pillule
@ 2021-06-15 22:20         ` pillule
  2021-06-15 23:32         ` Juri Linkov
  1 sibling, 0 replies; 8+ messages in thread
From: pillule @ 2021-06-15 22:20 UTC (permalink / raw)
  To: pillule; +Cc: 48917, Juri Linkov

[-- Attachment #1: Type: text/plain, Size: 917 bytes --]


pillule <pillule@riseup.net> writes:

> Juri Linkov <juri@linkov.net> writes:
>
>>>>>    :version "27.1")
>>>>
>>>> The :version tag should be updated, because the defcustom was changed.
>>>
>>> -  :version "27.1")
>>> +  :version "28.0.50")
>
> Done.
>
>> Thanks for sending two patches in bug#48916 and bug#48917.
>> If you have not signed papers yet, I guess
>> these patches are small enough to push.
>>
>> But in both patches please change the :version tag to "28.1".
>
> I get the papers now \o/
>
> I was a little bit worried that this user-option is quite obscure to understand,
> so among other little docstring fixes, I documented an usage with
> 'display-buffer-alist' in the commentary section of the package.
>
> Please let me know if it is not desirable, in which case I will remove it.
>
> Also I added the parent function ARG to be passed, it is an universal-argument.

hm I'm still making typos :/


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: user-option windmove-create-window with function --]
[-- Type: text/x-diff, Size: 6142 bytes --]

From 8dce7c9c4aa0457f5f921cb6f7af8ca681da5467 Mon Sep 17 00:00:00 2001
From: Trust me I am a doctor <pillule@riseup.net>
Date: Tue, 8 Jun 2021 11:44:54 +0200
Subject: [PATCH] User option to choose a function triggered by windmove-create

* lisp/windmove.el (windmove-create-window): Add a defcustom choice.
(windmove-do-window-select): Trigger custom functions, update the
docstring.

Commentary: document the usage of this user option with a basic
'display-buffer-alist', a dispatcher function for
'windmove-create-window' and an alist to hold the dispatch.
---
 lisp/windmove.el | 90 ++++++++++++++++++++++++++++++++++++++++++++----
 1 file changed, 84 insertions(+), 6 deletions(-)

diff --git a/lisp/windmove.el b/lisp/windmove.el
index f558903681..0ef20fb498 100644
--- a/lisp/windmove.el
+++ b/lisp/windmove.el
@@ -110,6 +110,72 @@
 ;;    (setq windmove-wrap-around t)
 ;;
 
+;; Configuring windmove to display side windows :
+;;
+;; Assuming you have customized your 'display-buffer-alist' to
+;; uses side-windows, see (info "(elisp) Choosing Window")
+;;
+;; Or refer to this basic example :
+;;
+;; (customize-set-variable 'display-buffer-alist
+;; 			'(("\\*Ibuffer\\*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . left) (window-width . 42))
+;; 			  ("\\*Info.*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . right) (window-width . 80))
+;; 			  ("\\*e?shell.*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . top))
+;; 			  ("\\*Messages.*"
+;; 			   (display-buffer-in-side-window)
+;; 			   (side . bottom))))
+;;
+;; You can create a function that will dispatch the calls by direction :
+;;
+;; (defun windmove-create-side-window (dir arg window)
+;;   "Intermedary function choosing what to call on direction DIR.
+;; If the selected-window is a side-window, delete it, otherwise,
+;; select the relevant function from `windmove-dispatch-sides-functions'.
+;; Only pass ARG and WINDOW to the childs functions."
+;;   ;; normalise the direction
+;;   (let ((dir (pcase dir (`up 'top) (`down 'bottom) (_ dir))))
+;;     (funcall (if (eq dir (window-parameter window 'window-side))
+;;                  (lambda (_dir _arg window)
+;;                    (prog1 (get-mru-window) (delete-window window)))
+;;                (alist-get dir windmove-dispatch-sides-functions))
+;;              dir arg window)))
+;;
+;; Then assign it to 'windmove-create-window'
+;;
+;; (customize-set-variable 'windmove-create-window
+;;                         #'windmove-create-side-window)
+;;
+;; You can then specify an alist to actually hold the functions
+;; to be called with their directions :
+;;
+;; (defvar windmove-dispatch-sides-functions
+;;   '((left . (lambda (_dir _arg _window)
+;;               (ibuffer 'other-window)
+;;               (get-buffer-window "*Ibuffer*")))
+;;     (right . (lambda (_dir _arg _window)
+;;                (let ((buffer (get-buffer "*info*")))
+;;                  (if buffer
+;;                      (display-buffer buffer)
+;;                    (info))
+;;                  (get-buffer-window "*info*"))))
+;;     (top . (lambda (_dir _arg _window)
+;;              (shell)
+;;              (get-buffer-window "*shell*")))
+;;     (bottom . (lambda (_arg _dir _window)
+;;                 (view-echo-area-messages)
+;;                 'no-select)))
+;;   "Alist to dispatch by direction the calls of `windmove-create-side-window'")
+;;
+;; And also activate this recommended setting :
+;;
+;; (customize-set-variable 'windmove-allow-all-windows t)
+
 ;; Acknowledgments:
 ;;
 ;; Special thanks to Julian Assange (proff@iq.org), whose
@@ -145,10 +211,18 @@ windmove-create-window
   "Whether movement off the edge of the frame creates a new window.
 If this variable is set to t, moving left from the leftmost window in
 a frame will create a new window on the left, and similarly for the other
-directions."
-  :type 'boolean
-  :group 'windmove
-  :version "27.1")
+directions.
+This variable may also be a function to be called in this circumstance
+by `windmove-do-window-select'.  The function should accept then as
+argument the DIRECTION targeted, an interactive ARG and a WINDOW
+corresponding to the currently selected window.  It should also return
+or a valid window that `windmove-do-window-select' will select,
+or the symbol 'no-select to ignore that final selection.
+The commentary section of windmove.el show an example of this utilisation."
+  :type '(choice (const :tag "Don't create new windows" nil)
+          (const :tag "Create new windows" t)
+          (function :tag "Provide a function"))
+  :version "28.1")
 
 ;; If your Emacs sometimes places an empty column between two adjacent
 ;; windows, you may wish to set this delta to 2.
@@ -350,19 +424,23 @@ windmove-do-window-select
   "Move to the window at direction DIR as seen from WINDOW.
 DIR, ARG, and WINDOW are handled as by `windmove-find-other-window'.
 If no window is at direction DIR, an error is signaled.
-If `windmove-create-window' is non-nil, try to create a new window
+If `windmove-create-window' is a function, call that function with
+DIR, ARG and WINDOW, if it is non-nil, try to create a new window
 in direction DIR instead."
   (let ((other-window (windmove-find-other-window dir arg window)))
     (when (and windmove-create-window
                (or (null other-window)
                    (and (window-minibuffer-p other-window)
                         (not (minibuffer-window-active-p other-window)))))
-      (setq other-window (split-window window nil dir)))
+      (setq other-window (if (functionp windmove-create-window)
+                             (funcall windmove-create-window dir arg window)
+                           (split-window window nil dir))))
     (cond ((null other-window)
            (user-error "No window %s from selected window" dir))
           ((and (window-minibuffer-p other-window)
                 (not (minibuffer-window-active-p other-window)))
            (user-error "Minibuffer is inactive"))
+          ((eq other-window 'no-select))
           (t
            (select-window other-window)))))
 
-- 
2.20.1


[-- Attachment #3: Type: text/plain, Size: 6 bytes --]




--

^ permalink raw reply	[flat|nested] 8+ messages in thread

* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
  2021-06-15 22:04       ` pillule
  2021-06-15 22:20         ` pillule
@ 2021-06-15 23:32         ` Juri Linkov
  2021-06-16  1:26           ` pillule
  1 sibling, 1 reply; 8+ messages in thread
From: Juri Linkov @ 2021-06-15 23:32 UTC (permalink / raw)
  To: pillule; +Cc: 48917

tags 48917 fixed
close 48917 28.0.50
thanks

>> If you have not signed papers yet, I guess
>> these patches are small enough to push.
>>
>> But in both patches please change the :version tag to "28.1".
>
> I get the papers now \o/

Good news.  So now your patch is pushed.  Thanks for this useful feature.

> I was a little bit worried that this user-option is quite obscure to understand,
> so among other little docstring fixes, I documented an usage with
> 'display-buffer-alist' in the commentary section of the package.
>
> Please let me know if it is not desirable, in which case I will remove it.

It doesn't look like a suitable place to document its possible uses.
So pushed without commentary.

> Also I added the parent function ARG to be passed, it is an universal-argument.

This is a good change.





^ permalink raw reply	[flat|nested] 8+ messages in thread

* bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window
  2021-06-15 23:32         ` Juri Linkov
@ 2021-06-16  1:26           ` pillule
  0 siblings, 0 replies; 8+ messages in thread
From: pillule @ 2021-06-16  1:26 UTC (permalink / raw)
  To: Juri Linkov; +Cc: pillule, 48917


Juri Linkov <juri@linkov.net> writes:

> tags 48917 fixed
> close 48917 28.0.50
> thanks
>
>>> If you have not signed papers yet, I guess
>>> these patches are small enough to push.
>>>
>>> But in both patches please change the :version tag to "28.1".
>>
>> I get the papers now \o/
>
> Good news.  So now your patch is pushed.  Thanks for this useful feature.
>
>> I was a little bit worried that this user-option is quite obscure to understand,
>> so among other little docstring fixes, I documented an usage with
>> 'display-buffer-alist' in the commentary section of the package.
>>
>> Please let me know if it is not desirable, in which case I will remove it.
>
> It doesn't look like a suitable place to document its possible uses.
> So pushed without commentary.
>
>> Also I added the parent function ARG to be passed, it is an universal-argument.
>
> This is a good change.

thanks !
--





^ permalink raw reply	[flat|nested] 8+ messages in thread

end of thread, other threads:[~2021-06-16  1:26 UTC | newest]

Thread overview: 8+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2021-06-08 10:31 bug#48917: 28.0.50; allow user to choose what function is used when windmove create a window pillule
2021-06-08 11:49 ` Eli Zaretskii
2021-06-08 14:12   ` pillule
2021-06-12 22:09     ` Juri Linkov
2021-06-15 22:04       ` pillule
2021-06-15 22:20         ` pillule
2021-06-15 23:32         ` Juri Linkov
2021-06-16  1:26           ` pillule

unofficial mirror of bug-gnu-emacs@gnu.org 

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://yhetil.org/emacs-bugs/0 emacs-bugs/git/0.git

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V2 emacs-bugs emacs-bugs/ https://yhetil.org/emacs-bugs \
		bug-gnu-emacs@gnu.org
	public-inbox-index emacs-bugs

Example config snippet for mirrors.
Newsgroups are available over NNTP:
	nntp://news.yhetil.org/yhetil.emacs.bugs
	nntp://news.gmane.io/gmane.emacs.bugs


code repositories for project(s) associated with this inbox:

	https://git.savannah.gnu.org/cgit/emacs.git

AGPL code for this site: git clone http://ou63pmih66umazou.onion/public-inbox.git