bug#10907: 24.0.94; Updating display of Customize buffer

[Stephen Berman <stephen.berman@gmx.net>]

[-- Attachment #1: Type: text/plain, Size: 771 bytes --]

On Tue, 28 Feb 2012 21:06:59 -0500 Stefan Monnier <monnier@iro.umontreal.ca> wrote:

>> Ah, thanks.  I feared as much.  Is there really no way to reevaluate a
>> defcustom in a running Emacs?
>
> Agreed that there should be some way to have a defcustom type that is
> a bit more dynamic: no need to completely reevaluate the whole
> expression, but being able to have a dynamic set of `choice's would
> be helpful.

It turns out that, at least for my use case, completely reevaluating the
whole expression in fact DTRT -- see the attached file.  Admittedly,
elegant it isn't, and AFAIK this is virtually never done (I guess that's
why it didn't occur to me when I asked the above question) -- but other
than inelegance, is there a problem with doing this?

Steve Berman


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: test updating defcustom --]
[-- Type: text/x-emacs-lisp, Size: 2053 bytes --]

(defgroup srb nil
  "srb group.")

(defcustom srb-dir "~/srb/"
  "Directory of files whose names are members of `srb-file-list'."
  :type 'directory
  :group 'srb)

(defvar srb-file-list (if (file-exists-p srb-dir)
			  (directory-files srb-dir nil
					   "^[^.]+")) ; Don't include "." or ".."
  "List of names of files in `srb-dir'.")

(defcustom srb-selected-file (car srb-file-list)
  "A selected file name from `srb-file-list'."
  :type `(radio ,@(mapcar (lambda (x) (list 'const x)) srb-file-list))
  :group 'srb)

(defun srb-reevaluate-defcustom ()
  "Reevaluate defcustom `srb-selected-file'."
  (eval (defcustom srb-selected-file (car srb-file-list)
	  "A selected file name from `srb-file-list'."
	  :type `(radio ,@(mapcar (lambda (x) (list 'const x)) srb-file-list))
	  :group 'srb)))

(defun srb-add-file ()
  "Add a file to `srb-dir' and update variables."
  (interactive)
  (unless (file-exists-p srb-dir)
    (make-directory srb-dir))
  (let ((file (read-from-minibuffer "Enter a file name: ")))
    (with-current-buffer (get-buffer-create file)
      (erase-buffer)
      (write-region (point-min) (point-max)
		    (concat srb-dir file) nil 'nomessage nil t)
      (kill-buffer file)))
  (setq srb-file-list (directory-files srb-dir nil "^[^.]+"))
  (custom-set-default 'srb-selected-file (symbol-value 'srb-selected-file))
  (srb-reevaluate-defcustom))

(defun srb-delete-file ()
  "Delete a file from `srb-dir' and update variables."
  (interactive)
  (let ((files (directory-files srb-dir nil "^[^.]+")))
    (if (and (file-exists-p srb-dir) (> (length files) 0))
	(let ((file (completing-read "Enter a file name: " files nil t)))
	  (when (yes-or-no-p (format "Confirm you want to delete file %s " file))
	    (delete-file (concat srb-dir file))
	    (setq srb-file-list (directory-files srb-dir nil "^[^.]+"))
	    (custom-set-default 'srb-selected-file
				(symbol-value 'srb-selected-file))
	    (srb-reevaluate-defcustom)
	    (message "File %s deleted" file)))
      (error "There are no files to delete"))))

(provide 'srb)