From: Joseph Turner via "Bug reports for GNU Emacs, the Swiss army knife of text editors" <bug-gnu-emacs@gnu.org>
To: Philip Kaludercic <philipk@posteo.net>
Cc: 63336@debbugs.gnu.org
Subject: bug#63336: [PATCH] package-vc: Process :make and :shell-command spec args
Date: Sun, 14 May 2023 01:08:29 -0700 [thread overview]
Message-ID: <87cz33parh.fsf@breatheoutbreathe.in> (raw)
In-Reply-To: <87ilcvichb.fsf@posteo.net>
[-- Attachment #1: Type: text/plain, Size: 4703 bytes --]
Philip Kaludercic <philipk@posteo.net> writes:
> Joseph Turner <joseph@breatheoutbreathe.in> writes:
>
>> Philip Kaludercic <philipk@posteo.net> writes:
>>
>>> Joseph Turner <joseph@breatheoutbreathe.in> writes:
>> From b27724197acd4ee72f9d336843f0e6ed9fcee87b Mon Sep 17 00:00:00 2001
>> From: Joseph Turner <joseph@breatheoutbreathe.in>
>> Date: Sat, 13 May 2023 10:05:04 -0700
>> Subject: [PATCH] package-vc: Process :make and :shell-command spec args
>>
>> ---
>> lisp/emacs-lisp/package-vc.el | 37 +++++++++++++++++++++++++++++++++++
>> 1 file changed, 37 insertions(+)
>>
>> diff --git a/lisp/emacs-lisp/package-vc.el b/lisp/emacs-lisp/package-vc.el
>> index beca0bd00e2..8529d1dad5c 100644
>> --- a/lisp/emacs-lisp/package-vc.el
>> +++ b/lisp/emacs-lisp/package-vc.el
>> @@ -344,6 +344,33 @@ asynchronously."
>> "\n")
>> nil pkg-file nil 'silent))))
>>
>> +(defcustom package-vc-process-make nil
>
> Have we discussed the name of this user option? I feel it is too
> immediate, and therefore not intuitively obvious what purpose it serves.
> I would imagine something along the lines of
> "package-vc-allow-side-effects" or "package-vc-permit-building" could be
> better? WDYT?
I like "package-vc-allow-side-effects". Changed in attached patch.
>> + "Whether to process :make and :shell-command spec arguments.
>
> I guess here too an explanation would be warranted (and in the manual).
> Explaining what the issue is, and why one might be wary to enable the option.
Does my addition suffice?
We also might want to add another option for
package-vc-allow-side-effects like 'user-defined, which only runs :make
and :shell-command args which were specified by the user (as opposed to
those which were downloaded from elpa). WDYT?
To update the manual, shall I edit doc/emacs/package.texi directly or is
there another file to edit?
>> +When set to a list of symbols (packages), run commands for only
>> +packages in the list. When `nil', never run commands. Otherwise
>> +when non-`nil', run commands for any package with :make or
>> +:shell-command specified.
>> +
>> +Package specs are loaded from trusted package archives."
>> + :type '(choice (const :tag "Run for all packages" t)
>> + (repeat :tag "Run only for selected packages" (symbol :tag "Package name"))
>> + (const :tag "Never run" nil))
>> + :version "30.1")
>> +
>> +(defun package-vc--make (pkg-spec pkg-desc)
>> + "Process :make and :shell-command PKG-SPEC arguments for PKG-DESC."
>> + (let ((target (plist-get pkg-spec :make))
>> + (cmd (plist-get pkg-spec :shell-command)))
>> + (when (or cmd target)
>> + (with-current-buffer (get-buffer-create
>
> I'd format the buffer name in the top let to prevent this line-break here.
Done.
>> + (format " *package-vc make %s*" (package-desc-name pkg-desc)))
>> + (erase-buffer)
>> + (when (and cmd (/= 0 (call-process shell-file-name nil t nil shell-command-switch cmd)))
>> + (warn "Failed to run %s, see buffer %S" cmd (buffer-name)))
>> + (when (and target (/= 0 (apply #'call-process "make" nil t nil (if (consp target) target (list target)))))
>> + (warn "Failed to make %s, see buffer %S" target (buffer-name)))))))
>
> If :shell-command fails, do we really want to proceed to :make?
Up to you! I was following the lead of elpa-admin.el.
>> (declare-function org-export-to-file "ox" (backend file))
>>
>> (defun package-vc--build-documentation (pkg-desc file)
>> @@ -486,6 +513,16 @@ documentation and marking the package as installed."
>> ;; Generate package file
>> (package-vc--generate-description-file pkg-desc pkg-file)
>>
>> + ;; Process :make and :shell-command arguments before building documentation
>> + (pcase package-vc-process-make
>> + ((pred consp) ; When non-`nil' list, check if package is on the list.
>> + (when (memq (package-desc-name pkg-desc) package-vc-process-make)
>> + (package-vc--make pkg-spec pkg-desc)))
>> + ('nil ; When `nil', do nothing.
>> + nil)
>
> Perhaps swap the two conditions, first checking nil then listp which I
> think reads more natural. Then again, is pcase actually serving
> anything here?
I switched the first two cases. I think pcase is readable here,
especially if we add an 'user-defined option. What would you use
instead?
>> + (_ ; When otherwise non-`nil', run commands.
>> + (package-vc--make pkg-spec pkg-desc)))
>> +
>> ;; Detect a manual
>> (when (executable-find "install-info")
>> (dolist (doc-file (ensure-list (plist-get pkg-spec :doc)))
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-package-vc-Process-make-and-shell-command-spec-args.patch --]
[-- Type: text/x-diff, Size: 3065 bytes --]
From 3e7084e8e3e3ba142f383e90bfa656f59f3cc1ad Mon Sep 17 00:00:00 2001
From: Joseph Turner <joseph@breatheoutbreathe.in>
Date: Sat, 13 May 2023 10:05:04 -0700
Subject: [PATCH] package-vc: Process :make and :shell-command spec args
---
lisp/emacs-lisp/package-vc.el | 40 +++++++++++++++++++++++++++++++++++
1 file changed, 40 insertions(+)
diff --git a/lisp/emacs-lisp/package-vc.el b/lisp/emacs-lisp/package-vc.el
index beca0bd00e2..8403add364c 100644
--- a/lisp/emacs-lisp/package-vc.el
+++ b/lisp/emacs-lisp/package-vc.el
@@ -344,6 +344,36 @@ asynchronously."
"\n")
nil pkg-file nil 'silent))))
+(defcustom package-vc-allow-side-effects nil
+ "Whether to process :make and :shell-command spec arguments.
+
+Be careful when changing this option as processing :make and
+:shell-command will run potentially harmful code.
+
+When set to a list of symbols (packages), run commands for only
+packages in the list. When `nil', never run commands. Otherwise
+when non-`nil', run commands for any package with :make or
+:shell-command specified.
+
+Package specs are loaded from trusted package archives."
+ :type '(choice (const :tag "Run for all packages" t)
+ (repeat :tag "Run only for selected packages" (symbol :tag "Package name"))
+ (const :tag "Never run" nil))
+ :version "30.1")
+
+(defun package-vc--make (pkg-spec pkg-desc)
+ "Process :make and :shell-command PKG-SPEC arguments for PKG-DESC."
+ (let ((target (plist-get pkg-spec :make))
+ (cmd (plist-get pkg-spec :shell-command))
+ (buf (format " *package-vc make %s*" (package-desc-name pkg-desc))))
+ (when (or cmd target)
+ (with-current-buffer (get-buffer-create buf)
+ (erase-buffer)
+ (when (and cmd (/= 0 (call-process shell-file-name nil t nil shell-command-switch cmd)))
+ (warn "Failed to run %s, see buffer %S" cmd (buffer-name)))
+ (when (and target (/= 0 (apply #'call-process "make" nil t nil (if (consp target) target (list target)))))
+ (warn "Failed to make %s, see buffer %S" target (buffer-name)))))))
+
(declare-function org-export-to-file "ox" (backend file))
(defun package-vc--build-documentation (pkg-desc file)
@@ -486,6 +516,16 @@ documentation and marking the package as installed."
;; Generate package file
(package-vc--generate-description-file pkg-desc pkg-file)
+ ;; Process :make and :shell-command arguments before building documentation
+ (pcase package-vc-allow-side-effects
+ ('nil ; When `nil', do nothing.
+ nil)
+ ((pred consp) ; When non-`nil' list, check if package is on the list.
+ (when (memq (package-desc-name pkg-desc) package-vc-allow-side-effects)
+ (package-vc--make pkg-spec pkg-desc)))
+ (_ ; When otherwise non-`nil', run commands.
+ (package-vc--make pkg-spec pkg-desc)))
+
;; Detect a manual
(when (executable-find "install-info")
(dolist (doc-file (ensure-list (plist-get pkg-spec :doc)))
--
2.40.1
next prev parent reply other threads:[~2023-05-14 8:08 UTC|newest]
Thread overview: 18+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-05-06 20:39 bug#63336: [PATCH] package-vc: Process :make and :shell-command spec args Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-07 9:03 ` Philip Kaludercic
2023-05-07 18:47 ` Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-08 8:42 ` Ruijie Yu via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-08 19:38 ` Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-09 0:03 ` Richard Stallman
2023-05-10 6:35 ` Philip Kaludercic
2023-05-11 1:37 ` Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-14 7:44 ` Philip Kaludercic
2023-05-14 8:08 ` Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors [this message]
2023-05-14 19:30 ` Philip Kaludercic
2023-05-14 23:01 ` Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-15 9:12 ` Philip Kaludercic
2023-05-15 19:03 ` Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-16 19:29 ` Philip Kaludercic
2023-05-16 21:08 ` Joseph Turner via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-05-17 14:07 ` Philip Kaludercic
2023-05-13 17:18 ` Philip Kaludercic
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://www.gnu.org/software/emacs/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=87cz33parh.fsf@breatheoutbreathe.in \
--to=bug-gnu-emacs@gnu.org \
--cc=63336@debbugs.gnu.org \
--cc=joseph@breatheoutbreathe.in \
--cc=philipk@posteo.net \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).