* bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter
@ 2013-02-03 19:01 Jambunathan K
2013-02-05 8:04 ` Glenn Morris
2013-02-09 5:29 ` Chong Yidong
0 siblings, 2 replies; 6+ messages in thread
From: Jambunathan K @ 2013-02-03 19:01 UTC (permalink / raw)
To: 13622
[-- Attachment #1: Type: text/plain, Size: 50 bytes --]
I am attaching a patch. Please apply to trunk.
[-- Attachment #2: doc-view.diff --]
[-- Type: text/plain, Size: 3626 bytes --]
=== modified file 'lisp/doc-view.el'
--- lisp/doc-view.el 2013-01-24 03:34:20 +0000
+++ lisp/doc-view.el 2013-02-03 18:47:45 +0000
@@ -231,14 +231,36 @@ If this and `doc-view-dvipdfm-program' a
:type 'file
:group 'doc-view)
-(defcustom doc-view-unoconv-program "unoconv"
+(define-obsolete-variable-alias 'doc-view-unoconv-program
+ 'doc-view-odf->pdf-converter-program
+ "24.4")
+
+(defcustom doc-view-odf->pdf-converter-program
+ (cond
+ ((executable-find "soffice") "soffice")
+ ((executable-find "unoconv") "unoconv"))
"Program to convert any file type readable by OpenOffice.org to PDF.
Needed for viewing OpenOffice.org (and MS Office) files."
- :version "24.1"
+ :version "24.4"
:type 'file
:group 'doc-view)
+(defcustom doc-view-odf->pdf-converter-function
+ (cond
+ ((string-match "unoconv\\'" doc-view-odf->pdf-converter-program)
+ #'doc-view-odf->pdf-converter-unoconv)
+ ((string-match "soffice\\'" doc-view-odf->pdf-converter-program)
+ #'doc-view-odf->pdf-converter-soffice))
+ "Function to call to convert a ODF file into a PDF file."
+ :type '(radio
+ (function-item doc-view-odf->pdf-converter-unoconv
+ :doc "Use unoconv")
+ (function-item doc-view-odf->pdf-converter-soffice
+ :doc "Use LibreOffice")
+ function)
+ :version "24.4")
+
(defcustom doc-view-ps2pdf-program "ps2pdf"
"Program to convert PS files to PDF.
@@ -700,8 +722,8 @@ OpenDocument format)."
(and doc-view-ghostscript-program
(executable-find doc-view-ghostscript-program)))
((eq type 'odf)
- (and doc-view-unoconv-program
- (executable-find doc-view-unoconv-program)
+ (and doc-view-odf->pdf-converter-program
+ (executable-find doc-view-odf->pdf-converter-program)
(doc-view-mode-p 'pdf)))
((eq type 'djvu)
(executable-find "ddjvu"))
@@ -903,14 +925,23 @@ If PAGE is nil, convert the whole docume
,@(if page `(,(format "%d" page))))
callback))
-(defun doc-view-odf->pdf (odf callback)
+(defun doc-view-odf->pdf-converter-unoconv (odf callback)
"Convert ODF to PDF asynchronously and call CALLBACK when finished.
The converted PDF is put into the current cache directory, and it
is named like ODF with the extension turned to pdf."
- (doc-view-start-process "odf->pdf" doc-view-unoconv-program
+ (doc-view-start-process "odf->pdf" doc-view-odf->pdf-converter-program
(list "-f" "pdf" "-o" (doc-view-current-cache-dir) odf)
callback))
+(defun doc-view-odf->pdf-converter-soffice (odf callback)
+ "Convert ODF to PDF asynchronously and call CALLBACK when finished.
+The converted PDF is put into the current cache directory, and it
+is named like ODF with the extension turned to pdf."
+ (doc-view-start-process "odf->pdf" doc-view-odf->pdf-converter-program
+ (list "--headless" "--convert-to" "pdf"
+ "--outdir" (doc-view-current-cache-dir) odf)
+ callback))
+
(defun doc-view-pdf/ps->png (pdf-ps png)
;; FIXME: Fix name and docstring to account for djvu&tiff.
"Convert PDF-PS to PNG asynchronously."
@@ -1058,7 +1089,7 @@ Those files are saved in the directory g
;; The unoconv tool only supports an output directory, but no
;; file name. It's named like the input file with the
;; extension replaced by pdf.
- (doc-view-odf->pdf doc-view-buffer-file-name
+ (funcall doc-view-odf->pdf-converter-function doc-view-buffer-file-name
(lambda ()
;; Rename to doc.pdf
(rename-file opdf pdf)
[-- Attachment #3: Type: text/plain, Size: 299 bytes --]
In GNU Emacs 24.3.50.8 (i686-pc-linux-gnu, X toolkit, Xaw3d scroll bars)
of 2013-02-02 on debian-6.05
Bzr revision: 111663 eliz@gnu.org-20130202171424-zeijhu9wq1tstzt0
Windowing system distributor `The X.Org Foundation', version 11.0.10707000
System Description: Debian GNU/Linux 6.0.5 (squeeze)
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter
2013-02-03 19:01 bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter Jambunathan K
@ 2013-02-05 8:04 ` Glenn Morris
2013-02-05 10:53 ` Jambunathan K
2013-02-05 11:50 ` Jambunathan K
2013-02-09 5:29 ` Chong Yidong
1 sibling, 2 replies; 6+ messages in thread
From: Glenn Morris @ 2013-02-05 8:04 UTC (permalink / raw)
To: Jambunathan K; +Cc: 13622
Jambunathan K wrote:
> I am attaching a patch. Please apply to trunk.
Some explanation as to why would be nice.
> +(defcustom doc-view-odf->pdf-converter-program
> + (cond
> + ((executable-find "soffice") "soffice")
> + ((executable-find "unoconv") "unoconv"))
This could end up being nil, which would give a type mismatch with 'file.
> :type 'file
>
> +(defcustom doc-view-odf->pdf-converter-function
> + (cond
> + ((string-match "unoconv\\'" doc-view-odf->pdf-converter-program)
> + #'doc-view-odf->pdf-converter-unoconv)
> + ((string-match "soffice\\'" doc-view-odf->pdf-converter-program)
> + #'doc-view-odf->pdf-converter-soffice))
> + "Function to call to convert a ODF file into a PDF file."
> + :type '(radio
> + (function-item doc-view-odf->pdf-converter-unoconv
> + :doc "Use unoconv")
> + (function-item doc-view-odf->pdf-converter-soffice
> + :doc "Use LibreOffice")
> + function)
> + :version "24.4")
Why do you need this, as opposed to a single function which calls
-program with a customizable -program-options argument?
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter
2013-02-05 8:04 ` Glenn Morris
@ 2013-02-05 10:53 ` Jambunathan K
2013-02-05 11:50 ` Jambunathan K
1 sibling, 0 replies; 6+ messages in thread
From: Jambunathan K @ 2013-02-05 10:53 UTC (permalink / raw)
To: Glenn Morris; +Cc: 13622
Glenn Morris <rgm@gnu.org> writes:
> Jambunathan K wrote:
>
>> I am attaching a patch. Please apply to trunk.
>
> Some explanation as to why would be nice.
One is likely to have LibreOffice installed rather than unoconv.
Getting unoconv on non-Linux platforms could be cumbersome.
>
>> +(defcustom doc-view-odf->pdf-converter-program
>> + (cond
>> + ((executable-find "soffice") "soffice")
>> + ((executable-find "unoconv") "unoconv"))
>
> This could end up being nil, which would give a type mismatch with 'file.
>
>> :type 'file
What would you suggest? Use `choice'?
>>
>> +(defcustom doc-view-odf->pdf-converter-function
>> + (cond
>> + ((string-match "unoconv\\'" doc-view-odf->pdf-converter-program)
>> + #'doc-view-odf->pdf-converter-unoconv)
>> + ((string-match "soffice\\'" doc-view-odf->pdf-converter-program)
>> + #'doc-view-odf->pdf-converter-soffice))
>> + "Function to call to convert a ODF file into a PDF file."
>> + :type '(radio
>> + (function-item doc-view-odf->pdf-converter-unoconv
>> + :doc "Use unoconv")
>> + (function-item doc-view-odf->pdf-converter-soffice
>> + :doc "Use LibreOffice")
>> + function)
>> + :version "24.4")
>
> Why do you need this, as opposed to a single function which calls
> -program with a customizable -program-options argument?
I am mimicing what is done for recent mupdf changes.
,----
| (defcustom doc-view-pdf->png-converter-function
| (if (executable-find doc-view-pdfdraw-program)
| #'doc-view-pdf->png-converter-mupdf
| #'doc-view-pdf->png-converter-ghostscript)
| "Function to call to convert a PDF file into a PNG file."
| :type '(radio
| (function-item doc-view-pdf->png-converter-ghostscript
| :doc "Use ghostscript")
| (function-item doc-view-pdf->png-converter-mupdf
| :doc "Use mupdf")
| function)
| :version "24.4")
`----
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter
2013-02-05 8:04 ` Glenn Morris
2013-02-05 10:53 ` Jambunathan K
@ 2013-02-05 11:50 ` Jambunathan K
1 sibling, 0 replies; 6+ messages in thread
From: Jambunathan K @ 2013-02-05 11:50 UTC (permalink / raw)
To: Glenn Morris; +Cc: 13622
Glenn
I am interested in patch sailing through in whatever form that suits
maintainers. Crux of the patch is in how soffice needs to be used.
Rest all are fillers, that a reviewer can easily workaround.
Feel free to modify the patch in a way that is acceptable to you.
Jambunathan K.
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter
2013-02-03 19:01 bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter Jambunathan K
2013-02-05 8:04 ` Glenn Morris
@ 2013-02-09 5:29 ` Chong Yidong
2013-02-09 10:03 ` Tassilo Horn
1 sibling, 1 reply; 6+ messages in thread
From: Chong Yidong @ 2013-02-09 5:29 UTC (permalink / raw)
To: Tassilo Horn; +Cc: 13622, Jambunathan K
Hi Tassilo,
Could you please review the changes suggested by Jambunathan K (and go
ahead and apply them if you agree)? Thanks.
http://debbugs.gnu.org/cgi/bugreport.cgi?bug=13622
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter
2013-02-09 5:29 ` Chong Yidong
@ 2013-02-09 10:03 ` Tassilo Horn
0 siblings, 0 replies; 6+ messages in thread
From: Tassilo Horn @ 2013-02-09 10:03 UTC (permalink / raw)
To: Chong Yidong; +Cc: Jambunathan K, 13622-done
Chong Yidong <cyd@gnu.org> writes:
Hi Chong,
> Could you please review the changes suggested by Jambunathan K (and go
> ahead and apply them if you agree)? Thanks.
>
> http://debbugs.gnu.org/cgi/bugreport.cgi?bug=13622
Thanks for notifying.
Oh, I didn't know soffice up to now. That's a great change as it
removes the (optional) dependency to unoconv which probably nobody has
installed anyway.
I've committed the patch with some minor modification. Thanks,
Jambunathan!
Bye,
Tassilo
^ permalink raw reply [flat|nested] 6+ messages in thread
end of thread, other threads:[~2013-02-09 10:03 UTC | newest]
Thread overview: 6+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-02-03 19:01 bug#13622: 24.3.50; doc-view: Use (and prefer) soffice as default ODF->PDF converter Jambunathan K
2013-02-05 8:04 ` Glenn Morris
2013-02-05 10:53 ` Jambunathan K
2013-02-05 11:50 ` Jambunathan K
2013-02-09 5:29 ` Chong Yidong
2013-02-09 10:03 ` Tassilo Horn
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).