bug#36494: 27.0.50; [Proposition] New option to scroll up regardless of eob

[Marco Wahl <marcowahlsoft@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 54 bytes --]

Ok, sorry for the patch missing.  Here is the patch.


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-New-function-for-scroll-lock-mode-to-always-scroll.patch --]
[-- Type: text/x-patch, Size: 4603 bytes --]

From baf7c0cd4c095d283a9d418dda4e6d1e5f565d24 Mon Sep 17 00:00:00 2001
From: Marco Wahl <marcowahlsoft@gmail.com>
Date: Thu, 4 Jul 2019 22:32:44 +0200
Subject: [PATCH] New function for scroll-lock-mode to always scroll

* lisp/scroll-lock.el (scroll-lock-next-line-always-scroll): New
  function.  Opposed to scroll-lock-next-line it does not switch to
  forward-line at eob.  S-down is the default key binding for this
  function.
* test/lisp/scroll-lock-tests.el: A few tests for
  scroll-lock-next-line-always-scroll.
---
 lisp/scroll-lock.el            | 11 +++++
 test/lisp/scroll-lock-tests.el | 73 ++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 test/lisp/scroll-lock-tests.el

diff --git a/lisp/scroll-lock.el b/lisp/scroll-lock.el
index 8281edb172..5b7a69a17c 100644
--- a/lisp/scroll-lock.el
+++ b/lisp/scroll-lock.el
@@ -36,6 +36,7 @@ scroll-lock-mode-map
     (define-key map [remap previous-line] 'scroll-lock-previous-line)
     (define-key map [remap forward-paragraph] 'scroll-lock-forward-paragraph)
     (define-key map [remap backward-paragraph] 'scroll-lock-backward-paragraph)
+    (define-key map [S-down] 'scroll-lock-next-line-always-scroll)
     map)
   "Keymap for Scroll Lock mode.")
 
@@ -81,6 +82,16 @@ scroll-lock-move-to-column
       (move-to-column column)
     (forward-char (min column (- (line-end-position) (point))))))
 
+(defun scroll-lock-next-line-always-scroll (&optional arg)
+  "Scroll up ARG lines keeping point fixed."
+  (interactive "p")
+  (or arg (setq arg 1))
+  (scroll-lock-update-goal-column)
+  (condition-case nil
+      (scroll-up arg)
+    (end-of-buffer (scroll-up (1- (count-screen-lines (point) (point-max))))))
+  (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
+
 (defun scroll-lock-next-line (&optional arg)
   "Scroll up ARG lines keeping point fixed."
   (interactive "p")
diff --git a/test/lisp/scroll-lock-tests.el b/test/lisp/scroll-lock-tests.el
new file mode 100644
index 0000000000..590ab4518c
--- /dev/null
+++ b/test/lisp/scroll-lock-tests.el
@@ -0,0 +1,73 @@
+;;; scroll-lock-tests.el --- Test suite for scroll-lock -*- lexical-binding: t -*-
+
+;; Copyright (C) 2019 Free Software Foundation, Inc.
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software: you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Code:
+
+(require 'ert)
+(require 'scroll-lock)
+
+\f
+(defun point-in-window-line-p (n)
+  "Return if point is in window line N.  Counting starts with 0.
+Precondition: the line N must be available."
+  (save-excursion
+    (let ((point (progn (beginning-of-line) (point))))
+      (let ((moved-to-line (move-to-window-line n)))
+        (cl-assert (= n moved-to-line) t "precondition violation"))
+      (= point (progn (beginning-of-line) (point))))))
+
+\f
+(ert-deftest scroll-lock-next-line-always-scroll-1 ()
+  (with-temp-buffer
+    (insert "\n\n\n")
+    (goto-char (point-min))
+    (switch-to-buffer (current-buffer))
+    (scroll-lock-next-line-always-scroll)
+    (should (point-in-window-line-p 0))))
+
+(ert-deftest scroll-lock-next-line-always-scroll-2 ()
+  (with-temp-buffer
+    (scroll-lock-mode)
+    (insert "\n\n\n")
+    (goto-char (1+ (point-min)))
+    (switch-to-buffer (current-buffer))
+    (scroll-lock-next-line-always-scroll)
+    (should (point-in-window-line-p 1))))
+
+(ert-deftest scroll-lock-next-line-always-scroll-3 ()
+  (with-temp-buffer
+    (scroll-lock-mode)
+    (insert "\n\n\n")
+    (goto-char (1+ (point-min)))
+    (switch-to-buffer (current-buffer))
+    (scroll-lock-next-line-always-scroll 1234)
+    (should (point-in-window-line-p 1))))
+
+(ert-deftest scroll-lock-next-line-always-scroll-4 ()
+  (with-temp-buffer
+    (scroll-lock-mode)
+    (insert (make-string 1000 ?\n))
+    (goto-char (1+ (point-min)))
+    (switch-to-buffer (current-buffer))
+    (scroll-lock-next-line-always-scroll 1234)
+    (should (point-in-window-line-p 1))))
+
+(provide 'scroll-lock-tests)
+
+;;; scroll-lock-tests.el ends here
-- 
2.22.0