bug#17401: 24.4.50; Narrow to {region,page,defun} in an indirect clone buffer in the other window

[Drew Adams <drew.adams@oracle.com>]

[-- Attachment #1: Type: text/plain, Size: 2220 bytes --]

> I was initially against the idea of naming the indirect buffer
> according to the narrowed region, for the simple reason that the
> name stops making sense as soon as you widen the buffer.
> 
> However, I expect that people are far less likely to widen these
> buffers (as opposed to simply killing them); and this naming
> approach would certainly be useful in the buffer list, so I think
> it's a good idea after all.
> 
> I've also noticed there are some org-mode specific narrowing
> commands as well, which should probably be supported. I did
> consider whether we could support all existing narrowing commands
> automagically with some trickery, but I concluded that the only
> approach I could think of was too convoluted and brittle for its
> own good, so I think simply adding a new function alongside each
> existing one is still the most practical way to go.
> 
> Do we want both a `narrow-to-*-indirect' and an `...-other-window'
> variant for each case? I think the latter works very nicely with
> the C-x 4 n prefix (as per the initial patch), but I can see the
> utility in providing both functions.

I agree about killing vs widening indirect buffers.  And I
don't find a need for same-window versions of the commands,
for my own use.

FWIW, attached is what I've been using lately.

The default buffer naming is similar to what Lennart suggested,
but (for the non-defun command) the region text (with whitespace
collapsed) is used, not the first line.  And the buffer-name
length is limited.  And the text following the original name is
separated by ` | ' instead of being enclosed in <...>.

Two options control naming: one limits the length, the other
is a name prefix (e.g., to easily distinguish indirect buffers).

A prefix arg prompts you for the new buffer name.

For defun narrowing, a negative prefix arg prompts you for the
text that follows ` | ' (in place of the defun object name).

To me, being able to provide names different from the default
is important.

--

(FWIW, I also use library `wide-n.el', which lets you widen
to any number of narrowings of the same buffer - e.g., cycle.
http://www.emacswiki.org/emacs-de/MultipleNarrowings)

[-- Attachment #2: narrow-other.el --]
[-- Type: application/octet-stream, Size: 3744 bytes --]

(defcustom narrowed-buf-name-max 60
  "Max length of cloned indirect buffer name, for narrowing commands."
  :type '(restricted-sexp :tag "Max length of buffer name"
          :match-alternatives ((lambda (x) (and (integerp x)  (> x 0))))
          :value ignore)
  :group 'editing)

(defcustom narrowed-buf-name-prefix ""
  "Name prefix for indirect buffer cloned by `narrow-*-indirect*' commands.
Using a non-empty prefix lets you easily distinguish the indirect
buffers from the original."
  :type 'string :group 'editing)

(defun narrow-to-defun-indirect-other-window (&optional full-name text)
  "`narrow-to-defun' in a cloned indirect buffer in the other window.
The name of the indirect buffer depends on the use of a prefix arg:

* No prefix arg: the current buffer name, but with ` | NAME'
  appended, where NAME is the name of the object defined by the defun.

* Prefix arg < 0 : like no prefix arg, but you are prompted for NAME.

* Prefix arg >= 0: you are prompted for the full buffer name.

However, the buffer name is in any case truncated at
`narrowed-buf-name-max' chars.

Non-interactively:
* FULL-NAME is the full buffer name, and TEXT is ignored.
* TEXT is used for NAME, if FULL-NAME is nil.

See `clone-indirect-buffer'."
  (interactive
   (list (and current-prefix-arg
              (natnump (prefix-numeric-value current-prefix-arg))
              (read-string "Buffer name: "))
         (and current-prefix-arg
              (< (prefix-numeric-value current-prefix-arg) 0)
              (read-string "Buffer name suffix: "))))
  (require 'which-func)
  (let ((here  (point)))
    (mark-defun)
    (narrow-to-region-indirect-other-window
     (region-beginning) (region-end) here full-name
     (and (not full-name)  (or text  (which-function))))))
     
(defun narrow-to-region-indirect-other-window (start end here
                                               &optional full-name text msgp)
  "`narrow-to-region' in a cloned indirect buffer in the other window.
The indirect buffer is named the same as the current buffer, except:

 * It is prefixed by the value of option `narrowed-buf-name-prefix'.
 * It is suffixed by ` | TEXT', where TEXT is the region text.

However, the buffer name is in any case truncated at
`narrowed-buf-name-max' chars.

Non-interactively:
START and END are the region beginning and end.
HERE is where to place the cursor, relative to START.
TEXT is prefixed by ` | ' and appended to the original
 buffer name, which is appended to `narrowed-buf-name-prefix' to name
 the new buffer.
If FULL-NAME is a string then it is used as the complete indirect
buffer name.  (TEXT is then ignored.)

See `clone-indirect-buffer'."
  (interactive
   (list (region-beginning) (region-end) (point)
         (and current-prefix-arg  (read-string "Buffer name: "))
         nil 'MSGP))
  (if (and (= start end)  msgp)
      (message "Region is empty")
    (deactivate-mark)
    (let* ((buf  (or full-name
                     text
                     (replace-regexp-in-string
                      "\\(\s \\)+" "\1"
                      (replace-regexp-in-string
                       "\\`\s+\\|\s+\\'" ""
                       (buffer-substring-no-properties start end)))))
           (buf  (or full-name
                     (concat narrowed-buf-name-prefix (buffer-name) " | " buf)))
           (buf  (or full-name
                     (substring buf 0 (min (length buf) narrowed-buf-name-max))))
           (buf  (clone-indirect-buffer buf nil)))
      (with-current-buffer buf (narrow-to-region start end) (goto-char here))
      (pop-to-buffer buf))))

(define-key ctl-x-4-map "nn" 'narrow-to-region-indirect-other-window)
(define-key ctl-x-4-map "nd" 'narrow-to-defun-indirect-other-window)