bug#25951: [PATCH] Fix quoted files for 'verify-visited-file-modtime'

bug#25951: [PATCH] Fix quoted files for 'verify-visited-file-modtime'

[Philipp Stephani]

Fixes Bug#25951.

* lisp/files.el (file-name-non-special): Set the file name for the
correct buffer.

* test/lisp/files-tests.el (files-tests--file-name-non-special--buffers):
Add unit test.
(files-tests--with-advice, files-tests--with-temp-file): New helper
macros.
---
 lisp/files.el            |  9 ++++++-
 test/lisp/files-tests.el | 64 +++++++++++++++++++++++++++++++++++++++++++++++-
 2 files changed, 71 insertions(+), 2 deletions(-)

diff --git a/lisp/files.el b/lisp/files.el
index 6848818cad..2e9ab1aad1 100644
--- a/lisp/files.el
+++ b/lisp/files.el
@@ -28,6 +28,8 @@
 
 ;;; Code:
 
+(eval-when-compile (require 'cl-lib))
+
 (defvar font-lock-keywords)
 
 (defgroup backup nil
@@ -6987,7 +6989,12 @@ file-name-non-special
            (when (and visit buffer-file-name)
              (setq buffer-file-name (concat "/:" buffer-file-name))))))
       (`unquote-then-quote
-       (let ((buffer-file-name (substring buffer-file-name 2)))
+       (cl-letf* ((buffer (or (car arguments) (current-buffer)))
+                  ((buffer-local-value 'buffer-file-name buffer)
+                   (substring (buffer-file-name buffer) 2)))
+         ;; `unquote-then-quote' is only used for the
+         ;; `verify-visited-file-modtime' action, which takes a buffer
+         ;; as only optional argument.
          (apply operation arguments)))
       (_
        (apply operation arguments)))))
diff --git a/test/lisp/files-tests.el b/test/lisp/files-tests.el
index 80bbeb1bc5..4583b1af3c 100644
--- a/test/lisp/files-tests.el
+++ b/test/lisp/files-tests.el
@@ -1,4 +1,4 @@
-;;; files-tests.el --- tests for files.el.
+;;; files-tests.el --- tests for files.el.  -*- lexical-binding: t; -*-
 
 ;; Copyright (C) 2012-2017 Free Software Foundation, Inc.
 
@@ -20,6 +20,7 @@
 ;;; Code:
 
 (require 'ert)
+(require 'nadvice)
 
 ;; Set to t if the local variable was set, `query' if the query was
 ;; triggered.
@@ -251,5 +252,66 @@ files-test-bug-18141-file
                       (start-file-process "foo" nil "true"))))
   (should (eq (let ((default-directory "/:/")) (shell-command "true")) 0)))
 
+(defmacro files-tests--with-advice (symbol where function &rest body)
+  (declare (indent 3))
+  (cl-check-type symbol symbol)
+  (cl-check-type where keyword)
+  (cl-check-type function function)
+  (macroexp-let2 nil function function
+    `(progn
+       (advice-add #',symbol ,where ,function)
+       (unwind-protect
+           (progn ,@body)
+         (advice-remove #',symbol ,function)))))
+
+(defmacro files-tests--with-temp-file (name &rest body)
+  (declare (indent 1))
+  (cl-check-type name symbol)
+  `(let ((,name (make-temp-file "emacs")))
+     (unwind-protect
+         (progn ,@body)
+       (delete-file ,name))))
+
+(ert-deftest files-tests--file-name-non-special--buffers ()
+  "Check that Bug#25951 is fixed.
+We call `verify-visited-file-modtime' on a buffer visiting a file
+with a quoted name.  We use two different variants: first with
+the buffer current and a nil argument, second passing the buffer
+object explicitly.  In both cases no error should be raised and
+the `file-name-non-special' handler for quoted file names should
+be invoked with the right arguments."
+  (files-tests--with-temp-file temp-file-name
+    (with-temp-buffer
+     (let* ((buffer-visiting-file (current-buffer))
+            (actual-args ())
+            (log (lambda (&rest args) (push args actual-args))))
+       (insert-file-contents (concat "/:" temp-file-name) :visit)
+       (should (stringp buffer-file-name))
+       (should (string-prefix-p "/:" buffer-file-name))
+       (should (consp (visited-file-modtime)))
+       (should (equal (find-file-name-handler buffer-file-name
+                                              #'verify-visited-file-modtime)
+                      #'file-name-non-special))
+       (files-tests--with-advice file-name-non-special :before log
+         ;; This should call the file name handler with the right
+         ;; buffer and not signal an error.  The file hasn't been
+         ;; modified, so `verify-visited-file-modtime' should return
+         ;; t.
+         (should (equal (verify-visited-file-modtime) t))
+         (with-temp-buffer
+           (should (stringp (buffer-file-name buffer-visiting-file)))
+           ;; This should call the file name handler with the right
+           ;; buffer and not signal an error.  The file hasn't been
+           ;; modified, so `verify-visited-file-modtime' should return
+           ;; t.
+           (should (equal (verify-visited-file-modtime buffer-visiting-file)
+                          t))))
+       ;; Verify that the handler was actually called.  We called
+       ;; `verify-visited-file-modtime' twice, so both calls should be
+       ;; recorded in reverse order.
+       (should (equal actual-args
+                      `((verify-visited-file-modtime ,buffer-visiting-file)
+                        (verify-visited-file-modtime nil))))))))
+
 (provide 'files-tests)
 ;;; files-tests.el ends here
-- 
2.12.2

bug#25951: [PATCH] Fix quoted files for 'verify-visited-file-modtime'

[Philipp]

[-- Attachment #1: Type: text/plain, Size: 5380 bytes --]

Philipp Stephani <p.stephani2@gmail.com> schrieb am Sa., 29. Apr. 2017 um
14:20 Uhr:

> Fixes Bug#25951.
>
> * lisp/files.el (file-name-non-special): Set the file name for the
> correct buffer.
>
> * test/lisp/files-tests.el (files-tests--file-name-non-special--buffers):
> Add unit test.
> (files-tests--with-advice, files-tests--with-temp-file): New helper
> macros.
> ---
>  lisp/files.el            |  9 ++++++-
>  test/lisp/files-tests.el | 64
> +++++++++++++++++++++++++++++++++++++++++++++++-
>  2 files changed, 71 insertions(+), 2 deletions(-)
>
> diff --git a/lisp/files.el b/lisp/files.el
> index 6848818cad..2e9ab1aad1 100644
> --- a/lisp/files.el
> +++ b/lisp/files.el
> @@ -28,6 +28,8 @@
>
>  ;;; Code:
>
> +(eval-when-compile (require 'cl-lib))
> +
>  (defvar font-lock-keywords)
>
>  (defgroup backup nil
> @@ -6987,7 +6989,12 @@ file-name-non-special
>             (when (and visit buffer-file-name)
>               (setq buffer-file-name (concat "/:" buffer-file-name))))))
>        (`unquote-then-quote
> -       (let ((buffer-file-name (substring buffer-file-name 2)))
> +       (cl-letf* ((buffer (or (car arguments) (current-buffer)))
> +                  ((buffer-local-value 'buffer-file-name buffer)
> +                   (substring (buffer-file-name buffer) 2)))
> +         ;; `unquote-then-quote' is only used for the
> +         ;; `verify-visited-file-modtime' action, which takes a buffer
> +         ;; as only optional argument.
>           (apply operation arguments)))
>        (_
>         (apply operation arguments)))))
> diff --git a/test/lisp/files-tests.el b/test/lisp/files-tests.el
> index 80bbeb1bc5..4583b1af3c 100644
> --- a/test/lisp/files-tests.el
> +++ b/test/lisp/files-tests.el
> @@ -1,4 +1,4 @@
> -;;; files-tests.el --- tests for files.el.
> +;;; files-tests.el --- tests for files.el.  -*- lexical-binding: t; -*-
>
>  ;; Copyright (C) 2012-2017 Free Software Foundation, Inc.
>
> @@ -20,6 +20,7 @@
>  ;;; Code:
>
>  (require 'ert)
> +(require 'nadvice)
>
>  ;; Set to t if the local variable was set, `query' if the query was
>  ;; triggered.
> @@ -251,5 +252,66 @@ files-test-bug-18141-file
>                        (start-file-process "foo" nil "true"))))
>    (should (eq (let ((default-directory "/:/")) (shell-command "true"))
> 0)))
>
> +(defmacro files-tests--with-advice (symbol where function &rest body)
> +  (declare (indent 3))
> +  (cl-check-type symbol symbol)
> +  (cl-check-type where keyword)
> +  (cl-check-type function function)
> +  (macroexp-let2 nil function function
> +    `(progn
> +       (advice-add #',symbol ,where ,function)
> +       (unwind-protect
> +           (progn ,@body)
> +         (advice-remove #',symbol ,function)))))
> +
> +(defmacro files-tests--with-temp-file (name &rest body)
> +  (declare (indent 1))
> +  (cl-check-type name symbol)
> +  `(let ((,name (make-temp-file "emacs")))
> +     (unwind-protect
> +         (progn ,@body)
> +       (delete-file ,name))))
> +
> +(ert-deftest files-tests--file-name-non-special--buffers ()
> +  "Check that Bug#25951 is fixed.
> +We call `verify-visited-file-modtime' on a buffer visiting a file
> +with a quoted name.  We use two different variants: first with
> +the buffer current and a nil argument, second passing the buffer
> +object explicitly.  In both cases no error should be raised and
> +the `file-name-non-special' handler for quoted file names should
> +be invoked with the right arguments."
> +  (files-tests--with-temp-file temp-file-name
> +    (with-temp-buffer
> +     (let* ((buffer-visiting-file (current-buffer))
> +            (actual-args ())
> +            (log (lambda (&rest args) (push args actual-args))))
> +       (insert-file-contents (concat "/:" temp-file-name) :visit)
> +       (should (stringp buffer-file-name))
> +       (should (string-prefix-p "/:" buffer-file-name))
> +       (should (consp (visited-file-modtime)))
> +       (should (equal (find-file-name-handler buffer-file-name
> +
> #'verify-visited-file-modtime)
> +                      #'file-name-non-special))
> +       (files-tests--with-advice file-name-non-special :before log
> +         ;; This should call the file name handler with the right
> +         ;; buffer and not signal an error.  The file hasn't been
> +         ;; modified, so `verify-visited-file-modtime' should return
> +         ;; t.
> +         (should (equal (verify-visited-file-modtime) t))
> +         (with-temp-buffer
> +           (should (stringp (buffer-file-name buffer-visiting-file)))
> +           ;; This should call the file name handler with the right
> +           ;; buffer and not signal an error.  The file hasn't been
> +           ;; modified, so `verify-visited-file-modtime' should return
> +           ;; t.
> +           (should (equal (verify-visited-file-modtime
> buffer-visiting-file)
> +                          t))))
> +       ;; Verify that the handler was actually called.  We called
> +       ;; `verify-visited-file-modtime' twice, so both calls should be
> +       ;; recorded in reverse order.
> +       (should (equal actual-args
> +                      `((verify-visited-file-modtime
> ,buffer-visiting-file)
> +                        (verify-visited-file-modtime nil))))))))
> +
>  (provide 'files-tests)
>  ;;; files-tests.el ends here
> --
> 2.12.2
>
>
No further comments, so I've pushed this as 5e47c2e52b.

[-- Attachment #2: Type: text/html, Size: 6629 bytes --]

bug#25951: [PATCH] Fix quoted files for 'verify-visited-file-modtime'

[Glenn Morris]

This fails to build: http://hydra.nixos.org/build/52549555

bug#25951: [PATCH] Fix quoted files for 'verify-visited-file-modtime'

[npostavs]

Glenn Morris <rgm@gnu.org> writes:

> This fails to build: http://hydra.nixos.org/build/52549555

    Loading /tmp/nix-build-emacs-tarball-unknown.drv-0/x1vxdahi72zl4bj2yd676ichh4iwi9iw-git-export/lisp/files.el (source)...
    Warning: Unknown defun property `gv-setter' in cl-fifth
    Warning: Unknown defun property `gv-setter' in cl-sixth
    Warning: Unknown defun property `gv-setter' in cl-seventh
    Warning: Unknown defun property `gv-setter' in cl-eighth
    Warning: Unknown defun property `gv-setter' in cl-ninth
    Warning: Unknown defun property `gv-setter' in cl-tenth
    Symbol's function definition is void: gv-define-simple-setter
    make[1]: *** [bootstrap-emacs] Error 255

Looks like my suggestion of using cl-letf doesn't work because it's too
early in the bootstrap process.  Should work with the original code (but
perhaps add a comment about why we can't use cl-letf).

bug#25951: [PATCH] Fix bootstrap build of files.el

[Philipp]

* lisp/files.el (file-name-non-special): Don't use cl-letf.
---
 lisp/files.el | 14 +++++++++-----
 1 file changed, 9 insertions(+), 5 deletions(-)

diff --git a/lisp/files.el b/lisp/files.el
index 7e627d36d4..8ac1993754 100644
--- a/lisp/files.el
+++ b/lisp/files.el
@@ -29,7 +29,6 @@
 ;;; Code:
 
 (eval-when-compile
-  (require 'cl-lib)
   (require 'pcase)
   (require 'easy-mmode)) ; For `define-minor-mode'.
 
@@ -7032,13 +7031,18 @@ file-name-non-special
            (when (and visit buffer-file-name)
              (setq buffer-file-name (concat "/:" buffer-file-name))))))
       (`unquote-then-quote
-       (cl-letf* ((buffer (or (car arguments) (current-buffer)))
-                  ((buffer-local-value 'buffer-file-name buffer)
-                   (substring (buffer-file-name buffer) 2)))
+       ;; We can't use `cl-letf' with `(buffer-local-value)' here
+       ;; because it wouldn't work during bootstrapping.
+       (let ((buffer (current-buffer)))
          ;; `unquote-then-quote' is only used for the
          ;; `verify-visited-file-modtime' action, which takes a buffer
          ;; as only optional argument.
-         (apply operation arguments)))
+         (with-current-buffer (or (car arguments) buffer)
+           (let ((buffer-file-name (substring buffer-file-name 2)))
+             ;; Make sure to hide the temporary buffer change from the
+             ;; underlying operation.
+             (with-current-buffer buffer
+               (apply operation arguments))))))
       (_
        (apply operation arguments)))))
 
-- 
2.12.2

bug#25951: [PATCH] Fix quoted files for 'verify-visited-file-modtime'

[Philipp]

[-- Attachment #1: Type: text/plain, Size: 1041 bytes --]

<npostavs@users.sourceforge.net> schrieb am Sa., 6. Mai 2017 um 22:39 Uhr:

> Glenn Morris <rgm@gnu.org> writes:
>
> > This fails to build: http://hydra.nixos.org/build/52549555
>
>     Loading
> /tmp/nix-build-emacs-tarball-unknown.drv-0/x1vxdahi72zl4bj2yd676ichh4iwi9iw-git-export/lisp/files.el
> (source)...
>     Warning: Unknown defun property `gv-setter' in cl-fifth
>     Warning: Unknown defun property `gv-setter' in cl-sixth
>     Warning: Unknown defun property `gv-setter' in cl-seventh
>     Warning: Unknown defun property `gv-setter' in cl-eighth
>     Warning: Unknown defun property `gv-setter' in cl-ninth
>     Warning: Unknown defun property `gv-setter' in cl-tenth
>     Symbol's function definition is void: gv-define-simple-setter
>     make[1]: *** [bootstrap-emacs] Error 255
>
> Looks like my suggestion of using cl-letf doesn't work because it's too
> early in the bootstrap process.  Should work with the original code (but
> perhaps add a comment about why we can't use cl-letf).
>

Installed commit cea3b22bc7.

[-- Attachment #2: Type: text/html, Size: 1586 bytes --]

bug#25951: [PATCH] Fix bootstrap build of files.el

[Glenn Morris]

We have a diffs mailing list, so you don't need to send your patches to
two other mailing lists as well.

bug#25951: [PATCH] Fix bootstrap build of files.el

[Philipp]

[-- Attachment #1: Type: text/plain, Size: 323 bytes --]

Glenn Morris <rgm@gnu.org> schrieb am So., 7. Mai 2017 um 03:25 Uhr:

>
> We have a diffs mailing list, so you don't need to send your patches to
> two other mailing lists as well.
>
>

Yes, I just wanted to have my patch reviewed before committing, but since
it broke bootstrapping I decided to install it without review.

[-- Attachment #2: Type: text/html, Size: 618 bytes --]