;;; iroquoian.el --- Quail package for inputting Iroquoian languages  -*- lexical-binding: t; coding: utf-8; -*-

;; Copyright (C) 2024  Free Software Foundation, Inc.

;; Author: Kierin Bell <fernseed@fernseed.me>
;; Keywords: i18n

;; This file is part of GNU Emacs.

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; This file implements input methods for Northern Iroquoian languages.

;; Input methods are implemented for all Five Nations Iroquois
;; languages:

;; - Mohawk (Kanien’kéha / Onkwehonwe’néha)
;; - Oneida (Onʌyota:ká: / Ukwehuwehnéha)
;; - Cayuga (Gayogo̱ho:nǫhnéha:ˀ)
;; - Onondaga (Onųdaʔgegáʔ)
;; - Seneca (Onödowá’ga:’)

;; Input methods are not yet implemented for the remaining Northern
;; Iroquoian languages, including:

;; - Tuscarora (Skarù:ręʔ)
;; - Wendat (Huron) / Wyandot

;;; Code:

(require 'quail)
(require 'seq)

(defun quail-iroquoian-combining-char-p (char)
  "Return whether CHAR is a combining character."
  (and (characterp char)
       ;; XXX: Combining characters here all have 'Mn' general category.
       (memq (get-char-code-property char 'general-category) '(Mn))))

(defun quail-iroquoian-update-translation (control-flag)
  (cond
   ((integerp control-flag)
    ;; XXX: Set `quail-current-str' according to `quail-overlay', which
    ;; seems to work more reliably in this use-case than analogous code
    ;; in `quail-update-translation' (borrowed from the function
    ;; `quail-lao-update-translation' in 'lao.el').
    (setq quail-current-str
          (buffer-substring (overlay-start quail-overlay)
                            (overlay-end quail-overlay)))
    (unless input-method-exit-on-first-char
      (quail-add-unread-command-events
       (string-to-vector (substring quail-current-key control-flag)))))
   ((quail-iroquoian-combining-char-p quail-current-str)
    (setq quail-current-str
          (compose-string
           ;;
           ;; XXX: Kludge to delete extraneous initial letters from some
           ;; translations, e.g., with keys "a/'" in `onondaga-post',
           ;; the following would be inserted (with the extraneous
           ;; initial "a"): aǽ
           ;;
           ;; Doesn't work:
           ;; (substring STR (max 0 (- (string-width STR) 1)))
           ;;
           (apply #'string
                  (seq-reduce
                   (lambda (acc elt)
                     (if (quail-iroquoian-combining-char-p elt)
                         (append acc (list elt))
                       (list elt)))
                   (quail-lookup-map-and-concat quail-current-key)
                   '())))))
   ((null control-flag)
    ;; Borrowed from `quail-update-translation'.
    (unless quail-current-str
      (setq quail-current-str
            (if (quail-kbd-translate)
                (quail-keyseq-translate quail-current-key)
              quail-current-key))
      (when (and input-method-exit-on-first-char (quail-simple))
        (setq control-flag t)))))
  control-flag)

\f
;;; Mohawk

(defconst iroquoian-mohawk-punctuation-alist
  '((":" ?:)))

(defconst iroquoian-mohawk-vowel-alist
  '(("a" ?a)
    ("A" ?A)
    ("e" ?e)
    ("E" ?E)
    ("i" ?i)
    ("I" ?I)
    ("o" ?o)
    ("O" ?O)))

(defconst iroquoian-mohawk-consonant-alist
  '((";;" ?\N{RIGHT SINGLE QUOTATION MARK})
    ("h" ?h)
    ("H" ?H)
    ("k" ?k)
    ("K" ?K)
    ("n" ?n)
    ("N" ?N)
    ("r" ?r)
    ("R" ?R)
    ("s" ?s)
    ("S" ?S)
    ("t" ?t)
    ("T" ?T)
    ("w" ?w)
    ("W" ?W)
    ("Y" ?Y)
    ("y" ?y)))

(defconst iroquoian-mohawk-accent-alist
  '(("'" ?\N{COMBINING ACUTE ACCENT})
    ("`" ?\N{COMBINING GRAVE ACCENT})))

(quail-define-package
 "mohawk-postfix" "Mohawk" "MOH<" nil
 "Mohawk input method with postfix modifiers"
 nil t t nil nil nil nil nil
 #'quail-iroquoian-update-translation
 nil t)

(quail-install-map
 (quail-map-from-table
  '((base-state (iroquoian-mohawk-vowel-alist . v-state)
                iroquoian-mohawk-consonant-alist
                iroquoian-mohawk-punctuation-alist)
    (v-state iroquoian-mohawk-accent-alist))))

\f
;;; Oneida

(defconst iroquoian-oneida-punctuation-alist
  '(("::" ?\N{MIDDLE DOT})
    ;; Alternative vowel lengthener:
    (":" ?:)))

(defconst iroquoian-oneida-vowel-alist
  '(("a" ?a)
    ("A" ?A)
    ("e" ?e)
    ("E" ?E)
    ("i" ?i)
    ("I" ?I)
    ("o" ?o)
    ("O" ?O)
    ("u" ?u)
    ("U" ?U)
    ("e/" ?ʌ)
    ("E/" ?Ʌ)))

(defconst iroquoian-oneida-consonant-alist
  '(;; Alternative: ?\N{RIGHT SINGLE QUOTATION MARK}
    (";;" ?\N{MODIFIER LETTER GLOTTAL STOP})
    ("h" ?h)
    ("H" ?H)
    ("k" ?k)
    ("K" ?K)
    ("l" ?l)
    ("L" ?L)
    ("n" ?n)
    ("N" ?N)
    ("s" ?s)
    ("S" ?S)
    ("t" ?t)
    ("T" ?T)
    ("w" ?w)
    ("W" ?W)
    ("y" ?y)
    ("Y" ?Y)))

(defconst iroquoian-oneida-accent-alist
  '(("'" ?\N{COMBINING ACUTE ACCENT})))

(defconst iroquoian-oneida-pre-pausal-alist
  '(("_" ?\N{COMBINING LOW LINE})))

(quail-define-package
 "oneida-postfix" "Oneida" "ONE<" nil
 "Oneida input method with postfix modifiers"
 nil t t nil nil nil nil nil
 #'quail-iroquoian-update-translation
 nil t)

(quail-install-map
 (quail-map-from-table
  '((base-state (iroquoian-oneida-vowel-alist . v-state)
                (iroquoian-oneida-consonant-alist . p-state)
                (iroquoian-oneida-punctuation-alist . p-state))
    (v-state (iroquoian-oneida-accent-alist . p-state)
             iroquoian-oneida-pre-pausal-alist)
    (p-state iroquoian-oneida-pre-pausal-alist))))

\f
;;; Onondaga

(defconst iroquoian-onondaga-punctuation-alist
  '(("::" ?\N{MIDDLE DOT})
    ;; Alternative vowel lengthener:
    (":" ?:)))

(defconst iroquoian-onondaga-vowel-alist
  '(("a" ?a)
    ("A" ?A)
    ("a/" ?æ)
    ("i" ?i)
    ("I" ?I)
    ("o" ?o)
    ("O" ?O)))

(defconst iroquoian-onondaga-ogonek-vowel-alist
  '(("e" ?e)
    ("E" ?E)
    ("u" ?u)
    ("U" ?U)))

(defconst iroquoian-onondaga-consonant-alist
  '(;; Alternative glottal stop: ?\N{RIGHT SINGLE QUOTATION MARK}
    ;; Alternative glottal stop: ?\N{MODIFIER LETTER GLOTTAL STOP}
    (";;" ?\N{LATIN LETTER GLOTTAL STOP})
    ("c" ?c)
    ("C" ?C)
    ("d" ?d)
    ("D" ?D)
    ("g" ?g)
    ("G" ?G)
    ("h" ?h)
    ("H" ?H)
    ("j" ?j)
    ("J" ?J)
    ("k" ?k)
    ("K" ?K)
    ("n" ?n)
    ("N" ?N)
    ("s" ?s)
    ("S" ?S)
    ("t" ?t)
    ("T" ?T)
    ("w" ?w)
    ("W" ?W)
    ("y" ?y)
    ("Y" ?Y)))

(defconst iroquoian-onondaga-accent-alist
  '(("'" ?\N{COMBINING ACUTE ACCENT})))

(defconst iroquoian-onondaga-ogonek-alist
  '(("," ?\N{COMBINING OGONEK})))

(quail-define-package
 "onondaga-postfix" "Onondaga" "ONO<" nil
 "Onondaga input method with postfix modifiers"
 nil t t nil nil nil nil nil
 #'quail-iroquoian-update-translation
 nil t)

(quail-install-map
 (quail-map-from-table
  '((base-state (iroquoian-onondaga-ogonek-vowel-alist . o-state)
                (iroquoian-onondaga-vowel-alist . v-state)
                iroquoian-onondaga-consonant-alist
                iroquoian-onondaga-punctuation-alist)
    (o-state (iroquoian-onondaga-ogonek-alist . v-state)
             iroquoian-onondaga-accent-alist)
    (v-state iroquoian-onondaga-accent-alist))))

\f
;;; Cayuga

(defconst iroquoian-cayuga-punctuation-alist
  '((":" ?:)))

(defconst iroquoian-cayuga-vowel-alist
  '(("a" ?a)
    ("A" ?A)
    ("i" ?i)
    ("I" ?I)
    ("u" ?u)
    ("U" ?U)))

(defconst iroquoian-cayuga-ogonek-vowel-alist
  '(("e" ?e)
    ("E" ?E)
    ("o" ?o)
    ("O" ?O)))

(defconst iroquoian-cayuga-consonant-alist
  '((";;" ?\N{MODIFIER LETTER GLOTTAL STOP})
    ("d" ?d)
    ("D" ?D)
    ("f" ?f) ; Example word?
    ("F" ?F)
    ("g" ?g)
    ("G" ?G)
    ("h" ?h)
    ("H" ?H)
    ("j" ?j)
    ("J" ?J)
    ("k" ?k)
    ("K" ?K)
    ("n" ?n)
    ("N" ?N)
    ("r" ?r)
    ("R" ?R)
    ("s" ?s)
    ("S" ?S)
    ("t" ?t)
    ("T" ?T)
    ("w" ?w)
    ("W" ?W)
    ("y" ?y)
    ("Y" ?Y)))

(defconst iroquoian-cayuga-accent-alist
  '(("'" ?\N{COMBINING ACUTE ACCENT})
    ("-" ?\N{COMBINING MACRON BELOW})))

(defconst iroquoian-cayuga-ogonek-alist
  '(("," ?\N{COMBINING OGONEK})))

(quail-define-package
 "cayuga-postfix" "Cayuga" "CAY<" nil
 "Cayuga input method with postfix modifiers (Henry orthography)"
 nil t t nil nil nil nil nil
 #'quail-iroquoian-update-translation
 nil t)

(quail-install-map
 (quail-map-from-table
  '((base-state (iroquoian-cayuga-ogonek-vowel-alist . o-state)
                (iroquoian-cayuga-vowel-alist . v-state)
                iroquoian-cayuga-consonant-alist
                iroquoian-cayuga-punctuation-alist)
    (o-state (iroquoian-cayuga-ogonek-alist . v-state))
    (v-state iroquoian-cayuga-accent-alist))))

\f
;;; Seneca

(defconst iroquoian-seneca-punctuation-alist
  '((":" ?:)))

(defconst iroquoian-seneca-vowel-alist
  '(("i" ?i)
    ("I" ?I)
    ("u" ?u)
    ("U" ?U)))

(defconst iroquoian-seneca-diaeresis-vowel-alist
  '(("a" ?a)
    ("A" ?A)
    ("e" ?e)
    ("E" ?E)
    ("o" ?o)
    ("O" ?O)))

(defconst iroquoian-seneca-consonant-alist
  `((";;" ?\N{RIGHT SINGLE QUOTATION MARK})
    ("d" ?d)
    ("D" ?D)
    ("g" ?g)
    ("G" ?G)
    ("h" ?h)
    ("H" ?H)
    ("j" ?j)
    ("J" ?J)
    ("k" ?k)
    ("K" ?K)
    ("n" ?n)
    ("N" ?N)
    ("s" ?s)
    ("S" ?S)
    ("s/" ?š)
    ("S/" ?Š)
    ("t" ?t)
    ("T" ?T)
    ("w" ?w)
    ("W" ?W)
    ("y" ?y)
    ("Y" ?Y)
    ("z" ?z)
    ("Z" ?Z)))

(defconst iroquoian-seneca-accent-alist
  '(("'" ?\N{COMBINING ACUTE ACCENT})))

(defconst iroquoian-seneca-diaeresis-alist
  '(("\"" ?\N{COMBINING DIAERESIS})))

(quail-define-package
 "seneca-postfix" "Seneca" "SEE<" nil
 "Seneca input method with postfix modifiers (Henry orthography)"
 nil t t nil nil nil nil nil
 #'quail-iroquoian-update-translation
 nil t)

(quail-install-map
 (quail-map-from-table
  '((base-state (iroquoian-seneca-diaeresis-vowel-alist . d-state)
                (iroquoian-seneca-vowel-alist . v-state)
                iroquoian-seneca-consonant-alist
                iroquoian-seneca-punctuation-alist)
    (d-state (iroquoian-seneca-diaeresis-alist . v-state)
             iroquoian-seneca-accent-alist)
    (v-state iroquoian-seneca-accent-alist))))

\f
;;; Composite Iroquoian

(defconst iroquoian-composite-punctuation-alist
  (seq-uniq (append iroquoian-mohawk-punctuation-alist
                    iroquoian-oneida-punctuation-alist
                    iroquoian-onondaga-punctuation-alist
                    iroquoian-cayuga-punctuation-alist
                    iroquoian-seneca-punctuation-alist)))

(defconst iroquoian-composite-vowel-alist
  (seq-uniq (append iroquoian-mohawk-vowel-alist
                    iroquoian-oneida-vowel-alist
                    iroquoian-onondaga-vowel-alist
                    iroquoian-cayuga-vowel-alist
                    iroquoian-seneca-vowel-alist
                    iroquoian-onondaga-ogonek-vowel-alist
                    iroquoian-cayuga-ogonek-vowel-alist
                    iroquoian-seneca-diaeresis-vowel-alist)))

(defconst iroquoian-composite-consonant-alist
  (seq-uniq (append
             '((";;" ?\N{RIGHT SINGLE QUOTATION MARK})
               (";'" ?\N{MODIFIER LETTER GLOTTAL STOP})
               (";:" ?\N{LATIN LETTER GLOTTAL STOP}))
             iroquoian-mohawk-consonant-alist
             iroquoian-oneida-consonant-alist
             iroquoian-onondaga-consonant-alist
             iroquoian-cayuga-consonant-alist
             iroquoian-seneca-consonant-alist)
            (lambda (c1 c2)
              (equal (car c1) (car c2)))))

(defconst iroquoian-composite-accent-alist
  '(("'" ?\N{COMBINING ACUTE ACCENT})
    ("`" ?\N{COMBINING GRAVE ACCENT})
    ("-" ?\N{COMBINING MACRON BELOW})))

(defconst iroquoian-composite-modifier-alist
  '(("," ?\N{COMBINING OGONEK})
    ("\"" ?\N{COMBINING DIAERESIS})))

(defconst iroquoian-composite-pre-pausal-alist
  '(("_" ?\N{COMBINING LOW LINE})))

(quail-define-package
 "iroquoian-postfix" "Iroquoian" "IRO<" nil
 "Composite input method for Northern Iroquoian languages"
 nil t t nil nil nil nil nil
 #'quail-iroquoian-update-translation
 nil t)

(quail-install-map
 (quail-map-from-table
  '((base-state (iroquoian-composite-vowel-alist . v-state)
                (iroquoian-composite-consonant-alist . p-state)
                (iroquoian-composite-punctuation-alist . p-state))
    (v-state (iroquoian-composite-modifier-alist . v-state-2)
             (iroquoian-composite-accent-alist . p-state)
             iroquoian-composite-pre-pausal-alist)
    (v-state-2 (iroquoian-composite-accent-alist . p-state)
               iroquoian-composite-pre-pausal-alist)
    (p-state iroquoian-composite-pre-pausal-alist))))

;;; iroquoian.el ends here