bug#46621: Copy line

["Mattias Engdegård" <mattiase@acm.org>]

[-- Attachment #1: Type: text/plain, Size: 771 bytes --]

> I've now added this command to Emacs 29 as `duplicate-line'. 

Thank you! There was quite some discussion about generalising the concept last time it came up for discussion, and making it work on the region when active was found to be very useful. It comes quite naturally in use, much like upcase-dwim etc.

The attached patch does that. For extra convenience, when the active region is rectangular it is duplicated to the right, since that is what is usually most convenient.

There's a few subtleties here: the code takes care to preserve the region because the user may want to press the key again for another copy. (This means that we need to use undo-inhibit-region for undo to work properly.)

Do you feel audacious enough for a standard key binding?


[-- Attachment #2: duplicate-line-or-region.diff --]
[-- Type: application/octet-stream, Size: 2179 bytes --]

diff --git a/lisp/misc.el b/lisp/misc.el
index 3fb30e5372..d5db0a35ae 100644
--- a/lisp/misc.el
+++ b/lisp/misc.el
@@ -63,19 +63,51 @@ copy-from-above-command
 				 (+ n (point)))))))
     (insert string)))
 
+(declare-function extract-rectangle-line "rect" (startcol endcol lines))
+(declare-function apply-on-rectangle "rect" (function start end &rest args))
+
+(put 'duplicate-line-or-region 'undo-inhibit-region t)
+
 ;;;###autoload
-(defun duplicate-line (&optional n)
-  "Duplicate the current line N times.
+(defun duplicate-line-or-region (&optional n)
+  "Duplicate the current line or region N times.
+If the region is inactive, the current line is duplicated.
+Otherwise, duplicate the region's contents.  The region remains
+active afterwards.
+If the region is rectangular, duplication is made on its right-hand side.
 Interactively, N is the prefix numeric argument, and defaults to 1.
 Also see the `copy-from-above-command' command."
   (interactive "p")
-  (let ((line (buffer-substring (line-beginning-position) (line-end-position))))
-    (save-excursion
-      (forward-line 1)
-      (unless (bolp)
-        (insert "\n"))
-      (dotimes (_ n)
-        (insert line "\n")))))
+  (cond
+   ((bound-and-true-p rectangle-mark-mode)
+    (require 'rect)
+    (apply-on-rectangle
+     (lambda (startcol endcol)
+       (let ((lines (list nil)))
+         (extract-rectangle-line startcol endcol lines)
+         (move-to-column endcol t)
+         (dotimes (_ n)
+           (insert (cadr lines)))))
+     (region-beginning) (region-end))
+    (setq deactivate-mark nil))
+   ((use-region-p)
+    (let* ((beg (region-beginning))
+           (end (region-end))
+           (text (buffer-substring beg end)))
+      (save-excursion
+        (goto-char end)
+        (dotimes (_ n)
+          (insert text))))
+    (setq deactivate-mark nil))
+   (t
+    (let ((line (buffer-substring (line-beginning-position)
+                                  (line-end-position))))
+      (save-excursion
+        (forward-line 1)
+        (unless (bolp)
+          (insert "\n"))
+        (dotimes (_ n)
+          (insert line "\n")))))))
 
 ;; Variation of `zap-to-char'.